;Demoprogramm für 8-fach-PWM mit Tastensteuerung Up-Down.

;8 LEDs gegen Vcc an PortB (STK500)
;8 entprellte Tasten gegen GND für die einzelnen PWM-Kanäle an PortD
;1 "Shift-Taste" an PA6 gegen GND zum Wählen der Stellrichtung der Kanaltasten.
;Shift offen -> Kanaltasten zählen hoch,
;Shift betätigt -> Kanaltasten zählen runter.
;Der Zählumfang wird nach oben und unten begrenzt.

.include "m8515def.inc"

.equ clock = 8000000        ;Taktfrequenz

.equ pwu = 99               ;PWM-Zählumfang
.equ timerwert = -100       ;Timer-Startwert (Reload)
.equ step=6                 ;Schrittweite für Änderung pro Tastendruck
.equ lep=portb              ;Port für LEDs
.equ tap=pinc               ;Tastenport
.equ ship=pind              ;Port für Shift-Taste
.equ shib=6                 ;Bit für Shift-Taste

.equ avt0=25                ;Startwert Anzeige-Vorteiler


.def soll0 = r0             ;Sollwert Kanal 1
.def soll1 = r1             ;Sollwert Kanal 2
.def soll2 = r2             ;Sollwert Kanal 3
.def soll3 = r3             ;Sollwert Kanal 4
.def soll4 = r4             ;Sollwert Kanal 5
.def soll5 = r5             ;Sollwert Kanal 6
.def soll6 = r6             ;Sollwert Kanal 7
.def soll7 = r7             ;Sollwert Kanal 8
.def tsw = r8               ;Timer-Startwert
.def sregtemp = r9          ;Sicherheitskopie SREG
.def scan=r10               ;Scannwert Tastenport
.def tz0=r11                ;Tasten-Prellzähler Bit0
.def tz1=r12                ;Tasten-Prellzähler Bit1
.def tas=r13                ;Tastenstatus (gültig)
.def null=r14               ;immer 0

.def temp = r16
.def tfl=r17                ;Flags für Tasten, die gedrückt wurden
.def pwz = r18              ;PWM-Zähler
.def task=r19               ;Taskscheibe für diverse Aufgaben
.def ri=r20                 ;Richtung der Änderung
.def max=r21                ;Maximum
.def avt=r22                ;Anzeige-Vorteiler
.def flags=r23              ;Steuerflags
    .equ aktuLCD=7              ;LCD aktualisieren

.def wl=r24                 ;Working L
.def wh=r25                 ;Working H


.cseg
.org 0                      ;Reset- und Interrupt-Vektoren Mega 8535
.org 0              ;Reset- und Interrupt-Vektoren AT-Mega 8515
 rjmp RESET         ;Reset Handler
 rjmp nix;EXT_INT0      ;IRQ0 Handler
 rjmp nix;EXT_INT1      ;IRQ1 Handler
 rjmp nix;TIM1_CAPT     ;Timer1 Capture Handler
 rjmp nix;TIM1_COMPA    ;Timer1 Compare A Handler
 rjmp nix;TIM1_COMPB    ;Timer1 Compare B Handler
 rjmp nix;TIM1_OVF      ;Timer1 Overflow Handler
 rjmp TIM0_OVF      ;Timer0 Overflow Handler
 rjmp nix;SPI_STC       ;SPI Transfer Complete Handler
 rjmp nix;USART_RXC     ;USART RX Complete Handler
 rjmp nix;USART_UDRE    ;UDR0 Empty Handler
 rjmp nix;USART_TXC     ;USART TX Complete Handler
 rjmp nix;ANA_COMP      ;Analog Comparator Handler
 rjmp nix;EXT_INT2      ;IRQ2 Handler
 rjmp nix;TIM0_COMP     ;Timer0 Compare Handler
 rjmp nix;EE_RDY        ;EEPROM Ready Handler
 rjmp nix;SPM_RDY       ;Store Program memory Ready Handler
nix:                    ;unbenutzte Interrupts
 reti                   ;zurück...

.include"LCDprint.inc"      ;LCD-Ausgabefunktionen
.include"LCD_4x40.inc"      ;LCD-Routinen für 2-Zeilen-LCDs mit HD44780

