; general device setup
; this is for the ATtiny 13
.NOLIST                ; Disable listfile generation 
.include "tn13def.inc"
.LIST
; light control for my shack 
; simple timeouter desactivates the TRIAC if not switched off before
;
; constants @ 600 kHz clk 
;
.equ	ROMSTART	= 0x0100
.equ	RAMSTART	= SRAM_START
.equ	cr		= 0x0d
.equ	lf		= 0x0a
.equ	SECOND		= 0x68		; roughly a second with wozwait
.equ	THIRDSECOND		= 0x48		; roughly a third of a second with wozwait
.equ 	MAXTIME	= 5		; 111 seconds multiple by this is the timeout
; hardware ports
.equ	Monkey 	= 1		; MonkeyLives, positive logic (high = on)
.equ	LightOut	= 2	; Activate Light via MOC3063, low is ON
.equ	OptoIn 	= 3		; historic designation, you could connect a pushbutton to reset the timer
; 

; immediate registers
.def	temp	= r16	;misc usage, must be in upper regs for IMMED mode
.def	tempirq	= r17	;misc usage, higher byte for word access
.def	del	= r18	; delay counter
.def	counterlo = r20	; long counter
.def	counterhi = r21
.def 	irqstor = r22

.def    flags = r24	; flags
.equ	lighton = 0x80	;lights are on
.equ	lightonbit = 7 ; 
.equ	sens	= 0x40	; from Optocoupler
.equ	sensbit = 6 ;


; **************   MAIN PROGRAM STARTS HERE *************************
.CSEG 
	.ORG	0x0
 	rjmp 	RESET 		; Reset Handler
 	rjmp 	EXT_INT0 	; IRQ0 Handler
 	rjmp 	PC_INT0 	; PCINT0 Handler
 	rjmp 	TIM0_OVF 	; Timer0 Overflow Handler
 	rjmp 	EE_RDY 		; EEPROM Ready Handler
 	rjmp 	ANA_COMP 	; Analog Comparator Handler
 	rjmp 	TIM0_COMPA 	; Timer0 CompareA Handler
 	rjmp 	TIM0_COMPB 	; Timer0 CompareB Handler
 	rjmp 	WATCHDOG 	; Watchdog Interrupt Handler
 	rjmp 	ADC_INT 	; ADC Conversion Handler


TIM0_OVF:
	in 		irqstor,SREG
	sbi		PINB, Monkey		; the monkey lives bit
	inc		counterlo		; gearbox 1
	brne	tim0a	
	inc		counterhi		; gearbox 2
	cpi		counterhi,MAXTIME	; is counterhi lower than maxtime?
	brcs	tim0a				; if yes, exit 
	cbr		flags,lighton		; else signal light off
	in 		tempirq,TIMSK0			
	cbr		tempirq,(1<<TOIE0)
	out		TIMSK0,tempirq		; block me	
	out 	TIFR0,tempirq		; clr pending
	clr		tempirq
	out 	TCCR0B,tempirq		; stop the timer
	cbi		PORTB,Monkey		; clr the monkey

	rjmp	tim0a
; this should retrigger the timeouter (optional Push button input)
PC_INT0:
	in 		irqstor,SREG
	clr		counterlo
	clr		counterhi
	sbr		flags,lighton
	clr		tempirq
	out 	TCNT0,tempirq
	in		tempirq,TIMSK0
	sbr		tempirq,(1<<TOIE0)
	out		TIMSK0,tempirq		; enable timer irq
	out		TIFR0,tempirq		; clr pending
	ldi		tempirq,(1<<CS02)|(0<<CS01)|(1<<CS00)	
	out 	TCCR0B,tempirq		; and run the timer again

tim0a:
	out 	SREG,irqstor
; 
; stubs
EXT_INT0:
EE_RDY:
ANA_COMP:
ADC_INT:
TIM0_COMPA:
TIM0_COMPB: 
WATCHDOG:	RETI
; 
RESET:
; init stack
	ldi		temp, low(RAMEND)
	out		SPL, temp
	clr		flags
	rcall 	init_ports
	cbi		PORTB, LightOut			; start the light
	sbr		flags,lighton
	sei

main:
	rcall	thirdsec
	sbrs	flags, lightonbit
	sbi		PORTB,LightOut		; off the lights
	sbrc	flags, lightonbit
	cbi		PORTB,LightOut		; on the lights
	rjmp	main
			

; steve wozniak's wait routine - this time for AVR 
; this is the extended routine with del^3 
; this wait routine is ingenious and handles wide ranges of delay 
; as a hommage to steve i port it to all my embedded systems. 
thirdsec: 
		ldi	del,THIRDSECOND
wozwait: push	del
wwait2:	push	del
wwait1:	subi	del,1	
		brne	wwait1
		pop		del
		subi	del,1
		brne	wwait2
		pop		del
		subi	del,1
		brne	wozwait
		ret


init_ports:
	ldi	temp,(1 << LightOut)|(0 << OptoIn)|(1 << Monkey)	; Set Outputs and Inputs
	out	DDRB,temp		; set
	sbi	PortB,OptoIn		; use the pull-ups
	ldi	del,0x10		; first settle 
	rcall	wozwait
; timer set on longest period possible
init_timer:
	clr counterlo
	clr	counterhi
	clr	temp
	out TCCR0A,temp
	out TCNT0,temp
	ldi	temp,(1<<CS02)|(0<<CS01)|(1<<CS00)
	out TCCR0B,temp
	ldi temp, (1<<TOIE0)	; enable the irq
	out TIFR0, temp			; clr pendings
	out TIMSK0, temp
; pinchange interrupt on OptoIn
init_pci:
	ldi	temp,(1<<OptoIn)	; enable that pin
	out	PCMSK,temp
	ldi	temp,(1<<PCIE)		; general pci enable
	out	GIMSK,temp			
	out	GIFR,temp		; clr pendings
	ldi	del,0x10		; first settle 
	rcall	wozwait
	ret