;****************************************************************************
;*																			*
;*				LCD Controller für 4Graustufen (nach Benedikt)				*
;*																			*
;****************************************************************************
;

.NOLIST
.INCLUDE "m162def.inc"			
.LIST

.def Null			=r1
.def Fuellung		=r15		;Füllfarbe

.def temp			=r16		
.def temp1			=r17
.def temp2			=r18
.def YCnt			=r19		;Zeilenzähler 

;Takt
.equ F_CPU			=16000000

;Framerate
.equ	F_rate		=85

;LCD_Pixel
.equ XSize			=320		;Bildgröße in X Richtung in Pixel
.equ YSize			=240		;Bildgröße in Y Richtung pro Bild

.equ XOScan			=0			;Anzahl der zusätzlich auszugebenden Bytes in X Richtung
.equ YOScan			=0			;Anzahl der zusätzlich auszugebenden Zielen in Y Richtung 

.equ GrayCnt		=3

;ext. RAM
.equ YMin			=5			;ext. Speicher beginnt ab 10100000000 = 0x500
.equ YMax			=YMin+YSize
.equ YScan			=YMin+YSize+YOScan					;Endadresse bei der Bildausgabe in Y Richtung
.equ Reload			=(F_CPU/8/(F_rate*(YSize+YOScan)))-1;Wert für Timer: Timertakt/Zeilenfrequenz-1

;PortD
.equ CKDIS			=3			;CLK disable
.equ FLM			=4			;VSync
.equ LP				=5			;HSync

;****************************************************************************
;	Interrupt Vektoren
;****************************************************************************
.cseg
.org 0
rjmp Reset

.org OC0addr
rjmp LCD_int
	
;****************************************************************************
Reset:
	ldi		temp, LOW(RAMEND)
	out		SPL, temp					;setup stack pointer
	ldi		temp, HIGH(RAMEND)
	out		SPH, temp					;setup stack pointer
	clr		Null	

LCD_Init:
	ldi		temp, 0x03					;PIN 0(RXD) und 1(NC) auf Pullup bzw. 1
	out		PORTD, temp	
	ldi		temp, 0xFE					;nur PIN 0(RXD) auf Eingang	
	out		DDRD, temp	
	ldi		temp, 0xFF	
	out		DDRB, temp					;alles Ausgang	
	out		DDRE, temp					;alles Ausgang	
	out		PORTA, temp					;Pullup	
	out		PORTC, temp					;Pullup	

	cli
	ldi 	temp, (1<<SRE)|(0<<SRW10)	;Enable XRAM, die Null vor dem SRW Bit durch 
										;eine 1 ersetzen, wenn der verwendete SRAM mehr
										;als 35ns hat !!!
	out 	MCUCR, temp
	ldi 	temp, 10
	out 	OCR1AL, temp
	ldi 	temp, 128
	out 	OCR1BL, temp				;PWM: 50% Duty Cycle
	ldi 	temp, (1<<COM1B1)|(1<<COM1B0)|(1<<WGM10)	;Enable PWM (Kontrast)
	out 	TCCR1A, temp
	ldi 	temp, (1<<CS10)				;31,25kHz PWM Frequenz
	out 	TCCR1B, temp
	ldi 	temp, Reload				;Timer Reloadwert
	out 	OCR0, temp
	ldi 	temp, (1<<WGM01)|2			;2MHz Timer Takt, CTC
	out 	TCCR0, temp								
	ldi 	temp, (1<<OCIE0)
	out 	TIMSK, temp

LCD_Clear:			
	ldi		XL, 0x00	
	ldi		XH, YMin					;Display-RAM Anfang 0x500 bis 0xffff

LCD_Clear_loop:			
	st		X, Null	
	adiw	XL, 1
	cpi		XH, 0xFF					
	brne	LCD_Clear_loop				

	rcall	Start

	sei
	sbi		PortE, 0					;LCD Spannung ein!

Main:
	rjmp	Main
;*********************************************************************************************
Start:						
	ldi		XL, 5
	lsl		XL
	ldi		XH, YMin
	ldi		temp, 0xFF
	mov		Fuellung, temp 	
	mov		YL, XL
	mov		YH, XH
	subi	YH,-35				; Zeilennummer 35+YMin = 40

schreiben:
	st		Y+,Fuellung 		; schreibe Bitmuster in SRAM
	cpi		YL, 15*2			; Zeilenbyte 15 erreicht? 
	breq	Neuzeil				; wenn ja, dann neue Zeile
	rjmp	schreiben 			; Weitermachen

Neuzeil:
	mov		YL, XL				; wieder auf 10 setzen
	inc		YH					; Zeilennummer erhöhen
	cpi		YH, 60				; 60 erreicht?
	breq	Exit				; wenn ja, dann Ende
	rjmp	schreiben

Exit:
	ret

;********************************************************************************************
LCD_int:
	push 	temp
	in 		temp, SREG
	push 	temp
	sbi 	PORTD, LP			;Latchpuls der vorherigen Daten (am Anfang des Interrupts, da hier der Jitter am geringsten ist)
	push 	XL
	push 	XH
	push	temp1
	push 	temp2
	cbi 	PORTD, LP

	lds 	temp2, GrayCnt		;PWM Counter für 4 Graustufen (Bild 0x an, 1x an, 2x an)
	cpi 	temp2, 2
	brlo 	frame0				;Bei 0 und 1 wird Bild 0 angzeigt, ansonsten Bild 2

	ldi 	XL, 128				;entspricht 64x8=512, da Adressbit 0 nicht angeschlossen
	rjmp 	startframe

frame0:
	ldi 	XL, 0

startframe:
	mov 	XH, YCnt			;Zeilenadresse laden
	inc 	XH
	ldi 	temp2, ((XSize/16)+XOScan)	;320/16, da immer 16 Bit übertragen werden
	cbi 	PORTD, FLM

Xshift:							;320 Bits ausgeben
	ld 		temp, X+			;jeweils 2 Adressen entsprechen einer 8 Bit Adresse im 
	ld 		temp, X+			;ext. Ram, da Adressbit 0 nicht angeschlossen ist. 
	ld 		temp, X+			;Somit kann jeweils High, bzw. LOW übertragen werden.
	ld 		temp, X+
	dec 	temp2
	brne 	Xshift

	cpi 	XH, YMin			;Zeilenzähler berechnen
	brne 	not_firstline		;Bildende ?
	sbi 	PORTD, FLM
	wdr

	lds 	temp2, GrayCnt		;PWM Zähler erhöhen
	inc 	temp2
	cpi 	temp2, 3
	brlo 	skipgcreset
	clr 	temp2
	sts 	GrayCnt,temp2
	rjmp 	not_firstline

skipgcreset:
	sts 	GrayCnt,temp2

not_firstline:
	cpi 	XH, YScan			;VSync ?
	brlo 	SkipAdRes
	ldi 	XH, YMin-1			;Adresszähler Reset

SkipAdRes:
	mov 	YCnt, XH

	pop 	temp2
	pop		temp1
	pop 	XH
	pop 	XL
	pop 	temp
	out 	SREG, temp
	pop 	temp
	reti