;Baustelle...
;Zuenduhr fuer Feuerwerks-Sequenzen

;Version 3a fuer Zuendgeraet A mit 2 eigenen Zuendkreisen fuer Soundsteuerung
;und zusaetzlicher Handausloesung mittels Drehgeber und Handschusstaste, sowie
;Steuereingang zum Synchronstart mehrerer Zünduhren.


;Minimaler Schussabstand 0,1 Sekunde.

;


;Ressourcen:

;Timer0-Ovf:        Synchronisieren von LCD-Ausgabe und Drehgeberentprellung
;Timer1-OCA:        Haupttakt fuer Uhr und Tastenentprellung (10ms)
;Timer2-OC+Ovf:     Erzeugung der Ausgangsimpulse fuer Datenuebertragung zu
;                   Zuendverteilern 
;USART:             Polling-Betrieb zur seriellen Datenuebertragung mit dem PC



.nolist                     ;List der Include-Datei unterdruecken
.include"m8535def.inc"      ;Hardwaredefinitionen einbinden
.list                       ;Programm listen
.listmac                    ;Makros listen
.equ clock=3686400          ;Taktfrequenz des AVR
.equ telda=5                ;Telegrammdauer, Anzahl Wiederholungen
.equ souda=10               ;Signaldauer Soundsteuerung

.equ timer0ein=3            ;Bitmuster Timer0 mit Vorteiler 64 (LCD-Sync)
.equ timer0swku=256-(clock/64/2000) ;Startwert Timer0 fuer 0,5 ms

.equ tim1zu=clock/2560      ;Timer1-Interrupt-Takt
.equ baud=23                ;USART-Baudrate 9k6

.equ tap=pind               ;Eingangs-Port Tasten
    .equ tli=7                  ;Taste links
    .equ tho=6                  ;Taste hoch
    .equ tru=5                  ;Taste runter
    .equ tre=4                  ;Taste rechts
    .equ ths=3                  ;Taste Handschuss
    .equ tdg=2                  ;Taster vom Drehgeber
    .equ tsy=1                  ;Synchronisationseingang
;Maske aller Tasten:
;.equ alltast=(1<<tru)|(1<<tre)|(1<<tho)|(1<<tli)|(1<<ths)|(1<<tdg) 
.equ alltast=(1<<tru)|(1<<tre)|(1<<tho)|(1<<tli)    ;Menuetasten
.equ hstast=(1<<ths)|(1<<tdg)   ;Handschusstasten

.equ syncpin=pina           ;Eingangsport für Synchronisation (Fernstart)
    .equ syncbit=0              ;Bit des Synch-Eingangs

.equ dgp=pinb               ;Eingangsport Drehgeber
    .equ dgmsk=0b00001100       ;Maske auf benutzte Bits
    .equ dgprell=0b00101010     ;Maske auf Togglebits

.equ dapo=portc             ;Port fuer Datenausgang Zuendverteiler
.equ dapi=pc0               ;Bit dazu

.equ vt8=2                  ;Timer2-Vorteiler 8 fuer Bitausgabe
.equ nullbit=$c0            ;Impulsbreite fuer Nullbit (75%) fuer Bitausgabe
.equ einsbit=$40            ;Impulsbreite fuer Einsbit (25%) fuer Bitausgabe

.equ zln=8                  ;Anzahl Zeilen LCD
.equ spn=24                 ;Anzahl Spalten LCD



