/*
 Copyright:      Hagen Reddmann  mailto HaReddmann at T-Online dot de
 Author:         Hagen Reddmann
 Remarks:        this Copyright must be included
 known Problems: none
 Version:        2.1. 2004
 Description:    Graphic Library for Nokia 6100 Display and compatible
*/

.nolist
#include "glcd.inc"
#include "regs.inc"
.list

// grafic library main part
        .section .data
        .global glcd_MemCtrl
        .global glcd_Flags
        .global glcd_Colors
#ifdef USE_CLIPPING
        .global glcd_Clip
#endif

glcd_MemCtrl: .byte   ORIENTATION_DEFAULT
glcd_Flags:   .byte   FLAGS_DEFAULT

#ifdef USE_HIGHCOLOR
glcd_Colors:  .word   SCREEN_COLOR0, SCREEN_COLOR1, SCREEN_COLOR2, SCREEN_COLOR3
  #if COLOR_TABLE_SIZE > 8
              .space  (COLOR_TABLE_SIZE - 8)
  #endif
#else
glcd_Colors:  .byte   SCREEN_COLOR0, SCREEN_COLOR1, SCREEN_COLOR2, SCREEN_COLOR3
  #if COLOR_TABLE_SIZE > 4
              .space  (COLOR_TABLE_SIZE - 4)
  #endif
#endif
#ifdef USE_CLIPPING
glcd_Clip:    .byte   SCREEN_LEFT, SCREEN_TOP, SCREEN_RIGHT, SCREEN_BOTTOM
#endif


// initialization procedure of glcd lib
#ifdef USE_AUTOINIT
        .section .init7

glcdInitializeDisplay:
        xcall   glcdDisplayInit
#endif

// glcd library
        .section .text

// SPI Interrupt to reset CS of LCD and deactivate SPI

#ifdef USE_ISR
#if defined (SIG_SPI)
        .global  SIG_SPI
SIG_SPI:
        sbi     LCD_PORT, LCD_CS
        reti
#else
#error "This chip has no SPI interrupts defined"
#endif
#endif

        .global  glcdDisplayCommand     // used T1 stack 1
glcdDisplayCommand:
        mov     T1, P0                  // don't touch D0,D1,T0,__tmp_reg__,__zero_reg__
    
        .global glcdDispCommand
glcdDispCommand:
        set
        rjmp    glcdDispSend

        .global glcdDisplayData         // used T1 stack 1
glcdDisplayData:
        mov     T1, P0                  // don't touch D0,D1,T0,__tmp_reg__,__zero_reg__
        .global glcdDispData
glcdDispData:
        clt

        .global glcdDispSend
glcdDispSend:                           // used T1 as SPI transmission data, T flag indicate 9'th MSB

#ifdef SPI_NOP_WAIT
        nop
        nop
        nop
        nop
#ifdef SPI_IN_LOWER_IO_REGS
        nop
        nop
#else                                   // SPI_IN_LOWER_IO_REGS 
        push T0
#endif                                  // SPI_IN_LOWER_IO_REGS 
#else                                   // SPI_NOP_WAIT
#ifndef SPI_IN_LOWER_IO_REGS
        push    T0                      // We need T0 to modify/read some SPI I/O-Registers
#endif                                  // SPI_IN_LOWER_IO_REGS

glcdDispSend0:
#ifdef USE_ISR
        sbis    LCD_PORT, LCD_CS        // don't touch D0,D1,T0,__tmp_reg__,__zero_reg__
#else                                   // USE_ISR
#ifdef SPI_IN_LOWER_IO_REGS
        sbis    LCD_SPSR, SPIF
#else                                   // SPI_IN_LOWER_IO_REGS
        in      T0, LCD_SPSR
        sbrs    T0, SPIF
#endif                                  // SPI_IN_LOWER_IO_REGS
#endif                                  // USE_ISR
        rjmp    glcdDispSend0
#endif                                  // SPI_NOP_WAIT
 
#if !defined(USE_ISR) && defined(TOGGLE_CS)
        sbi     LCD_PORT, LCD_CS        // Disable Chip Select to give address logic in display a known state 
#endif

#ifdef SPI_IN_LOWER_IO_REGS             // Disable SPI to send 9th bit
        cbi     LCD_SPCR, SPE
#else
        in      T0, LCD_SPCR
        cbr     T0, (1 << SPE)
        out     LCD_SPCR, T0
#endif
#ifdef TOGGLE_CS
        cbi     LCD_PORT, LCD_CS
