; rfm12/stk500.asm
;
; Funkmodul rfm12
; senden:
; auf negative Flanke auf steckbrett
; empfangen
; auf STK500
; siehe Oszi Bild
; senden: 		5 mal Prolog, 3 mal Daten (1 Länge, 2 Nutzdaten)
; empfangen:	3 mal Daten (1 Länge, 2 Nutzdaten)
; in den isr Routinen für Senden/ empfangen werden bei Start und Ende Ports gesetzt
;
; Takt 14.7456MHz

                    .LIST								; Listing ausschalten
                    .INCLUDE    "m32def.inc"			; Deklaration für mega32
                    .LIST								; Listing einschalten
					
					; Softwaretimer
					.EQU	TIM_TMP = 0b_0001_0000		; tmp-Timer
					
					; USART Baudrate
					.EQU	USART_BAUDRATE      = 23	; USART: Baudrate 38400
					
;***************************************
;********** CSEG: Codesegment **********
;***************************************

                    .CSEG								; Programm Flash
                    rjmp    prgReset					; Reset Einsprung
					.ORG	INT0addr					; Einsprung INT0, externer Interrupt
					rjmp	isrRFM12					; RFM12 senden/ empfangen
                    .ORG    OVF0addr					; Timer 0 Überlauf Einsprung
                    rjmp    isrTIMER0					; nach Interrupt Service Programm
                    .ORG    INT_VECTORS_SIZE			; weitere Interrupt Einsprünge übergehen

;********************************************
;********** Hauptprogramm Hochlauf **********
;********************************************

prgReset:           ldi     r16,LOW(RAMEND)				; Stapel anlegen
                    out     SPL,r16            
                    ldi     r16,HIGH(RAMEND)
                    out     SPH,r16
					  
					call	subRegisterIni

; PORTS definieren
					; Debug
					; cbi		DDRD,PIND7					; Eingang: Taster

					sbi		DDRD,PORTD3					; Ausgang: LED grün
					sbi		DDRD,PORTD4					; Ausgang: LED gelb
					sbi		DDRD,PORTD5					; Ausgang: LED rot
					sbi		DDRD,PORTD6					; Ausgang: debug senden
					sbi		DDRD,PORTD7					; Ausgang: debug empfangen
					sbi		DDRB,PORTB0					; Ausgang: debug isr senden/ empfangen
                    sbi		DDRB,PORTB2					; Ausgang: debug isr senden
					sbi		DDRB,PORTB3					; Ausgang: debug isr empfangen
					
					; RFM12
					cbi		DDRB,PINB6				    ; Eingang MISO   <- SDO
					cbi		DDRD,PIND2				    ; Eingang PIND2  <- nIRQ 

					sbi		DDRB,PORTB4				    ; Ausgang nSS (muß gesetzt sein, wegen SPI Masterbetrieb)
					sbi		DDRB,PORTB5				    ; Ausgang MOSI   -> SDI
					sbi		DDRB,PORTB7				    ; Ausgang SCK    -> SCK
					sbi		DDRB,PORTB1				    ; Ausgang PORTB1 -> nSEL

; Ports setzen
					; Debug
					sbi		PORTD,PORTD3				; LED grün aus
					sbi		PORTD,PORTD4				; LED gelb aus
					sbi		PORTD,PORTD5				; LED rot aus

					cbi		PORTD,PORTD6				; Ausgang: debug senden
					cbi		PORTD,PORTD7				; Ausgang: debug empfangen
					cbi		PORTB,PORTB0				; Ausgang: debug isr senden/ empfangen
					cbi		PORTB,PORTB2				; Ausgang: debug isr senden
					cbi		PORTB,PORTB3				; Ausgang: debug isr empfangen	
					cbi		PORTB,PORTB4				; Ausgang: debug isr senden/ empfangen

					; RFM12
					sbi		PORTB,PORTB4			    ; Ausgang nSS (muß gesetzt sein, wegen SPI Masterbetrieb)
					sbi		PORTB,PORTB1			    ; Ausgang nSEL setzen
					
; SPI init
					ldi		r16,(1<<SPE) | (1<<MSTR) | (0<<SPR1) |(1<<SPR0) ; SPI frei, MSB erst
					out		SPCR,r16					; 
					ldi		r16,(1<<SPI2X)				; SPI2X=1, SPR1=0, SPR0=1: f(osc)/8 = 14.7456 MHz/8 = 1.8432 MHz
					out		SPSR,r16
					  