.dseg                   ;SRAM-Variablen
.org $60                ;Page 0 ($060...$0ff)
tmpmath:        .byte 4     ;Uebergabebereich fuer Print
xptr:           .byte 1     ;Lesepointer LCD-Ringbuffer
yptr:           .byte 1     ;Schreibpointer LCD-Ringbuffer
shz:            .byte 1     ;Shiftzaehler fuer Ausgabe zum Zuendverteiler
shl:            .byte 1     ;Shift-Byte L fuer Ausgabe zum Zuendverteiler (Data)
shh:            .byte 1     ;Shift-Byte H fuer Ausgabe zum Zuendverteiler (Chk)
shd:            .byte 1     ;Datenbyte fuer Ausgabe zum Zuendverteiler (Chk)
dsla:           .byte 1     ;Datensatz L alt
dsha:           .byte 1     ;Datensatz H alt
snra:           .byte 1     ;Schussnummer alt
shibu:          .byte 4     ;Shiftbuffer fuer RX-Parser
tpz:            .byte 2     ;Tasten-Prellzaehler
rpos:           .byte 1     ;Leseposition VLCD
wpos:           .byte 1     ;Schreibposition VLCD
blinka:         .byte 1     ;Blinkbereich Anfang
blinke:         .byte 1     ;Blinkbereich Ende
delay_a0:       .byte 1     ;Dauerzaehler A0
delay_a1:       .byte 1     ;Dauerzaehler A1


.org $100               ;Page 1 ($100...$1ff)
vlcd:      .byte zln*spn    ;Bildschirmspeicher
ringbuffer:     .byte 32    ;Ringbuffer fuer UART-Ausgabe
                        ;Page 2 ($200...$25f) ist fuer Stack reserviert

.def null=r2                ;immer Null
.def ff=r3                  ;immer $ff
.def srsk=r4                ;SREG-Siko
.def drg=r5                 ;Drehgeber-Entprellvariable
.def zeile=r6               ;aktuelle Zeile
.def maxzeile=r7            ;maximal genutzte Zeile
.def dsl=r8                 ;Zeit L (temp Datensatz)
.def dsh=r9                 ;Zeit H (temp Datensatz)
.def snr=r10                ;Schussnummer (temp Datensatz)
.def bliz=r11               ;Blinkzaehler LCD
.def sdz=r12                ;Schussdauerzaehler
.def tas=r13                ;Tastenstatus (gueltig)
.def ztl=r14                ;Zeitstempel L
.def zth=r15                ;Zeitstempel H

.def vflags=r16             ;Flags fuer virt.LCD
.def haschunu=r17           ;Handschussnummer per Drehgeber
.def shift=r18              ;Shiftreg fuer serielle Ausgabe
.def mp=r19                 ;Menuepunkt
.def teiler=r20             ;Teiler fuer Timer (1 Sekunde)
.def tmp=r21                ;Temporaer fuer LCD und aehnliches
.def tfl=r22                ;Tasten-Flags (melden Tastendruck)

.def flags=r23              ;diverse Flags
    .equ neusek=0               ;neue Sekunde
    .equ v24rx=1                ;RX aktiv (debug...)
    .equ v24tx=2                ;TX aktiv (debug...)
    .equ aktiv=3                ;Uhr laeuft
    .equ schuss=4               ;Schuss ist ausgeloest
    .equ handschuss=5           ;Schuss wurde von Hand ausgeloest
    .equ dgschuss=6             ;Drehgeber-Schuss
    .equ entprell=7             ;Tasten müssen entprellt werden

.def wl=r24                 ;Working L
.def wh=r25                 ;Working H

.macro printsnr         ;Schussnummer ausgeben
 push xl                    ;verwendete Register sichern
 mov xl,@0                  ;Kopie vom Quellregister
 rcall lcd_printsnr         ;Aufruf...
 pop xl                     ;verwendete Register wiederherstellen
.endmacro               ;