Reset:

 ldi wl,low(ramend)         ;Stackpointer initialisieren
 out SPL,wl
 ldi wl,high(ramend)
 out SPH,wl
 
 clr null                   ;immer 0

 ldi wl, 0xFF    ;Port A = Ausgang
 out DDRA, wl


 
 ldi temp, 0xff
 out lep-1,temp             ;Ports B = Ausgang (DDRx=PORTx-1)

 ;out lep,temp               ;LED aus
 
 out tap+2,temp             ;Pull-Ups für Tasten einschalten (PORTx=PINx+2)
 ldi temp, 0x00
 out tap+1,temp             ;Ports d = Eingang (DDRx=PINx+1)
 
 cbi ship+1,shib            ;Shift-Tastenanschluss als Eingang
 sbi ship+2,shib            ;Shift-PullUp einschalten




 clr soll0
 clr soll1
 clr soll2
 clr soll3
 clr soll4
 clr soll5
 clr soll6
 clr soll7
 clr tz0                    ;Definierte Startbedingung 
 clr tz1                    ;für Tastenentprellung
 clr tas
 clr tfl


 ldi temp, 0x01
 out tccr0, temp            ;Timertakt = 1:1
 ldi temp, 1<<toie0
 out timsk, temp            ;Timer OVF freigeben
 ldi temp,timerwert+12      ;Timer-Startwert, korregiert mit Int-Aufruf12
 mov tsw,temp               ;definieren
 out tcnt0,tsw              ;und ausgeben

 ldi temp, 0; 50
 mov soll0, temp            ;Naja, wenn es sein muss...
 ldi temp,1<<se             ;Sleep-Mode (idle)
 out mcucr,temp             ;freischalten
 ldi max,pwu                ;Max-Wert für Begrenzung der Änderung

 rcall lcd_init             ;LCD initialisieren
 cbr flags,1<<aktuLCD       ;Jobflag löschen, wird ja jetzt erledigt



 sei 

 ldi flags,1<<aktuLCD       ;erstes Schreiben des LCDs anmelden
 ldi avt,avt0               ;Anzeige-Vorteiler auf Startwert setzen


Haupt:                      ;Hauptschleife, Auswertung der Tastenflags
  ;und Jobflags die in der ISR gesetzt wurden und verändern
  ;der PWM-Werte der 8 Kanäle.
 sleep                      ;Schlafmodus, Wecken erfolgt durch Timer-Int.


				
 sbrc flags,aktuLCD         ;muss LCD aktualisiert werden? - nein...
 rcall gibaus               ;ja, Job aufrufen...
 
 tst tfl                    ;Ein Bit im Tastenflag gesetzt?
 breq haupt                 ;nein, keine Taste gedrückt gewesen... (schlafen gehen...)
 ldi ri,step                ;ja, erstmal aufwärts zählen
 sbis ship,shib             ;Shift-Taste gedrückt? (nein...)
 rjmp minus                 ;ja, zum Abwärtszählen...
taste0: 
 sbrs tfl,0                 ;Taste 0?
 rjmp taste1                ;nein...
 add soll0,ri         ;ja, ändern
 cp soll0,max               ;Maxwert überschritten?
 brlo taste1                ;nein...
 mov soll0,max              ;ja, auf Maxwert begrenzen  
taste1:
 sbrs tfl,1                 ;Taste 1?
 rjmp taste2                ;nein...
 add soll1,ri               ;ja, ändern
 cp soll1,max               ;Maxwert überschritten?
 brlo taste2                ;nein...
 mov soll1,max              ;ja, auf Maxwert begrenzen
taste2:
 sbrs tfl,2                 ;Taste 2?
 rjmp taste3                ;nein...
 add soll2,ri               ;ja, ändern
 cp soll2,max               ;Maxwert überschritten?
 brlo taste3                ;nein...
 mov soll2,max              ;ja, auf Maxwert begrenzen
taste3:
 sbrs tfl,3                 ;Taste 3?
 rjmp taste4                ;nein...
 add soll3,ri               ;ja, ändern      
 cp soll3,max               ;Maxwert überschritten?
 brlo taste4                ;nein...
 mov soll3,max              ;ja, auf Maxwert begrenzen