; Timerticks der Softwaretimer init
					call	subTimer16ini				; 16 Bit Timer initialisieren
					call	subTimer8ini				; 8 Bit Timer initialisieren

; TCNT0 init
					call	subTIMER0init
                    sei
; USART init                    
					ldi		r16,LOW(USART_BAUDRATE)
					ldi		r17,HIGH(USART_BAUDRATE)
					call	subUSARTini

; USART senden init                    
					call	subUSARTsendIni

; INT0 für RFM12 programmieren
					; RFM12
					in		r16,MCUCR					; MCU Steuerregister (MCU contol register)
					sbr		r16,1<<ISC01				; Interrupt INT0 auf fallende Flanke	
					cbr		r16,1<<ISC00	
					out		MCUCR,r16

					in		r16,GICR					; General Interrupt Control Register
					; cbr		r16,1<<INT0					; INT0 sperren
					sbr		r16,1<<INT0					; INT0 freigeben
					out		GICR,r16

; Wartezeit für Hochlauf RFM12
					ldi		r16,TIM_TMP
					ldi		r17, 100					; 100 mSek
					call	subDelay8

; RFM12, senden, empfangen initialisieren
					call	subRFM12paramIni			; RFM12 Parameter init
					call	subRFM12sendIni				; Senden init
					call	subRFM12recIni				; Empfangen init

					ldi		r16,1						; Testschrittkette, step 1: starte Empfang
					sts		tstStepCounter,r16				; stepCounter

; Wartezeit für Hochlauf
					cbi		PORTD,PORTD4				; LED gelb an

					ldi		r16,TIM_TMP
					ldi		r17, 250					; 1 Sek Wartezeit
					call	subDelay8
					call	subDelay8
					call	subDelay8
					call	subDelay8
					
					sbi		PORTD,PORTD4				; LED gelb aus     
					cbi		PORTD,PORTD3				; LED grün an
					               
;****************************************
;********** Hauptprogramm Loop **********
;****************************************

prgLoop:			; step1: Empfang starten
					lds		r17,tstStepCounter
					cpi		r17,1						; step 1: Empfang starten
					brne	prgStep2

					call	subClearRecData				; Empfangspuffer löschen

					ldi		r16,(1<<RFM12_REC_EXEC)		; Empfang starten
					sts		RFM12recCmdStat,r16

					ldi		r17,2						; next step: warten auf Empfangsende
					sts		tstStepCounter,r17
					rjmp	prgZyk

					; step2: warten auf Ende Empfang
prgStep2:			lds		r17,tstStepCounter
					cpi		r17,2						; step 2: warten auf Empfangsende
					brne	prgStep3

					lds		r16,RFM12recCmdStat
					andi	r16,(1<<RFM12_REC_IDLE)		; Empfang fertig ?
					brbs	SREG_Z,prgZyk				; nein: springe

					call	subDebTraceD5				; LED rot

					ldi		r16,22						; Kennung: 20: STK500, 2: empfangen
					call	subCopRecDataRS232			; Traceausgabe
					
					call	subUSARTsend
					
					ldi		r17,3						; next step: Sender einschalten
					; ldi		r17,1					; next step: Empfang starten
					
					sts		tstStepCounter,r17
					rjmp	prgZyk
					
					; step3: Sender einschalten
prgStep3:			lds		r17,tstStepCounter
					cpi		r17,3						; step 3: Sender einschalten
					brne	prgStep4

					call	subInitSendData				; Sendedaten vorbereiten
					
					ldi		r16,(1<<RFM12_SEND_EXEC)    ; senden starten
					sts		RFM12sendCmdStat,r16
					
					ldi		r17,4
					sts		tstStepCounter,r17			; next step: warten auf Sendenende
					rjmp	prgZyk						; Aussprung					
					
					; step4: warten auf Sendenende