#endif
        cbi     LCD_PORT, LCD_SCL
        cbi     LCD_PORT, LCD_SDA
        brts    glcdDispSend1
        sbi     LCD_PORT, LCD_SDA
glcdDispSend1:
        sbi     LCD_PORT, LCD_SCL
#ifdef SPI_IN_LOWER_IO_REGS
        sbi     LCD_SPCR, SPE
#else
        in      T0, LCD_SPCR
        sbr     T0, (1<<SPE)
        out     LCD_SPCR, T0
        pop     T0
#endif
        out     LCD_SPDR, T1
        ret

        .global glcdDisplayRead         // used T0, T1, D0 stack 0 return P0H:P0L:P1H:P1L
glcdDisplayRead:
        mov     T1, P0                  // Command
        mov     T0, P1                  // Nr. of bits

        .global glcdDispRead
glcdDispRead:
#ifdef USE_ISR
        sbis    LCD_PORT, LCD_CS
#else
#ifdef SPI_IN_LOWER_IO_REGS
        sbis    LCD_SPSR, SPIF
#else
        in      D0, LCD_SPSR
        sbrs    D0, SPIF
#endif
#endif
        rjmp    glcdDispRead

#ifndef  USE_ISR
        sbi     LCD_PORT, LCD_CS        // Disable Chip Select to give address logic in display a known state 
#endif

#ifdef SPI_IN_LOWER_IO_REGS
        cbi     LCD_SPCR, SPE
#else
        in      D0, LCD_SPCR            // Disable SPI
        cbr     D0, (1 << SPE)
        out     LCD_SPCR, D0
#endif

        // Send the command manually. Sending via SPI causes CS signal to be toggled
        // which causes problems with some read commands. command in T1
        cbi     LCD_PORT, LCD_CS
        ldi     D0, 9                  // Send 9 bits
        clc                            // D/C bit is 0
glcdDispRead1:
        cbi     LCD_PORT, LCD_SCL
        cbi     LCD_PORT, LCD_SDA
        brcc    glcdDispRead2
        sbi     LCD_PORT, LCD_SDA
glcdDispRead2:
        sbi     LCD_PORT, LCD_SCL
        rol     T1                    // Rotat next command bit into carry
        dec     D0
        brne    glcdDispRead1

        // Read output from display, number of bits in T0
        cbi     LCD_DDR, LCD_SDA       // Data line is an input for reading now

        cbi     LCD_PORT, LCD_SCL      // There is always a spare bit between command and data
        clr     P1L
        clr     P1H
        sbi     LCD_PORT, LCD_SCL      // Output a single clock to shift that bit out.
        clr     P0L
        clr     P0H

glcdDispRead3:
        cbi     LCD_PORT, LCD_SCL
        add     P1L, P1L
        adc     P1H, P1H
        sbic    LCD_PIN, LCD_SDA
        inc     P1L
        sbi     LCD_PORT, LCD_SCL
        adc     P0L, P0L
        adc     P0H, P0H
        dec     T0
        brne    glcdDispRead3
        sbi     LCD_PORT, LCD_CS
        sbi     LCD_DDR, LCD_SDA
#ifndef TOGGLE_CS
        nop
        nop
        cbi     LCD_PORT, LCD_CS
#endif
        ret

        .global glcdDisplayBuffer       // used T0,T1,D0,D1,__temp_reg__ r0 if not enhanced AVR  stack 1
glcdDisplayBuffer:
        _movw   ZL, P0
        mov     T0, P1
glcdDispBuffer:
        tst     P2
        brne    glcdDispBuffer2
glcdDispBuffer1:
        ld      T1, Z+
        rcall   glcdDispData
        dec     T0
        brne    glcdDispBuffer1
        ret
glcdDispBuffer2:
        rpm     T1
        rcall   glcdDispData
        dec     T0
        brne    glcdDispBuffer2
        ret


        .global glcdWait                // used T0,T1 stack 0
glcdWait:
        sbiw    P0, 1                                   // 2
        brcc    glcdWait1                               // 2
        ret                                             // 2 -2 = 0 for no branch in both loops
glcdWait1:
        nop
        ldi     T0, lo8(DELAY_ONE_MILLISECOND -4)       // 1
        ldi     T1, hi8(DELAY_ONE_MILLISECOND -4)       // 1
glcdWait2:
        sbiw    T0, 1                                       // 2
        brne    glcdWait2                                   // 2 = 4, = 3 for last loop
        rjmp    glcdWait                                // 2 = 8


#ifndef USE_HIGHCOLOR
  #ifdef USE_ORGINALCOLORS
