.include "4433def.inc"   		;bzw. 2333def.inc

.org 0x000				; Programm kommt an Anfang von PROM

.def temp = r16				; temporäres Register definieren
.def cntrl = r17			; 16BIT Counter defineren
.def cntrh = r18
.def flanke = r19			; Flag für Signalflanke
.def flag = r20				; Steuer-Flag defineren
.def servoout = r21			; Wert der an Servo ausgegeben wird
.def temp1 = r22			; noch ein temp

initint:
		rjmp init		; RESET	
		reti			; IRQ0
		reti			; IRQ1
		rjmp timer		; T1 Capture
		reti			; T1 Compare
		rjmp overflow		; T1 Overflow
		rjmp pulse		; T0 Overflow
		reti			; SPI Transfer complete
		reti			; UART RX Complete
		reti			; UDR Empty
		reti			; UART TX Complete
		reti			; ADC complete
		reti			; EEPROM Ready
		reti			; Analog Comparator

init:
		ldi temp, RAMEND	
		out SPL, temp		;Stackpointer initialisieren
		
		ldi temp, 0b00000000
		out DDRB, temp		; Port B als Eingang

		ldi temp, 0b11111111
		out DDRD, temp		; Port D als Ausgang

		ldi temp, 0b11111111
		out PORTD, temp		; '1' an Port D


		sbi UCSRB, TXEN
		ldi temp, 4000000 /(9600*16)-1
		out UBRR,temp		; 9600 BAUD bei 4 MhZ

		ldi temp, 0b11000001
		out TCCR1B, temp	; Timer 1 auf kein Teiler stellen
					; setzt ICES1-Bit und ICNC1-Bit

		ldi flanke,1		; Flag für steigende Flanke setzen

		ldi temp, 1<<ICF1	 
		out TIFR, temp		; Timer 1 auf Capture stellen

		ldi flag, 4		; flag=4

		ldi servoout, 127	; Mittelstellung Servo
		
		ldi temp, 0b00000010	
		out TCCR0, temp		; T0 auf Clock Teiler 8

		ldi temp, 1
		out TCNT0, temp		; init for 500µs

		ldi temp, 0b00001010	
		out TIMSK, temp		; T1+T0 Interrupt initialisieren
	
		sei			; Interrupts freigeben

		rjmp main		; Programmstart

timer:
		push temp		
		
		rcall togglebit		; Capture-Flanke togglen
		
		in cntrl,ICR1L		
		in cntrh,ICR1H		; 16-Bit-Wert einlesen
		
		clr temp		; Rücksetzprozedur
		out TCNT1H, temp
		out TCNT1L, temp
		
		pop temp		; Register ausgeben
		reti

togglebit:	in temp, TCCR1B		
		bst temp, ICES1			
		brts toggletmp
		ori temp, 0b01000000
		out TCCR1B, temp
		ldi flanke,1		; steigende Flanke
		ret
toggletmp:	andi temp, 0b10111111
		out TCCR1B, temp
		ldi flanke,0		; fallende Flanke
		ret

convert:	; Konvertiert 8-BIT Binärzahl in Hex-ASCII
		push temp
		swap temp
		rcall convtmp
		rcall serout
		pop temp
		rcall convtmp
		rcall serout
		ret
convtmp:	andi temp,0b00001111 
		ori  temp,0b00110000
		cpi temp, '9'+1
		brcs convtmp1
		subi temp,-7	
convtmp1:	ret

serout:		; Schreibt auf serielle Schnittstelle
		sbis UCSRA,UDRE
		rjmp serout
		out UDR,temp
		ret

overflow:
		push temp
		ldi flanke, 0
		ldi temp, '*'		
		rcall serout
		ldi temp,13
		rcall serout
		ldi temp, 10
		rcall serout
		pop temp
		reti
pulse:
		push temp

		cpi flag, 0
		breq lowpulse

		cpi flag, 3
		brcs servoangle 	; Wert < 3 ?
		
		ldi temp, 0b11111111	
		out PORTD, temp		; '1' an Port D

		ldi temp, 0b00000010	
		out TCCR0, temp		; T0 auf CK 8

		ldi temp, 10		 
		out TCNT0, temp		; 500µs (gemessen) bei 4Mhz

		dec flag		; flag = flag - 1

	
		pop temp
		reti

servoangle:
		out TCNT0, servoout	; 2x servowert bei 4Mhz

		dec flag		; flag = flag - 1
	
		pop temp
		reti

lowpulse: 	; ausführen wenn flag auf 0
		ldi temp, 0b00000000
		out PORTD, temp		; '0' an Port D

		ldi flag, 4		; flag auf 4
		ldi temp, 0b00000101
		out TCCR0, temp		; T0 auf CK 1024

		ldi temp, 184
		out TCNT0, temp		; 18ms bei 4Mhz
	
		pop temp
		reti

main:
		nop			; Hauptprogramm

		cpi flanke, 1
		brne main		; nur ausgeben, wenn Impuls war

		mov temp1, cntrh
		andi temp1, 0b00001111
		mov temp, cntrl
		andi temp, 0b11110000
		or temp, temp1
		swap temp

		mov servoout, temp	; Kopplung zwischen Impulsmessung und Erzeugung
					; Hier kann Regelung etc. durchgeführt werden
		rcall convert
		ldi temp, 10
		rcall serout
		ldi temp, 13
		rcall serout

		rjmp main