Lazarus + Synaser

[Tony B. (Gast)]

Hallo liebes Forum! (=

Ich hab schon seit Ewigkeiten nach einer Möglichkeit gesucht, um per 
RS232 zwischen PC un AtMega8 eine Kommunikation aufzubauen!

Da ich aber meine Kontrolloberfläche auf dem PC selbst gestalten möchte 
wollte ich kein übliches Panel(damit funzt es ohne Probleme) sondern ein 
eigenes Program, und da ich in Lazarus schon einige Erfahrung habe, 
wollte ich das einfach nutzen.
Kurzer hand hab ich mir Synaser besorgt und mal so durch die Proceduren 
und Funktionen gestöbert und auch schnell etwas gefunden, leider hab ich 
Probleme damit etwas vom µC zu empfangen. Senden geht ohne Probleme!

Der Syntax in Lazarus habt Ihr hier einmal!

 
unit Unit1; 

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, LResources, Forms, Controls, Graphics, Dialogs,
  StdCtrls, synaser;

  var
  serv:TBlockSerial;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure empfang;
  private
    { private declarations }
  public
    { public declarations }
  end; 

var
  Form1: TForm1; 

implementation

{ TForm1 }

procedure TForm1.empfang;
var
timeout : integer;
signal : string;


begin
Timeout := 4000;
signal := serv.Recvstring(timeout);
edit2.text := signal;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  serv.free;
  ShowMessage('ComPort muss freigeschalten werden! Jetzt freischalten?');
  sleep(1000);
  close;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
portnr : string;
parity : char;
baud,bits,stop : integer;
softflow : boolean;
hardflow : boolean;

begin
serv:=TBlockSerial.create;
portnr := 'COM1';
parity := 'N';
baud := 4800;
bits := 8;
stop := 1;
softflow := false;
hardflow := false;

try
  serv.Connect(portnr);
  serv.Config(baud, bits, parity, stop, softflow, hardflow);
  ShowMessage('Verbindung erfolgreich')
except;

end;
end;

procedure TForm1.Button3Click(Sender: TObject);
var
befehl, data : string;

const
CR = #$0d;
begin
  befehl := edit1.text;
  data   := befehl+CR;
  serv.SendString(data);
end;


initialization
  {$I Unit1.lrs}

end.

Ich wollte einfach mal wissen, warum ich in mein Edit2feld keinen Text 
bekomme.
Der µC ist mit Bascom gecoded, hier benutze ich den Print befehl ohne 
';' dahinter (Das hat zur Folge das nach jedem String durch PRINT 
automatisch ein CRLF gesendet wird...)


Bitte helft mir, hab noch rein gar nichts brauchbares im Netz gefunden!

Danke schonmal!! (=

Lg

[Wegstaben V. (wegstabenverbuchsler)]

.. und ein einfaches Terminal-Programm funktioniert, d.h. es zeigt das 
an was vom uC gesendet wird?

[Tony B. (Gast)]

Wegstaben Verbuchsler schrieb:
> .. und ein einfaches Terminal-Programm funktioniert, d.h. es zeigt das
> an was vom uC gesendet wird?

Ja, das is ja das mekrwürdige. =(

Mit einem einfachen I/O Terminal unter Windows, kann ich senden und 
empfangen ohne Probleme, ohne Datenverlust und in astreiner 
Geschwindigkeit!

Fällt euch vielleicht irgendwo mein Fehler auf? (=


Wäre echt Spitze!!

Lg

[GeraldB (Gast)]

Ich wundere mich, daß du was senden konntest. Der COM-Port wurde 
überhaupt nicht (richtig?) geöffnet.

Mach mal folgende Änderungen:

Bei der Klassendeklaration von TForm1 :

private
    connected: Boolean;

Ändere die procedure TForm1.Button2Click folgendermaßen :

begin
  if connected then
  begin
    ShowMessage('Verbindung ist bereits vorhanden');
    exit;
  end;
  serv:=TBlockSerial.create;
  portnr := 'COM1';
  parity := 'N';
  baud := 4800;
  bits := 8;
  stop := SB1;
  softflow := false;
  hardflow := false;
  serv.Connect(portnr);
  sleep(1000);
  serv.Config(baud, bits, parity, stop, softflow, hardflow);
  sleep(1000);
  if serv.LastError = 0 then
  begin
    connected := True;
    ShowMessage('Verbindung erfolgreich');
  end
  else
  ShowMessage('Verbindung konnte nicht hergestellt werden');
end;

Die Funktion serv.Config ist bei Dir unerkannt abgebrochen, da ihr über 
den Parameter stop ein ungültiger Wert übergeben wurde. Und da das in 
diversen Beispielen angegebene Konstrukt mit try/except hier nicht 
funktioniert, wurde Dir ein geöffneter und konfigurierter COM-Port 
vorgegaukelt.

PS: Hast Du eigentlich das Buch über Lazarus?
Mitlerweile in der 2. Auflage vom C&L-Verlag
-> Lazarus: Klassenbibliothek und IDE (http://www.cul.de/lazarus2.html)

Der Titel der 1. Auflage war:
Lazarus: Arbeiten mit IDE und Klassenbibliotheken

Dort wird ein korrektes Beispiel gezeigt.

[Tony B. (Gast)]

Hey GeraldB (=

Ich danke Dir für deinen Ausführlichen Post!!
Ich hab das alles mal ergänzt/ korrigiert!
Es funktionierte leider weiterhin nur das Senden. Ich hab jedoch (wenn 
auch nicht sehr elegant) jetzt eine Möglichkeit des Empfangens gefunden.

Ich hab jetzt In jede SendeProcedure noch folgendes angehängt:

if serv.CanRead(2000) then
  signal := serv.Recvstring(5000);
  memo1.Lines.add(signal);

Jetzt empfange ich alles Korrekt! (=
Senden funktioniert auch ohne Probleme!

Ich hätte nur mal noch eine Frage:
Das Problem ist ja jetzt dass es nur dann empfängt, wenn ich etwas 
gesendet habe.
Aus diesem Grund wollte ich einen Timer erstellen der alle 2sek (2000ms) 
Quasi diese EmpfangsSyntax durchläuft, sodass ich alles immer empfangen 
kann. Ich hab selbstverständlich auf den "Verbinden" Button (mit COM 
verbinden und Configurieren) erst Timer1.Enabled := true; gelegt, da 
sonst eine fehler meldung kommt, wenn man sich nicht innerhalb von 2 
sekunden verbunden hat.

Aber irgendwie geht das nicht klar.

Muss ich da irgendwas beachten?

Danke schonmal! (=

[GeraldB (Gast)]

In dem Beispiel im o.a. Buch wird auch mit einem Timer gearbeitet.
Für Dein Programm angepaßt sieht das dann so aus:

procedure TForm1.Timer1Timer(Sender: TObject);
var
  signal : string;

begin
  if not connected then exit;
  signal := serv.Recvstring(Timer1.Interval div 2);
  if serv.LastError <> 0 then exit;
  Edit2.Text := signal;
end;

Zum Timer-Interval steht nichts dabei, daher kann es wohl auf 1000 
bleiben. Da erst das Vorhandensein der Verbindung abgefragt wird, 
braucht der Timer auch nicht aus-/einschaltet werden.

[Marcel B. (mikroseven)]

Hallo, zusammen!

Danke fur diesen Beitrag.
War auch auf suche nach Lazarus-Atmega Komunication.

M.f.G. Der Marcel

[Marcel B. (mikroseven)]

Hi,

kan Jemand "synaser" erklaren?

Bin mir icht sicher was ich dafur brauche.

Kann ich den genaue Component bekommen von jemand, oder ein Link?

M.f.G.

[Huhu (Gast)]

Marcel B. schrieb:
> oder ein Link?

http://synapse.ararat.cz/doku.php/download

Da ist auch alles beschrieben...

[Marcel B. (mikroseven)]

Vielen Dank, Uhu!

Hatte bereits den selbe Seite gefunden und bin gestartet.



- Alle Ordner/Dateien werden gefunden von den LAZARUS-IDE.

- Nur Fehlermeldung, aber ich denke ich muss mall nachsehen weil das
  Beispiel ist in Deutsch und meine LAZARUS ist in Englisch
  Zum Beispiel TForm.empfang...


Fur die geinteresierten, schau mall mein Projeckten an!
Der Robotor wird noch gesteuert mit Turbo Pascal 7.0 und ein ISA-Slot 
mit verschiedene 82c55a Chips. Muchte gerne zu Lazarus und Arduino ( 
mikroPascal ).



https://www.facebook.com/SurroundingMars/

http://europakade.nl/motion-control-and-robots

M.f.G.

[Marcel B. (mikroseven)]

Uberigens:

RS232 Kommunication habe ich schon functionieren mit ein 
PC-USART-Terminal.

Ich Sende zu Arduino, und den LCD zeciht es an.
Es wird auch zuruck gesendet und den PC-USART-Terminal zeicht das 
Gleiche an.

Hardware funcioniert!

[Marcel B. (mikroseven)]

Abend!

Mall eben im /synapse40/source/demo  rumgekuckt aber ich verstehe nicht 
was ich kann anwenden als funcionierendes Demo fur RS232.

Jemand ein Hinweis?

M.f.G.

[W.S. (Gast)]

Tony B. schrieb:
> Kurzer hand hab ich mir Synaser besorgt

Erwartest du, daß hier irgend jemand dieses/diesen Synaser kennt?

Du brauchst nen Comport-Anschluß für dein Delphi/Lazarus-Projekt. Sowas 
wie ne Komponente TComPort oder wie auch immer das im konkreten Falle 
heißen mag.

Dann solltest du dir sowas wie
procedure TForm1.empfang;
...
begin
Timeout := 4000;
signal := serv.Recvstring(timeout);
...

komplett verkneifen. Genau SO macht man so etwas überhaupt nicht. Hast 
du dir nie einen Gedanken gemacht darüber, wie ein GUI-Programm unter 
egal welchem OS eigentlich funktioniert?

Mein Rat: verpasse deinem Programm einen Timer, setze den auf 50..100 ms 
und erledige deine Input-Aufgaben in der OnTimer-Methode:

procedure Timer.OnTimer
..
if ComPort.CharAvailable
then
begin
  Ch:= ComPort.GetTheChar;
  Verarbeite(Char);
end;

So etwa geht sowas.

W.S.

[mikroSeven (Gast)]

Hi.

Bevor ich auf diesem Forum ankamm, habe ich mit 5spdo und lazser 
rumgebastellt.

Ich glaube ich gehe besser dorthin zuruck und steige nochmall "frish" 
hinein.

Da ist richtig ein component im Lazarus IDE compileert/-rebuild.

M.f.G.

[mikroSeven (Gast)]

For mehere jahren schon angefangen mit Delphi.
Hier mein funcionierendes Programm, aber ohne RobotArm konnekted.

( funktioniert jetzt noch mit TurboPAscal 7.0 und ISA-Slot )

[Schorsch X. (bastelschorsch)]

Synaser ist eigentlich recht einfach und funktioniert. Im Prinzip:

uses
  ...
  synaser;

var
  ser:TBlockSerial;
  s:string;
...
  ser:=TBlockserial.Create;
  ser.Connect('COM1');
  ser.Config(115200,8,'N',SB1,false,false);
...
  ser.SendString(text);
...
  if (ser.WaitingData <> 0) then begin
    s := ser.RecvPacket(5000);
  end;

[Marcel B. (mikroseven)]

Vielen Dank!

Werde nachste Wcohe weitergehn.

Mein Deutsch ist ja nicht Perfekt aber ich hoffe trotzdem es ist fur 
euch Allen zu begreifen!

M.f.G. Der Marcel

[Marcel B. (mikroseven)]

Hallo,  Schorsch X.

Dat hort mir was bekanter an.
So etwas anliches geht's in meine Arduino.

M.f.G.

[Marcel B. (mikroseven)]

Moi moi!

habe Erfolg!

Ich 'use' lazaSerial und Synaser.
Hingefughtes Beilspiel "sertest" bestudiert, was rumgebastelt und jetzt 
kan ein String hochzuladen werden zu Arduino/LCD.


Die wichtigste Sachen:

  Serial.Device := EditDevice.Text; { com setting aus editbox }
  Serial.Open;



  str:='(564,129)el';      { el wende ich an im Arduino als delimiter }
  Serial.WriteData(Str);






M.f.G.

[Marcel B. (mikroseven)]

Got some significant progress!

Value of 3 ScrollBars is sended by RS232 to my Arduino.
At 3 LedBars, the values are displayed as (0-255) values.
( gonna be in 0 to 8 led's later as is it showing an 
audio-level-indicater )

In Lazarus the refresh rate is 10/sec. Only the value of the last 
changed Scrollbar is sended to Arduino. At my Lazarus INIT al of the 3 
wil be sended!

I'm using

1 byte as LedbarNumber and

3 bytes as LedBarValue.

The string 'el' (end-line) is added as delimiter.


I'm very happy I got this far programming RS232.

Next step is to controll my robotArm by PC-RS232-Arduino!


Fortunately I got the major part for controlling my robotArm allready
coded in TurbuPascal7.0 and the control is done by ISA/ 82c55a.

The whole ForWard/BackWard-Kinematics, stepperControl and overal 
mathematics for Interpolation/Integral/Differential for creating a path 
in 3d.

http://europakade.nl/motion-control-an-robots/robot-arm

https://www.youtube.com/playlist?list=PL7iWs5bvJdxs91kCZUV9P6KuG4mvriLgJ

[Mathias (Gast)]

Ich arbeite auch mit Lazarus und synaser, dabei funktioniert die 
Kommunikation mit meinem Arduino hervorragend.

[Marcel B. (mikroseven)]

Hallo, Mathias!

Geht jetzt besser, aber...kann besser glaube ich.


Kannst du vieleicht etwas von deine Code posten?

Nur die Code schliesslich angewend vor das Senden und dem Empfang.

Ein wenig Erklarung:

Ich sende jetzt immer mit ein Bestimmte Lange des Strings.
z.B. ich sende ADC-Werten von Arduino-ADC zu pc. Bereich
0 bis 1023. Jeder bracht dabei 1, 2, 3 oder 4 Platzen in dem String.
8 ADC's machen 32 Platzen ( char's ) und ein AnfangCharacter . 
ADC-Werten werden mit intToStringWithZeros immer 4
 4Characters Plats einnehemn.

Der Arduino sendet 4 ADC's macht das z.B.
ADC1:= 58;
ADC2:= 659
ADC3:= 303;
ADC4:= 8;

// macht
stOut:= 'D0058065903030008';
uart1_write_text('stOut');

Aber ich will folgendes machen.

stOut:= 'D58,659,303,8';


Da muss, ich zb 58 Speichern im entfangADC1 bis ich ein ','
begegne und dan 659 im entfangADC2...u.s.w...

Am Lazarus krieg ich das nicht hin leider.

Ich glaube, das muss auch anders:


if SerialA.synser.waitingData = cStIn

Konstante cStin habe ich weil ich beim orginalcode immer
die gleiche lange entfange.

[Marcel B. (mikroseven)]

Hallo W.S.

Sie haben gepostet:

procedure Timer.OnTimer
..
if ComPort.CharAvailable
then
begin
  Ch:= ComPort.GetTheChar;
  Verarbeite(Char);
end;


So etwas suchte ich, nicht ganze string entfangen im Lazarus aber
die Character nach einander und die speicheren in ein String.

Werde nach Wochenende damit anfangen/versuchen.

Da muss ich auch das Senden des Arduino auch anderen:
nicht ein ganze String senden aber einzele Character. ( doch? oder? )

Schones Wochenende!

[Marcel B. (mikroseven)]

( hier mall eben was ich soweit habe. rechtunter seht mann die werden 
von 8 ADC's ( je x und y) und 4 Buttons ( je f ). L ist fur Erweiterung 
und jetzt nicht im betrieb. ganz rechtsunter den lange string ist das 
Entfangene String, erste Character ist nur ein Kontrollzahler. )

[Heinz B. (Firma: Privat) (hbrill)]

Hallo,
hatte das Problem auch. Zwar nicht mit Lazarus
sondern mit anderen Programmiersprachen.

Das Problem ist, wenn der Arduino (AVR u. a.)
einen String sendet, daß er kein NullByte hinter
den String hängt. Da die meisten Windows-Programmiersprachen
aber ein Nullbyte am Stringende erwarten, können sie
den Arduino-String nicht erkennen.

Abhilfe : einfach (z.B. in Bascom) am Ende des
zu sendenden Strings ein Chr$(0) dranhängen.

[W.S. (Gast)]

Marcel B. schrieb:
> So etwas suchte ich,

Dann guck dir den Anhang an. Läuft in Delphi 6 und 10 - den Port nach 
Lazarus hab ich zwar auch, aber grad nicht greifbar. Installiere dir das 
als Komponente und gut isses.

Zum Benutzen installierst du dir einfach einen Timer zum Pollen des 
Comports (oder nen separaten Thread, geht ja auch) und eine Listbox zum 
Anzeigen.
Prinzip:
Tasten--> via Comport senden;
Empfangen vom Comport--> via Timer in die Listbox stopfen
Das Folgende stammt aus dem STM32Prog-Projekt (hier im Forum zu finden), 
hab das Ganze vor einiger Zeit auch nach Lazarus portiert, aber das D10 
Programm sieht dank Skin netter aus.

LaberBox: TListBox;
LiBoTimer: TTimer;
....

procedure TMainForm.LaberBoxKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var
  ctl  : boolean;
  i    : integer;
  S    : AnsiString;
begin
  ctl:=  ssCtrl  in Shift;

  if ctl and (Key = $2D)   // einfg, also CTL_INS
  then
  begin
    S:= '';
    for i:= 0 to LaberBox.Count-1 do
    if LaberBox.Selected[i]
    then S:= S + #13#10 + LaberBox.Items[i];
    Clipboard.AsText:= S;
    Key:= 0;
  end;

end;

procedure TMainForm.LaberBoxKeyPress(Sender: TObject; var Key: Char);
var
  B : byte;
  i : integer;
begin
  B:= ord(Key);
  if B = 1         // CTRL_A  alles markieren
  then
  begin
    LaberBox.SelectAll;
    Key:= #0;
    exit;
  end;


  ComPort.WriteB(B);
  if B = 13 then ComPort.WriteB(10);
  for i:= 0 to LaberBox.Count-1 do LaberBox.Selected[i]:= false;
end;


procedure TMainForm.OnLiBoTimer(Sender: TObject);
var
  i : integer;
  j : integer;
  S : String;
  C : Char;
begin
  if not TerminalBox.Visible then exit;
  while LaberBox.Count>200 do LaberBox.Items.Delete(0);

  if LaberBox.Count=0
  then begin
         LaberBox.AddItem('Terminal '+IntToStr(ComPort.Baud) + ' baud',nil);
         LaberBox.AddItem('',nil);
       end;

  i:= ComPort.InCount;
  if i=0 then exit;
  S:= LaberBox.Items[LaberBox.Count-1];
  while i>0 do
  begin
    C:= Char(ComPort.ReadB);
    if C=#13
    then begin
           LaberBox.Items[LaberBox.Count-1]:= S;
           LaberBox.AddItem('',nil);
           S:= LaberBox.Items[LaberBox.Count-1];
         end
    else begin
           if C=#9
           then begin
                  j:= (length(S) or 7)+1;
                  while length(S)<j do S:= S+' ';
                end
           else if C=#8
           then begin
                  if length(S) > 0
                  then Setlength(S, length(S)-1);
                end
           else begin
                  if C>=' ' then S:= S+C;
                end;
         end;
    dec(i);
  end;
  LaberBox.Items[LaberBox.Count-1]:= S;
  LaberBox.ItemIndex:= LaberBox.Count-1;
end;

W.S.

[Marcel B. (mikroseven)]

Danke!

Leider diese Woche noch nicht programmiert.

Bis bald.