; *******************************************************************
;
; Projekt		Drehzahlmesser
; Datum			Dez.2023
; Prozessor		ATmega328p			Takt: 8 MHz ext
;
; Drehzahlmesser und Umdrehungszähler
;		für Einspritzpumpen-Prüfstand
;
; Anzeige mit 7-Segment-LED		Multiplex
;
; -------------------------------------------------------------------
; Ausgänge
;	Port-D	7-Segment-LED	/ PD7 .. 0		1 = aktiv
;	Port-B	Multiplex		/ PB3 .. 0		1 = aktiv
;
; Eingänge									aktiv = 0
;	PinC0	Hallsensor
;	PinC1	Modus,	0 = Drehzahl		(geschaltet)
;					1 = Umdrehungen
;	PinC2	Zähler 'Nullen'
;
; *******************************************************************

.DEF	ar	= r16		; Arbeitsregister
.DEF	dr	= r17		; Datenregister
.DEF	zi	= r18		; Anzeige - Ziffer
.DEF	seg	= r19		; Anzeige - Segment
.DEF	zsp	= r20		; Zwischenspeicher
.DEF	z4	= r21		; 1000er  Stelle
.DEF	z3	= r22		; 100er   Stelle
.DEF	z2	= r23		; 10er    Stelle
.DEF	z1	= r24		; 1er     Stelle

.DEF	ir	= r2		; Interruptregister
.DEF	za	= r3		; za, zb für
.DEF	zb	= r4		; Pausen-Schleife
.DEF	null = r5		; Null für Z-Pointer ADD
.DEF	imp1 = r6		; r6, r7
.DEF	imp2 = r7		; Zählimpulse

; Timer1 starten und stoppen
.EQU	Ti_on	= (1<<WGM12)|(1<<CS11)|(1<<CS10)
.EQU	Ti_off	= (1<<WGM12)|(0<<CS11)|(0<<CS10)

.ORG	$00
	rjmp	init

.ORG	OVF0addr
	rjmp	Multiplex

.ORG	OC1Aaddr
	rjmp	Tacho_Takt

.ORG	PCI1addr
	rjmp	Counter

.CSEG
.ORG	$34

init:
	ldi		ar,Low(RAMEND)
	out		SPL,ar
	ldi		ar,High(RAMEND)
	out		SPH,ar

; im DDR (Daten-Richtungs-Register)
; (1) - Port auf Ausgang setzen
; (0) - Port auf Eingang setzen
;		Pin's auf '0' = Pullup-Widerstände aus
;		Pin's auf '1' = Pullup-Widerstände eingeschaltet

	ldi		ar,0xFF
	out		DDRD,ar
	out		DDRB,ar
	ldi		ar,0x00
	out		DDRC,ar
	ldi		ar,0b00000111
	out		PortC,ar

	ldi		zi,3			; Startwerte für die Anzeige
	ldi		seg,0x08
	ldi		z1,8
	ldi		z2,8
	ldi		z3,8
	ldi		z4,8
	ldi		zsp,0
	ldi		ar,0
	mov		null,ar
	mov		imp1,ar
	mov		imp2,ar

; Timer0 = Takt für Multiplex-Anzeige
	ldi		ar,(1<<CS00)|(1<<CS01)			; Vorteiler 64
	out		TCCR0B,ar
	ldi		ar,(1<<TOIE0)
	sts		TIMSK0,ar

; Timer1 = Takt für die Drehzahlberechnung
	ldi		ar,0x3D							; 0,5-sek-Takt
	sts		OCR1AH,ar
	ldi		ar,0x09							; 3D09 (15625)
	sts		OCR1AL,ar
	ldi		ar,(1<<OCIE1A)
	sts		TIMSK1,ar

; ext. Pin-Wechsel-Interrupt
;		mit PCMSK werden die Pin's aktiviert
;			PCMSK0	= PCint0  .. 7	
;			     1	= PCint8  .. 14
;			     2	= PCint16 .. 23
;		die Maske gleicht der Interrupt-Adresse und Enabled-Bit
;	   z.B. PCMSK2 = PCI2addr = PCIE2
	ldi		ar,(1<<PCINT8)
	sts		PCMSK1,ar
	ldi		ar,(1<<PCIE1)	; Interrupt aktivieren
	sts		PCICR,ar
	sei

programm:
	sbis	PinC,1					; Modus
	rcall	tacho
	sbic	PinC,2					; Zähler-Reset
	rjmp	programm
	rcall	nullen
	rjmp	programm

; Drehzahl-Modus -- Timer aktivieren
tacho:
	ldi		ar,Ti_on
	sts		TCCR1B,ar				; Timer starten

	sbis	PinC,1
	rjmp	PC -1

	ldi		ar,Ti_off
	sts		TCCR1B,ar				; Timer stoppen
	ret