COLOR_RED:                                              // original color table
        .byte   0x00, 0x02, 0x04, 0x06, 0x09, 0x0B, 0x0D, 0x0F
COLOR_BLUE:
        .byte   0x00, 0x04, 0x0B, 0x0F
  #else
COLOR_RED:                                              // modified color table
        .byte   0x00, 0x03, 0x05, 0x07, 0x09, 0x0B, 0x0D, 0x0F
COLOR_BLUE:
        .byte   0x00, 0x08, 0x0B, 0x0F
  #endif
#endif

        .global glcdDisplayInit         // used D0,D1,T0,T1,__tmp_reg__,__zero_reg__ stack 4
glcdDisplayInit:

// now initialize ports
        in      T0, LCD_PORT
        sbr     T0, ((1 << LCD_RESET) | (1 << LCD_CS) | (1 << LCD_SDA) | (1 << LCD_SCL))
        out     LCD_PORT, T0
        in      T0, LCD_DDR
        ori     T0, (1 << LCD_CS) | (1 << LCD_SCL) | (1 << LCD_SDA) | (1 << LCD_RESET)
        out     LCD_DDR, T0

        cbi     LCD_PORT, LCD_CS        // do harware reset of PCF8833
        sbi     LCD_PORT, LCD_SCL
        cbi     LCD_PORT, LCD_RESET
        ldi     P0L, 2
        clr     P0H
        rcall   glcdWait
        sbi     LCD_PORT, LCD_RESET
        sbi     LCD_PORT, LCD_CS

#ifdef SPI2X                            // setup SPI
#ifdef SPI_IN_LOWER_IO_REGS
        sbi     LCD_SPSR, SPI2X
#else
        in      T0, LCD_SPSR
        sbr     T0, (1 <<SPI2X)
        out     LCD_SPSR, T0
#endif
#endif
#ifdef USE_ISR        
        ldi     T0, (1 << MSTR) | (1 << CPOL) | (1 << CPHA) | (1 << SPIE)
        out     LCD_SPCR, T0
        sei
#else 
        ldi     T0, (1 << MSTR) | (1 << CPOL) | (1 << CPHA) | (1 << SPE)
        out     LCD_SPCR, T0
        // Output a single byte without CS to set SPIF bit in SPSR
        clr     T0
        out     LCD_SPDR, T0
#ifndef TOGGLE_CS
glcdDisplayInit1:
#ifdef SPI_IN_LOWER_IO_REGS
        sbis    LCD_SPSR, SPIF
#else
        in      T0, LCD_SPSR
        sbrs    T0, SPIF
#endif
        rjmp    glcdDisplayInit1
        cbi     LCD_PORT, LCD_CS        // Give the display a chip select 
#endif
#endif

        ldi     T1, SOFT_RESET          // software reset, is really needed !!
        rcall   glcdDispCommand
#if INIT_DELAY > 0
        ldi     P0L, lo8(INIT_DELAY)
        ldi     P0H, hi8(INIT_DELAY)
        rcall   glcdWait
#endif

        ldi     T1, COLOR_INTERFACE     // initialize color format and color mapping
        rcall   glcdDispSend
#ifdef USE_HIGHCOLOR
        ldi     T1, COLOR_16_BIT
        rcall   glcdDispData
#else
        ldi     T1, COLOR_8_BIT
        rcall   glcdDispData
        ldi     P0L, lo8(COLOR_RED)      // red
        ldi     P0H, hi8(COLOR_RED)
        ldi     P1L, lo8(COLOR_RED)      // green
        ldi     P1H, hi8(COLOR_RED)
        ldi     P2L, lo8(COLOR_BLUE)     // blue
        ldi     P2H, hi8(COLOR_BLUE)
        rcall   glcdDisplaySetColors
#endif
        ldi     T1, MEM_CONTROL         // initialize display RAM access
        rcall   glcdDispCommand
        lds     T1, glcd_MemCtrl
        rjmp    glcdDispData

        .global glcdDisplaySetColors
glcdDisplaySetColors:
#ifndef USE_HIGHCOLOR
        ldi     T1, COLOR_SET
        rcall   glcdDispCommand
        _movw   D0, P2           // P2 = P3, P3 = P2
        mov     P2, P3
        _movw   P3, D0
        _movw   D0, P0
        ldi     T0, 8
        rcall   glcdDispBuffer
        _movw   D0, P1
        ldi     T0, 8
        rcall   glcdDispBuffer
        _movw   D0, P3
        ldi     T0, 4
        rjmp    glcdDispBuffer
#else
        ret
#endif
.end