;OK TV Remote
;
;Format NEC
;
;The NEC IR transmission protocol uses pulse distance encoding of the message bits. Each pulse burst (mark – RC transmitter ON) is 562.5µs in length,
;at a carrier frequency of 38kHz (26.3µs). Logical bits are transmitted as follows:
;
;Logical '0' – a 562.5µs pulse burst followed by a 562.5µs space, with a total transmit time of 1.125ms
;Logical '1' – a 562.5µs pulse burst followed by a 1.6875ms space, with a total transmit time of 2.25ms
;
;When a key is pressed on the remote controller, the message transmitted consists of the following, in order:
;
;a 9ms leading pulse burst (16 times the pulse burst length used for a logical data bit)
;a 4.5ms space
;the 8-bit address for the receiving device
;the 8-bit logical inverse of the address
;the 8-bit command
;the 8-bit logical inverse of the command
;a final 562.5µs pulse burst to signify the end of message transmission.
;The four bytes of data bits are each sent least significant bit first.

;------------------------------------------------------------------------------------------
;Pinout ATTiny24
;       -------U-------
;   VCC |1  VCC GND 14| GND
;       |2  PB0 PA0 13| SW1
;       |3  PB1 PA1 12| SW2
;       |4  PB3 PA2 11| SW3
;IR-LED |5  PB2 PA3 10| SW4
;       |6  PA7 PA4  9| SW5
;   SW7 |7  PA6 PA5  8| SW6
;       ---------------
;
;------------------------------------------------------------------------------------------

;SW1	POWER / INPUT
;SW2	CH+ / UP
;SW3	CH- / DOWN
;SW4	VOL+ / RIGHT
;SW5	VOL- / LEFT
;SW6	MUTE / OK
;SW7	ALT

; CPUFREQ: RC OSC 8MHz

.include "tn24def.inc"

.def cmd_2 = R0
.def cmd_1 = R1
.def adr_2 = R2
.def adr_1 = R3
.def temp = R16
.def key = R17
.def count = R18
.def alt_flag = R19

.org 0x0000

			rjmp init

.org PCI0addr
			rjmp PCINT_ISR

init:

;setup stack
			ldi temp, LOW(RAMEND)
			out SPL, temp

;setup ports
			ldi temp, 0x00
			out DDRA, temp	;Port A input
			ldi temp, 0xff
			out PORTA, temp ;enable pullups

			ldi temp, 0b00000000
			out DDRB, temp	;Port B input
			ldi temp, 0b00000011
			out PORTB, temp	;enable pullups


;setup timer 0: 38 kHz on OC0A Pin PB2 @ 8MHz
			ldi temp, 105+1
			
			out OCR0A, temp
			ldi temp, 1<<WGM01 | 1<<COM0A0	;CTC Mode, Toggle OC0A-Pin on compare match
			out TCCR0A, temp
			ldi temp, 1<<CS00
			out TCCR0B, temp

;shut down analog comparator
			in temp,ACSR
			sbr temp, 1<<ACD
			out ACSR, temp

;clear ALT-Flag
			clr alt_flag

;------------------------------------------------------------------------------------------

main:
;enable PCINT 0-6
			cli
			ldi temp, 1<<PCINT0 | 1<<PCINT1 | 1<<PCINT2 | 1<<PCINT3 | 1<<PCINT4 | 1<<PCINT5 | 1<<PCINT6
			out PCMSK0, temp
			ldi temp, 1<<PCIE0
			out GIMSK, temp

;clear interrupt flag
			in temp, GIFR
			sbr temp, 1<<PCIF0
			out GIFR, temp

;power down mode
			ldi temp, 1<<SM1 | 1<<SE
			out MCUCR, temp

			sei

			sleep

			rjmp main
;------------------------------------------------------------------------------------------

;getkey
getkey:

;check ALT Key Status
			cpi alt_flag, 1
			breq key_2

key_1:
			cpi key, 0b00111110	;key "Power"
			breq k_pwr
			cpi key, 0b00111101	;key "CH+"
			breq k_ch_inc
			cpi key, 0b00111011	;key "CH-"
			breq k_ch_dec
			cpi key, 0b00110111	;key "Vol+"
			breq k_vol_inc
			cpi key, 0b00101111	;key "Vol-"
			breq k_vol_dec
			cpi key, 0b00011111	;key "Mute"
			breq k_mute

			ldi key, 0
			ret

key_2:
			cpi key, 0b00111110	;key "Input"
			breq k_input
			cpi key, 0b00111101	;key "Up"
			breq k_up
			cpi key, 0b00111011	;key "Down"
			breq k_down
			cpi key, 0b00110111	;key "Right"
			breq k_right
			cpi key, 0b00101111	;key "Left"
			breq k_left
			cpi key, 0b00011111	;key "OK"
			breq k_ok

			ldi key, 0
			ret