; Teiler-Schleife für Umdrehungen:	teilt die Impulse durch 6
;									und zählt 4 Ziffern
teiler:
	ldi		ar,6
	cp		imp1,ar
	brlo	teiler_end
	clr		imp1
	inc		z1
	cpi		z1,10
	brlo	teiler_end
	clr		z1
	inc		z2
	cpi		z2,10
	brlo	teiler_end
	clr		z2
	inc		z3
	cpi		z3,10
	brlo	teiler_end
	clr		z3
	inc		z4
	teiler_end:
	ret

; Zählerstand löschen
nullen:
	dec		za				; Pause 25ms
	brne	PC -1
	dec		zb
	brne	PC -3
	sbic	PinC,2
	rjmp	nullen_end
	ldi		z1,0
	ldi		z2,0
	ldi		z3,0
	ldi		z4,0
	ldi		ar,0
	mov		imp1,ar
	mov		imp2,ar
	sbis	PinC,2
	rjmp	PC -1
	nullen_end:
	ret

; Impulse zählen
Counter:
	inc		imp1			; Sensor-Impuls
	sbic	PinC,1
	rcall	teiler
	reti

; Takt für Drehzahl-Berechnung
Tacho_Takt:
	in		ir,SREG
	mov		z1,imp2			; imp2 - Impulse der vorigen Messung
	mov		imp2,imp1		; Impulse für die nächste Messung speichern
	add		z1,imp1
	clr		imp1			; imp1 - für nächste Messung löschen

; 3 stellige Zahl zerlegen
; 1er - Stelle immer '0'
	ldi		z4,0xFF
	ldi		z3,0xFF
	sub100:
	inc		z4				; 1000_er
	subi	z1,(100)
	brcc	sub100
	subi	z1,(-100)
	sub10:
	inc		z3				; 100_er
	subi	z1,(10)
	brcc	sub10
	subi	z1,(-10)
	mov		z2,z1			; 10_er
	ldi		z1,0			; 1_er immer 0
	out		SREG,ir
	reti

; Bitmuster der Ziffern im SRAM ablegen
Multiplex:
	in		ir,SREG
	cpi		zi,3			; letzte Ziffer angezeigt
	brlo	anzeige			; Zahl neu einlesen
	mov		dr,z4
	add		zsp,z4
	cpi		zsp,0			; führende '0' unterdrücken
	brne	PC + 2			; Bitmuster '00000000' laden
	ldi		dr,10			; Byte 10 in der Datenbank
	rcall	code
	sts		zi_4,dr			; im SRAM speichern
	mov		dr,z3
	add		zsp,z3
	cpi		zsp,0
	brne	PC + 2
	ldi		dr,10
	rcall	code
	sts		zi_3,dr
	mov		dr,z2
	add		zsp,z2
	cpi		zsp,0
	brne	PC + 2
	ldi		dr,10
	rcall	code
	sts		zi_2,dr
	mov		dr,z1
	rcall	code
	sts		zi_1,dr
	clr		zsp
	anzeige:				; Bitmuster laden
	rcall	anz_treiber
	out		PortB,seg
	ldi		ZL,low(zi_1)
	ldi		ZH,high(zi_1)
	add		ZL,zi
	adc		ZH,null
	ld		dr,Z			; mit "ld" Laden vom SRAM
	out		PortD,dr		; Bitmuster ausgeben
	out		SREG,ir
	reti

; Bit für nächste Ziffer verschieben
anz_treiber:
	inc		zi
	clc
	rol		seg
	cpi		seg,0x10
	brlo	anz_end
	ldi		seg,1
	ldi		zi,0
	anz_end:
	ret

; Bitmuster aus der Datenbank laden
code:
  	ldi		ZL,Low(2*led)
	ldi		ZH,High(2*led)
	add		ZL,dr
	adc		ZH,null
	lpm		dr,Z		; mit "lpm" laden aus der
	ret					; Datenbank

; Bitmuster für die 7-Segment-Anzeige
led:
	.db		0b00111111,0b00000110 	; 0 - 1
	.db		0b01011011,0b01001111	; 2 - 3
	.db		0b01100110,0b01101101	; 4 - 5
	.db		0b01111101,0b00000111	; 6 - 7
	.db		0b01111111,0b01100111	; 8 - 9
	.db		0b00000000,0b00000000	; Byte 10, 11
									; ohne führende null

.DSEG
; Bitmuster im SRAM speichern

zi_1:	.byte	1	;   1er Stelle
zi_2:	.byte	1	;  10er Stelle
zi_3:	.byte	1	; 100er Stelle
zi_4:	.byte	1	;1000er Stelle