;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;										;
;	AVR-Tutorial Tasten							;
;	Entprellung und Autorepeat für 4 Tasten nach Peter Dannegger		;
;										;
;	4 Tasten, 1 LED, beim Drücken der Taste1/2/3/4 wechselt der Zustand	;
;	der LED. Beim Halten der Taste2/3 automatisches Togglen der LED		;
;										;
;				                        			;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

.include "m8def.inc"
;--------------------------------------------------------------------------------
;               Definitionen
;-------------------------------------------------------------------------------- 
.def iwr0          = r1
.def iwr1          = r2
 
.def key_state     = r4
.def key_press     = r5
.def key_rep_press = r6
.def key_rep       = r16
 
.def temp1         = r17

.def leds      = r20
.equ led_port  = PORTD
.equ led_ddr   = DDRD
.equ LED = 0
.equ Taste1     = 0
.equ Taste2     = 1
.equ Taste3     = 2
.equ Taste4     = 3

.equ KEY_PIN    = PINB
.equ KEY_PORT   = PORTB
.equ KEY_DDR    = DDRB
 
.equ KEY_REPEAT_START = 50		; Dauer, die gewartet werden muss,
	                                ; bevor Autorepeat startet

.equ KEY_REPEAT_NEXT  = 30		; Togglefrequenz
 

;.equ XTAL  = 3686400
.equ XTAL  = 1000000

.org 0x0000
        rjmp    init
.org OVF0addr
        rjmp    timer_overflow0

;--------------------------------------------------------------------------------
;               Initilisierung
;--------------------------------------------------------------------------------
init:
        ldi      temp1, LOW(RAMEND)     ; Stackpointer initialisieren
        out      SPL, temp1
        ldi      temp1, HIGH(RAMEND)
        out      SPH, temp1
 
        ldi      temp1, 1<<LED          ; PD0 als Ausgang
        out      led_ddr, temp1
 
        ldi      temp1, (1<<Taste1)|(1<<Taste2)|(1<<Taste3)|(1<<Taste4)
        out      KEY_PORT, temp1        ; Tasten Eingang, Pullup Widerstände ein
 
        ldi      temp1, (1<<CS02)         ; Vorteiler 256
        out      TCCR0, temp1
        ldi      temp1, 1<<TOIE0			
        out      TIMSK, temp1
 
        clr      key_state
        clr      key_press
        clr      key_rep_press
        clr      key_rep
 
        ldi      leds, 1<<LED
        out      led_port, leds

;--------------------------------------------------------------------------------
;               Main loop
;-------------------------------------------------------------------------------- 
main:

;-------------- Einzelnen Tastendruckauswerten ----------------------------------
        cli
        mov     temp1, key_press
        clr     key_press
        sei
 
        cpi     temp1, 1<<Taste1       ; Nur dann wenn Taste 1 gedrückt wurde
        breq    toggle

        cpi     temp1, 1<<Taste2       ; Nur dann wenn Taste 2 gedrückt wurde
        breq    toggle

        cpi     temp1, 1<<Taste3       ; Nur dann wenn Taste 3 gedrückt wurde
        breq    toggle

        cpi     temp1, 1<<Taste4       ; Nur dann wenn Taste 4 gedrückt wurde
        breq    toggle
                                     
;-------------- Autorepeat auswerten --------------------------------------------
        cli
        mov      temp1, key_rep_press
        clr      key_rep_press
        sei

        cpi      temp1, 1<<Taste2	; Nur dann wenn Taste 2 gehalten wurde
        breq     toggle
 
        cpi      temp1, 1<<Taste3	; Nur dann wenn Taste 3 gehalten wurde
        breq     toggle

        rjmp     main

;--------------------------------------------------------------------------------
toggle:
        ldi      temp1, 1<<LED
        eor      leds, temp1 
        out      led_port, leds
        rjmp     main

;--------------------------------------------------------------------------------
;               Timer Overflow Interrupt
;--------------------------------------------------------------------------------
timer_overflow0:
        push    xl                              ; temporäre Register sichern
        in      xl, SREG
        push    xl
        
        push    r16
        ldi     r16, -( XTAL / 256 * 10 / 1000 + 1 )
        out     TCNT0, r16
        pop     r16
 
get8key:
        in      xl, KEY_PIN        		; Tasten einlesen
        com     xl                 		; gedrückte Taste werden zu 1
        eor     xl, key_state      		; nur Änderunden berücksichtigen
        and     iwr0, xl           		; in iwr0 und iwr1 zählen
        com     iwr0
        and     iwr1, xl
        eor     iwr1, iwr0
        and     xl, iwr0
        and     xl, iwr1
        eor     key_state, xl
        and     xl, key_state
        or      key_press, xl      		; gedrückte Taste merken
        tst     key_state          		; irgendeine Taste gedrückt ?
        breq    get8key_rep        		; Nein, Zeitdauer zurücksetzen
        dec     key_rep
        brne    get8key_finish;    		; Zeit abgelaufen?
        mov     key_rep_press, key_state
        ldi     key_rep, KEY_REPEAT_NEXT
        rjmp    get8key_finish
 
get8key_rep:
        ldi     key_rep, KEY_REPEAT_START
 
get8key_finish:
        pop     xl                 		; Register wiederherstellen
        out     SREG, xl
        pop     xl
        reti