taste4:
 sbrs tfl,4                 ;Taste 4?
 rjmp taste5                ;nein...
 add soll4,ri               ;ja, ändern  
 cp soll4,max               ;Maxwert überschritten?
 brlo taste5                ;nein...
 mov soll4,max              ;ja, auf Maxwert begrenzen
taste5:
 sbrs tfl,5                 ;Taste 5?
 rjmp taste6                ;nein...
 add soll5,ri               ;ja, ändern,
 cp soll5,max               ;Maxwert überschritten?
 brlo taste6                ;nein...
 mov soll5,max              ;ja, auf Maxwert begrenzen
taste6:
 sbrs tfl,6                 ;Taste 6?
 rjmp taste7                ;nein...
 add soll6,ri               ;ja, ändern
 cp soll6,max               ;Maxwert überschritten?
 brlo taste7                ;nein...
 mov soll6,max              ;ja, auf Maxwert begrenzen
taste7:
 sbrs tfl,7                 ;Taste 7?
 rjmp taste8                ;nein...
 add soll7,ri               ;ja, ändern
 cp soll7,max               ;Maxwert überschritten?
 brlo taste8                ;nein...
 mov soll7,max              ;ja, auf Maxwert begrenzen
taste8:
 clr tfl                    ;alle Tastenflags löschen
 rjmp haupt                 ;fertig, schlafen gehen...
minus:
 sbrs tfl,0                 ;Taste 0?
 rjmp minus1                ;nein...
 sub soll0,ri               ;ja, ändern
 brcc minus1                ;Unterlauf ? (nein...)
 clr soll0                 ;ja, auf 0 setzen
minus1:
 sbrs tfl,1                 ;Taste 1?
 rjmp minus2                ;nein...
 sub soll1,ri               ;ja, ändern
 brcc minus2                ;Unterlauf ? (nein...)
 clr soll1                  ;ja, auf 0 setzen
minus2:
 sbrs tfl,2                 ;Taste 2?
 rjmp minus3                ;nein...
 sub soll2,ri               ;ja, ändern
 brcc minus3                ;Unterlauf ? (nein...)
 clr soll2                  ;ja, auf 0 setzen
minus3:
 sbrs tfl,3                 ;Taste 3?
 rjmp minus4                ;nein...
 sub soll3,ri               ;ja, ändern
 brcc minus4                ;Unterlauf ? (nein...)
 clr soll3                  ;ja, auf 0 setzen
minus4:
 sbrs tfl,4                 ;Taste 4?
 rjmp minus5                ;nein...
 sub soll4,ri               ;ja, ändern
 brcc minus5                ;Unterlauf ? (nein...)
 clr soll4                  ;ja, auf 0 setzen
minus5:
 sbrs tfl,5                 ;Taste 5?
 rjmp minus6                ;nein...
 sub soll5,ri               ;ja, ändern
 brcc minus6                ;Unterlauf ? (nein...)
 clr soll5                  ;ja, auf 0 setzen
minus6:
 sbrs tfl,6                 ;Taste 6?
 rjmp minus7                ;nein...
 sub soll6,ri               ;ja, ändern    
 brcc minus7                ;Unterlauf ? (nein...)
 clr soll6                  ;ja, auf 0 setzen
minus7:
 sbrs tfl,7                 ;Taste 7?
 rjmp minus8                ;nein...
 sub soll7,ri               ;ja, ändern
 brcc minus8                ;Unterlauf ? (nein...)
 clr soll7                  ;ja, auf 0 setzen
minus8:
 clr tfl                    ;alle Tastenflags löschen
 rjmp haupt                 ;Hauptprogramm Endlosschleife

 
gibaus:                 ;Unterprogramm zum Ausgeben der Werte
 cbr flags,1<<aktuLCD       ;Jobflag löschen, wird ja jetzt erledigt
 locate 0,0                 ;erste Position der ersten Zeile
 print8 r0                  ;1. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 print8 r1                  ;2. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 print8 r2                  ;3. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 print8 r3                  ;4. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 locate 1,0                 ;erste Position der zweiten Zeile
 print8 r4                  ;5. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 print8 r5                  ;6. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 print8 r6                  ;7. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 print8 r7                  ;8. Wert
 print '%'                  ;Prozent-Zeichen
 print ' '                  ;Leerzeichen
 ret                        ;fertig...