k_pwr:
			;TV on/off
			ldi ZL, LOW(b_power*2)
			ldi ZH, HIGH(b_power*2)
			rjmp load_code


k_ch_inc:
			;CH+
			ldi ZL, LOW(b_ch_inc*2)
			ldi ZH, HIGH(b_ch_inc*2)
			rjmp load_code

k_ch_dec:
			;CH-
			ldi ZL, LOW(b_ch_dec*2)
			ldi ZH, HIGH(b_ch_dec*2)
			rjmp load_code

k_vol_inc:
			;VOL+
			ldi ZL, LOW(b_vol_inc*2)
			ldi ZH, HIGH(b_vol_inc*2)
			rjmp load_code

k_vol_dec:
			;VOL-
			ldi ZL, LOW(b_vol_dec*2)
			ldi ZH, HIGH(b_vol_dec*2)
			rjmp load_code

k_mute:
			;MUTE
			ldi ZL, LOW(b_mute*2)
			ldi ZH, HIGH(b_mute*2)
			rjmp load_code

k_input:
			;Input
			ldi ZL, LOW(b_input*2)
			ldi ZH, HIGH(b_input*2)
			rjmp load_code

k_up:
			;UP
			ldi ZL, LOW(b_up*2)
			ldi ZH, HIGH(b_up*2)
			rjmp load_code

k_down:
			;DOWN
			ldi ZL, LOW(b_down*2)
			ldi ZH, HIGH(b_down*2)
			rjmp load_code

k_right:
			;RIGHT
			ldi ZL, LOW(b_right*2)
			ldi ZH, HIGH(b_right*2)
			rjmp load_code

k_left:
			;LEFT
			ldi ZL, LOW(b_left*2)
			ldi ZH, HIGH(b_left*2)
			rjmp load_code

k_ok:
			;OK
			ldi ZL, LOW(b_ok*2)
			ldi ZH, HIGH(b_ok*2)
			rjmp load_code

load_code:
			lpm adr_1, Z+
			lpm adr_2, Z+
			lpm cmd_1, Z+
			lpm cmd_2, Z
			rcall send_seq
			ret

;------------------------------------------------------------------------------------------

PCINT_ISR:
; disable PCINT

			ldi temp, 0
			out GIMSK, temp

			rcall delay15ms	;debounce
			in key, PINA
			andi key, 0b01111111

			cpi key, 0b00111111	;check if ALT is pressed
			brne keyin
alt_loop:
			sbis PINA, PA6	;wait for ALT is released
			rjmp alt_loop


;toggle ALT-Flag
			ldi temp, 1
			eor alt_flag, temp
			cpi alt_flag, 0
			brne alt_2flash
;flash LED 1 time
			sbi DDRB, PB2				;turn IR LED on 
			rcall delay15ms
			cbi DDRB, PB2				;turn IR LED off
			rjmp alt_exit
;flash LED 2 times
alt_2flash:
			sbi DDRB, PB2				;turn IR LED on 
			rcall delay15ms
			cbi DDRB, PB2				;turn IR LED off
			rcall delay100ms
			rcall delay100ms
			sbi DDRB, PB2				;turn IR LED on 
			rcall delay15ms
			cbi DDRB, PB2				;turn IR LED off

alt_exit:
			rcall delay100ms
			rcall delay100ms
			rcall delay100ms
			rcall delay100ms
			rjmp int_exit

keyin:
			andi key, 0b00111111	;mask alt-key out

			rcall getkey	;decode key and send IR

			rcall delay40ms
			in temp, PINA
			andi temp, 0b00111111
			cp temp, key	;is the same key still pressed?
			brne int_exit	;exit IRQ
			rcall send_repeat	;send "Repeat" command

repeat100:
			rcall delay100ms
			in temp, PINA
			andi temp, 0b00111111
			cp temp, key	;is the same key still pressed?
			brne int_exit
			rcall send_repeat
			rjmp repeat100

int_exit:
			rcall delay100ms	;debounce
			in temp, GIFR
			sbr temp, PCIF0	;clear interrupt flag
			out GIFR, temp

			reti

;------------------------------------------------------------------------------------------

delay562us:
;setup timer 1: @8MHz
			ldi temp, 0x11		;preload OCR1A
			out OCR1AH, temp
			ldi temp, 0x76
			out OCR1AL, temp

			;clear timer
			ldi temp, 0
			out TCNT1H, temp
			out TCNT1L, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A

			ldi temp, 1<<WGM12 | 1<<CS10	;start timer, CTC mode, no prescaler
			out TCCR1B, temp

			;wait for timer matches OCR1A (OCF1A flag)
loop1:
			sbis TIFR1, OCF1A
			rjmp loop1

			;stop timer
			ldi temp, 0
			out TCCR1B, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A

			ret
;------------------------------------------------------------------------------------------