.cseg
.org 0              ;Reset- und Interrupt-Vektoren AT-Mega 8535
 rjmp reset;         Reset Handler
 reti; rjmp EXT_INT0        ; IRQ0 Handler
 reti; rjmp EXT_INT1        ; IRQ1 Handler
 rjmp TIM2_COMP         ; Timer2 Compare Handler    (Datenausgang aus)
 rjmp TIM2_OVF          ; Timer2 Overflow Handler   (Datenausgang ein)
 reti; rjmp TIM1_CAPT       ; Timer1 Capture Handler
 rjmp TIM1_COMPA        ; Timer1 Compare A Handler  (Haupttakt 10ms)
 reti; rjmp TIM1_COMPB      ; Timer1 Compare B Handler
 reti; rjmp TIM1_OVF        ; Timer1 Overflow Handler
 rjmp TIM0_OVF          ; Timer0 Overflow Handler   (LCD-Ausgabe)
 reti; rjmp SPI_STC         ; SPI Transfer Complete Handler
 reti; rjmp USART_RXC       ; USART RX Complete Handler
 reti; rjmp USART_UDRE      ; UDR Empty Handler
 reti; rjmp USART_TXC       ; USART TX Complete Handler
 reti; rjmp ADC             ; ADC Conversion Complete Handler
 reti; rjmp EE_RDY          ; EEPROM Ready Handler
 reti; rjmp ANA_COMP        ; Analog Comparator Handler
 reti; rjmp TWSI            ; Two-wire Serial Interface Handler
 reti; rjmp EXT_INT2        ; IRQ2 Handler
 reti; rjmp TIM0_COMP       ; Timer0 Compare Handler
 reti; rjmp SPM_RDY         ; Store Program Memory Ready Handler

.include "pr_txt.inc"       ;Ausgabe von ASCII-Texten
.include "pr_debug.inc"     ;Ausgabe als HEX oder BIN
.include "pr_i2a8.inc"      ;Ausgabe von Integer 8 Bit
.include "pr_i2a16.inc"     ;Ausgabe von Integer 16 Bit
.include "pr_i2a24.inc"     ;Ausgabe von Integer 24 Bit
.include "pr_zuhr3.inc"     ;Ausgabe von Integer als Zeitstring
.include "vLCD8x24.inc"     ;LCD-Treiber-Routinen fuer LCDs mit M50530


reset:
 ldi wl,low(ramend)         ;Stackpointer initialisieren
 out SPL,wl
 ldi wl,high(ramend)
 out SPH,wl
 clr null                   ;immer Null
 clr ff
 dec ff                     ;immer $ff
 clr tas                    ;definierten
 mov ztl,ff                 ;Zeit 
 mov zth,ff                 ;auf -1

 ldi mp,34                  ;Menuepunkt 4


 clr zeile                  ;Erster Eintrag
 clr maxzeile               ;erstmal keine Eintraege
 mov haschunu,null          ;Handschuss-Nummer loeschen
 ldi wl,dgprell             ;Drehgeber-
 mov drg,wl                 ;Init

 sbic dgp,3                 ;Steht Drehgeber auf High? - ja...
 clr drg                    ;nein, auf Low initialisieren

 ldi wl,1<<se               ;Sleep-Mode Idle aktivieren
 out mcucr,wl
 
 ldi wl,alltast|hstast      ;Pull-Ups
 out tap+2,wl               ;fuer Tasten einschalten
 sbi syncpin+2,syncbit      ;Pull-Up für Synchroneigang

 ldi wl,dgmsk               ;Pull-Ups
 out dgp+2,wl               ;fuer Drehgeber einschalten

; sts xptr,null              ;Pointer fuer LCD-Ringbuffer
; sts yptr,null              ;setzen ($100...$1ff)

 ldi wl,1<<acd              ;Analog-Comparator aus
 out acsr,wl                ;Strom sparen

 ldi tmp,timer0ein          ;Timer0
 out tccr0,tmp              ;einschalten

 ldi wl,1<<cs10             ;Timer1 mit 
 out tccr1b,wl              ;Vorteiler 1:1 starten
 ldi wl,low(tim1zu)         ;Interrupt-
 ldi wh,high(tim1zu)        ;Intervall
 out ocr1ah,wh              ;Timer1
 out ocr1al,wl              ;setzen

 sts shd,ff                 ;ins SRAM
 sts shz,null               ;Ausgabe fuer Zuendverteiler
 sts shl,null               ;(Shiftregister)
 sts shh,null               ;loeschen
 sts tpz,null
 sts tpz+1,null
 
 ldi wl,nullbit             ;75% Tastgrad fuer Timer2-Impulse
 out ocr2,wl                ;(Kommunikation mit Zuendverteilern)
 ldi wl,vt8                 ;Timer2 fuer Datentransfer
 out tccr2,wl               ;starten
 sbi dapo-1,dapi            ;Datenrichtung Ausgang (Impulse fuer Z-Verteiler)
 sbi ddrb,pb4               ;Anschluss Schuss-LED als Ausgang

 ldi wl,(1<<ocie1a)|(1<<toie0)|(1<<toie2)|(1<<ocie2)    ;Int ein:
; ldi wl,(1<<ocie1a)|(1<<toie2)|(1<<ocie2)    ;Int ein:
 out TIMSK,wl           ;Timer1-Compare A (Zeit, 100ms),
                        ;Timer0-Ovf (Zeichenausgabe LCD, variabel),
                        ;Timer2-Ovf (Periodenende, Signal fuer Zuendverteiler),
                        ;Timer2-Comp. (Impulsende fuer Zuendverteiler)
 clr flags                  ;alle Flags erstmal aus
 clr vflags                 ;alle Flags erstmal aus
 
 ldi wl,(1<<adlar)|(1<<refs0)+7;ADC-Quelle 0, 
 out admux,wl               ;linksbuendig
 ldi wl,(1<<aden)|(1<<adsc)|(1<<adate)+4 ;ADC ein
 out adcsra,wl              ;
 
 sei                        ;Interrupts freigeben

 rcall lcd_init             ;Display initialisieren und loeschen


 locate 1,0
 print '-',24
 locate 6,0
 printf linie

; rjmp menu

tastaus:                ;Tastenpuffer leeren und mainloop
 clr tfl                    ;Tastenflags loeschen
; sbrc flags,v24rx           ;RS232-Empfang?
; rjmp mainloop              ;ja, keine Menuepunktausgabe...
 
 locate 1,1                 ;debug...
 print8 mp

 printt mt_list,mp          ;Text fuer Menuepunkt ausgeben
tastaus1:

mainloop:               ;Hauptschleife
 sbrc vflags,upsync         ;LCD-Synchronsignal vorhanden? nein...
 rjmp drehgeber             ;Drehgeber entprellen und Zeichen ausgeben...
 sbrc flags,neusek          ;neue Sekunde da? nein...
 rjmp neusekunde            ;ja...
 sbrc flags,entprell        ;sind die Tasten zu entprellen? nein...
 rjmp entprellung           ;ja...
 sbrc tfl,ths               ;Handschusstaste betaetigt? - nein...
 rjmp handschusstaste       ;ja, abarbeiten...
 sbrc tfl,tsy               ;Synchroneingang betaetigt? - nein...
 rjmp syncstart             ;ja, abarbeiten...
 andi tfl,alltast           ;nur benutzte Tasten pruefen
 breq mainloop1             ;keine Taste gedrueckt...
 rjmp menu                  ;Tastendruck auswerten...
mainloop1: 
 sbrc flags,v24rx           ;RX? (Debug)
 rjmp empfang               ;ja...
 sleep                      ;bis zum naechsten Int pennen
 rjmp mainloop              ;nochmal...

;der weitere Code ist für die Initialisierung nicht von Bedeutung und
;wurde dasher gelöscht...

;----------------------- ISRs ----------------------------------

TIM2_COMP:              ;Timer2 Compare Handler
 cbi dapo,dapi              ;Daten-Ausgang zuruecksetzen
 reti                       ;


TIM0_OVF:               ;Timer0 Overflow Handler
 in srsk,sreg               ;SREG sichern
 sbr vflags,1<<upsync       ;Timer0 Ueberlauf: LCD_Out freigeben
 out sreg,srsk              ;SREG wiederherstellen
 reti                       ;

 