prgStep4:			lds		r17,tstStepCounter
					cpi		r17,4						; step 4: warten auf Sendenende
					brne	prgZyk
					
					lds		r16,RFM12sendCmdStat
					andi	r16,(1<<RFM12_SEND_IDLE)	; Senden fertig ?
					brbs	SREG_Z,prgZyk				; nein: springe

					call	subDebTraceD4				; LED gelb					

					ldi		r17,1						; next step: Empfang starten
					; ldi		r17,10						; next step: ab in den Wald
					sts		tstStepCounter,r17
					rjmp	prgZyk						; Aussprung					
	
prgZyk:				call 	subRFM12Rec
					call 	subRFM12Send
					rjmp	prgLoop

;*************************************
;********** subClearRecData **********
;*************************************
; löscht die RFM12 Empfangsdaten, 11 Bytes
; Byte0: Länge, Byte1..Byte10: Daten

subClearRecData:  	push    r16
					push	r17
					push	XL
					push	XH
					
					ldi		XL,LOW(RFM12recData)		; RFM12 Empfangsdaten
					ldi		XH,HIGH(RFM12recData)		;
					
					clr		r16		
					ldi		r17,11						; 11: Feldlänge
					
subClRecDatLoop:	st		X+,r16
					dec		r17
					brbc	SREG_Z,subClRecDatLoop		; noch nicht fertig:  springe

					pop		XH
					pop		XL
					pop		r17
					pop		r16
					ret

;************************************
;********** subCopSendData **********
;************************************
; kopiert die empfangenen Daten in die Sendedaten

subCopSendData:  	push    r16
					push	r17
					push	XL
					push	XH
					push	YL
					push	YH
					
					ldi		XL,LOW(RFM12recData)		; RFM12 Empfangsdaten
					ldi		XH,HIGH(RFM12recData)		;
					ldi		YL,LOW(RFM12sendData)		; RFM12 Sendedaten
					ldi		YH,HIGH(RFM12sendData)		;
	
					ldi		r17,11						; 11: Feldlänge
					
subCoSendDatLoop:	ld		r16,X+
					st		Y+,r16
					dec		r17
					brbc	SREG_Z,subCoSendDatLoop		; noch nicht fertig:  springe

					pop		YH
					pop		YL
					pop		XH
					pop		XL
					pop		r17
					pop		r16
					ret


;*************************************
;********** subInitSendData **********
;*************************************
; initialisert die Sendedaten

subInitSendData:  	push    r16
					push	YL
					push	YH

					ldi		YH,HIGH(RFM12sendData)		; RFM12 Senden starten
					ldi		YL,LOW(RFM12sendData)		; Sendedaten

					ldi		r16,2						; Länge der Nutzdaten
					st		Y+,r16
					
					ldi		r16,0b_1111_0000			; Nutzdaten
					st		Y+,r16
					
					ldi		r16,0b_0000_1111			; Nutzdaten
					st		Y+,r16

					pop		YH
					pop		YL
					pop		r16
					ret

;****************************************
;********** subCopRecDataRS232 **********
;****************************************
; kopiert 10 Bytes Empfangsdaten nach
; RS232 Puffer, für Debugausgabe
; Eingang
; r16 12: Empfangsdaten auf steckbrett, 22: Empfangsdaten auf STK500

subCopRecDataRS232:	push    r16
					push	r17
					push	XL
					push	XH
					push	YL
					push	YH
					
					ldi		XL,LOW(RFM12recData)		; RFM12 Empfangsdaten
					ldi		XH,HIGH(RFM12recData)		;					
					ldi 	YL,LOW(USARTsendData)		; Adresse RS232 Daten
					ldi 	YH,HIGH(USARTsendData)

					ld		r17,X+						; Länge Nutzdaten
					inc		r17							; wegen Kennung Empfänger	
					st		Y+,r17

					st		Y+,r16						; Kennung Empfänger (12, 22)

					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17
					ld		r17,X+						; Nutzdaten				
					st		Y+,r17

					pop		YH
					pop		YL
					pop		XH
					pop		XL
					pop		r17
					pop		r16
					ret

;****************************************
;********** DSEG: Datensegment **********
;****************************************
					.DSEG

tstStepCounter:		.BYTE	1							; Testschrittzähler

;*****************************
;********** includes **********
;******************************
					.INCLUDE    "bibTimer.asm"		
					.INCLUDE    "bibMisc.asm"
					.INCLUDE    "bibRFM12.asm"
					.INCLUDE	"bibDebug.asm"
					.INCLUDE	"bibUSART.asm"		
					.EXIT