delay15ms:
;setup timer 1: @8MHz
			ldi temp, 0x3a		;preload OCR1A
			out OCR1AH, temp
			ldi temp, 0x98
			out OCR1AL, temp

			;clear timer
			ldi temp, 0
			out TCNT1H, temp
			out TCNT1L, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A 

			ldi temp, 1<<WGM12 | 1<<CS11	;start timer, CTC mode, prescaler /8
			out TCCR1B, temp

			;wait for timer matches OCR1A (OCF1A flag)
loop2:
			sbis TIFR1, OCF1A
			rjmp loop2

			;stop timer
			ldi temp, 0
			out TCCR1B, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A 
			ret

delay40ms:
;setup timer 1: @8MHz
			ldi temp, 0x13		;preload OCR1A
			out OCR1AH, temp
			ldi temp, 0x88
			out OCR1AL, temp

			;clear timer
			ldi temp, 0
			out TCNT1H, temp
			out TCNT1L, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A 

			ldi temp, 1<<WGM12 | 1<<CS11 | 1<<CS10	;start timer, CTC mode, prescaler /64
			out TCCR1B, temp

			;wait for timer matches OCR1A (OCF1A flag)
loop3:
			sbis TIFR1, OCF1A
			rjmp loop3

			;stop timer
			ldi temp, 0
			out TCCR1B, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A 
			ret

delay100ms:
;setup timer 1: @8MHz
			ldi temp, 0x30		;preload OCR1A
			out OCR1AH, temp
			ldi temp, 0xd4
			out OCR1AL, temp

			;clear timer
			ldi temp, 0
			out TCNT1H, temp
			out TCNT1L, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A 

			ldi temp, 1<<WGM12 | 1<<CS11 | 1<<CS10	;start timer, CTC mode, prescaler /64
			out TCCR1B, temp

			;wait for timer matches OCR1A (OCF1A flag)
loop4:
			sbis TIFR1, OCF1A
			rjmp loop4

			;stop timer
			ldi temp, 0
			out TCCR1B, temp

			;clear OCF1A flag
			sbi TIFR1, OCF1A 
			ret

;------------------------------------------------------------------------------------------

send_seq:
			ldi count, 32
			rcall send_start
rotate:
			lsr cmd_2
			ror cmd_1
			ror adr_2
			ror adr_1

			brcs one
zero:
			rcall send_L
			rjmp next_bit
one:
			rcall send_H

next_bit:
			dec count
			cpi count, 0
			breq done
			rjmp rotate
done:
			rcall send_stop

			ret
;------------------------------------------------------------------------------------
send_H:									;562µs pulse burst, 1686µs space
			sbi DDRB, PB2				;turn IR LED on
			rcall delay562us
			cbi DDRB, PB2				;turn IR LED off
			rcall delay562us
			rcall delay562us
			rcall delay562us
			ret

send_L:									;562µs pulse burst, 562µs space
			sbi DDRB, PB2				;turn IR LED on
			rcall delay562us
			cbi DDRB, PB2				;turn IR LED off
			rcall delay562us
			ret		

send_start:							;9ms pulse burst, 4,5ms space
			sbi DDRB, PB2				;turn IR LED on
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us

			cbi DDRB, PB2				;turn IR LED off
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us

			ret

send_stop:
			sbi DDRB, PB2				;turn IR LED on
			rcall delay562us
			cbi DDRB, PB2				;turn IR LED off
			ret

send_repeat:							;9ms pulse burst, 2,3ms space
			sbi DDRB, PB2				;turn IR LED on
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			cbi DDRB, PB2				;turn IR LED off
			rcall delay562us
			rcall delay562us
			rcall delay562us
			rcall delay562us
			sbi DDRB, PB2				;turn IR LED on
			rcall delay562us
			cbi DDRB, PB2				;turn IR LED off
			ret
;------------------------------------------------------------------------------------

;RC keycodes
b_power:		.db 0xa0, 0x5f, 0x1c, 0xe3
b_ch_inc:		.db 0xa0, 0x5f, 0x03, 0xfc
b_ch_dec:		.db 0xa0, 0x5f, 0x1f, 0xe0
b_vol_inc:		.db 0xa0, 0x5f, 0x40, 0xbf
b_vol_dec:		.db 0xa0, 0x5f, 0x5d, 0xa2
b_mute:			.db 0xa0, 0x5f, 0x5f, 0xa0

b_input:		.db 0xa0, 0x5f, 0x1a, 0xe5
b_up:			.db 0xa0, 0x5f, 0x59, 0xa6
b_down:			.db 0xa0, 0x5f, 0x51, 0xae
b_right:		.db 0xa0, 0x5f, 0x14, 0xeb
b_left:			.db 0xa0, 0x5f, 0x56, 0xa9
b_ok:			.db 0xa0, 0x5f, 0x55, 0xaa

;signature
signature:
.DB "OK-TV Remote Control 28.07.2023 B. Wieck"