TIM1_COMPA:             ;ISR Timer1-Interrupt (alle 0,39ms)
 in srsk,sreg               ;SREG sichern (Exklusivregister)
 push xh                    ;benutzte Register
 push xl                    ;sichern
 in xl,ocr1al               ;Weckzeit
 in xh,ocr1ah               ;holen,
 subi xl,low(-tim1zu)       ;Intervall
 sbci xh,high(-tim1zu)      ;dazu,
 out ocr1ah,xh              ;und wieder
 out ocr1al,xl              ;in den Timer
 ;xl und xh koennen jetzt innerhalb dieser ISR frei benutzt werden 
 inc teiler                 ;Sekundenvorteiler hoch
 brne nixvollsek            ;nein...
 sbr flags,1<<neusek        ;ja, Flag setzen,
 sbrs flags,aktiv           ;ist Ablauf eingeschaltet? ja...
 rjmp nixvollsek            ;nein...
 inc ztl                    ;Zeit erhoehen...
 brne nixvollsek            ;Uebertrag? nein...
 inc zth                    ;ja, erhoehen
nixvollsek: 
 mov xl,teiler              ;Kopie vom Vorteiler
 andi xl,63                 ;jedes 64. mal (alle 25ms)
 brne tim1_compa_ende       ;jetzt aber nicht...
 sbr flags,1<<entprell      ;Tastenentprellung als Job anmelden
tim1_compa_ende: 
 pop xl                     ;benutzte Register
 pop xh                     ;wiederherstellen
 out sreg,srsk              ;SREG wiederherstellen
 reti                       ;fertig...


tim2_ovf:               ;Zeichenausgabe fuer Zuendverteiler
 in srsk,sreg               ;SREG sichern
 push wl                    ;Variable besorgen
 lds wl,shz                 ;Shiftzaehler holen,
 inc wl                     ;erhoehen
 sts shz,wl                 ;und sichern
 andi wl,31                 ;jedes 32. mal Daten aktualisieren
 brne tim2_ovf1             ;jetzt aber nicht
 lds wl,shd                 ;Daten holen
 sts shl,wl                 ;ja, gueltig, als Daten ins L-Byte uebernehmen,
 com wl                     ;invertieren und als Checksumme
 sts shh,wl                 ;ins H-Byte uebernehmen
 ldi wl,einsbit             ;Startbit statt Shiftregister-Bit senden
 tst sdz                    ;Schussdauer aktiv?
 breq tim2_ovf2             ;nein...
 dec sdz                    ;ja, herunterzaehlen
 brne tim2_ovf2             ;abgelaufen? - nein...
 sts shd,ff                 ;ja, ungueltige Schussnummer fuer Datenausgang
; cbi portb,pb0              ;internen Schuesse
; cbi portb,pb1              ;abschalten
 cbi portb,pb4              ;Schuss-LED ausschalten
 rjmp tim2_ovf2             ;weiter...
tim2_ovf1:
 lds wl,shh                 ;oberes Shiftbyte aus SRAM
 lsr wl                     ;nach rechts (ins Carry)
 sts shh,wl                 ;und zurueck ins SRAM
 lds wl,shl                 ;unteres Shiftbyte aus SRAM
 ror wl                     ;Carry links rein, Bit0 rechts ins Carry
 sts shl,wl                 ;und zurueck ins SRAM
 ldi wl,nullbit             ;erstmal Nullbit fuer Timer2
 brcc tim2_ovf2             ;Carry gesetzt? (dann Eins senden) nein...
 ldi wl,einsbit             ;ja, Einsbit senden
tim2_ovf2:
 out ocr2,wl                ;Timer-Tastgrad einstellen (Sendebit)
 sbi dapo,dapi              ;Daten-Ausgangspin setzen
 pop wl                     ;Variable entsorgen
 out sreg,srsk              ;altes SREG wiederherstellen
 reti