Tim0_OVF:                   ;ISR Timer0-Überlauf
 in sregtemp, sreg          ;Sreg sichern
 out tcnt0,tsw              ;Timer auf Startwert setzen
 inc pwz                    ;PWM-Treppenzähler erhöhen
 cpi pwz, pwu               ;PWM-Zählumfang erreicht?
 brne Time0_a               ;nein... (die 3 Punkte bedeuten bei mir Sprung)
 clr pwz                    ;von vorn beginnen mit zählen
Time0_a:                    ;Vergleich der einzelnen PWM-Werte mit dem PWM-Treppenzähler
                            ;(Idee geklaut bei Peter Dannegger)
 cp pwz, soll7              ;Sollwert erreicht? (Ergebnis im Carry)
 rol temp                   ;Carry-Bits "einsammeln", dieses wird bis Bit7 durchgeschoben
 cp pwz, soll6
 rol temp                   ;Bit 6
 cp pwz, soll5
 rol temp                   ;Bit 5
 cp pwz, soll4
 rol temp                   ;Bit 4
 cp pwz, soll3
 rol temp                   ;Bit 3
 cp pwz, soll2
 rol temp                   ;Bit 2
 cp pwz, soll1
 rol temp                   ;Bit 1
 cp pwz, soll0
 rol temp                   ;Bit 0
 ;com temp                   ;invertieren da low-aktive LED im STK500
 out portB, temp            ;Ausgabe 
 inc task                   ;Taskscheibe erhöhen (Tastenabfrage erfolgt nur bei Task Nr. 0)
                            ;andere Aufgaben können bei anderen Zählerständen aufgerufen werden
                            ;dabei ist darauf zu achten, dass kein Durchlauf der ISR mehr als
                            ;70 Takte dauert, da die ISR alle 100 Takte aufgerufen wird und
                            ;der Aufruf (mit Reti) schon 10 Takte braucht.
 brne timertasks            ;nur bei 0 Tasten abfragen...
Tastenabfrage:              ;Entprellroutine (geklaut bei Peter Dannegger...)
 in scan,tap                ;Tastenport einlesen (gedrückt=L)
 com scan                   ;invertieren (gedrückt=H)
 eor scan,tas               ;nur Änderungen werden H
 and tz0,scan               ;Prellzähler unveränderter Tasten löschen (Bit0)
 and tz1,scan               ;Prellzähler unveränderter Tasten löschen (Bit1)
 com tz0                    ;L-Bit zählen 0,2,->1, 1,3,->0
 eor tz1,tz0                ;H-Bit zählen 0,2,->tz1 toggeln
 and scan,tz0               ;Änderungen nur dann erhalten, wenn im Prellzähler
 and scan,tz1               ;beide Bits gesetzt sind (Zählerstand 3)
 eor tas,scan               ;erhaltene Änderungen toggeln alten (gültigen) Tastenstatus
 and scan,tas               ;nur (neu) gedrückte Tastenbits bleiben erhalten
 or tfl,scan                ;und zugehörige Bits setzen (gelöscht wird nach Abarbeitung)
 ;in "tas" steht jetzt der gültige Tastenzustand,
 ;in "tfl" die Flags der neu gedrückten, noch nicht abgearbeiteten Tasten...
timertasks:
 cpi task,2                 ;Beispiel für Verzweigung nach Taskscheibe
 brne timerfertig           ;bei falscher Tasknummer Überspringen...
 dec avt                    ;Anzeige-Vorteiler runter
 brne timerfertig           ;unten? nein, weg hier...
 ldi avt,avt0               ;ja, Startwert laden
 sbr flags,1<<aktuLCD       ;Flag setzen, um LCD zu aktualisieren
 
timerfertig:
 out sreg, sregtemp         ;Sreg wiederherstellen
 reti                       ;ISR fertig