portb.2 vom atmega32

[roboterheld (Gast)]

der portb.2 vom atmega hat 3 (normal/int2/ain0)funktionen. wie wird da 
der int2 aktiviert?

mffg

[Michael G. (linuxgeek)]

Oben links unter AVR ist ein Link zum avr-gcc Tutorial.

[Karl H. (kbuchegg)]

Was auch nicht zu verachten ist:
Bei Atmel gibt es ein umfangreiches Datenblätt zum Mega32.
Da steht das alles drinnen.

Verblüffend, gelle?
Ein Hersteller, der seinen Chip dokumentiert!

[Stefan B. (stefan)]

Mit dem Datenblatt ist das manchmal so eine Sache...

Ich z.B. hatte gestern das Datenblatt zum Attiny2313 in den Fingern und 
richtig lange versucht genau das Thema Mehrfachbelegung nachzuschlagen.
(Ging um den Thread Beitrag "Interrupt beim AVR" 
und ich hatte AT90S2313 überlesen)

Ich habe es schäm nicht geschafft. Auch im AVR-GCC-Tutorial springt 
mir dazu ehrlich gesagt nichts ins Auge.

[Stefan B. (stefan)]

Das schäm kann ich jetzt streichen ;-) Die Einstellerei geht beim 
Atmega32 über die Special Function Register (SFR) MCUCSR und GICR.

Hier das Beispiel für Oilaf aus obigem Thread angepasst an den Atmega32:

; ################
; ### Includes ###
; ################
.include "m32def.inc"
; TARGET ATMEGA8

; ####################
; ### Definitionen ###
; ####################
.def    temp    =r16
.def    temp2   =r17

; #####################
; ### Vektortabelle ###
; #####################
; Hier verkürzt für Demozwecke.
; Komplette Vektortabelle ist sicher!
.org 0x0000
  rjmp  Reset
.org INT2addr
  rjmp  INT2_Handler

; #####################
; ### Hauptprogramm ###
; #####################
Reset:
    ; ########################
    ; ### Stack einrichten ###
    ; ########################
  ldi temp, high(RAMEND)
  out SPH, temp
  ldi temp, low(RAMEND)
  out SPL, temp

    ; ############################################
    ; ### LOW ACTIVE LED an PB0 initialisieren ###
    ; ############################################
    ; Toggelt später in INT2_Handler
  ldi temp, 0b00000000  ; PB0 LOW (LED_AN)
  out PORTB, temp
  ldi temp, 0b00000001  ; PB0 Ausgang
  out DDRB, temp
         
    ; #############################
    ; ### Interrupts einstellen ###
    ; #############################
    ; FALLENDE Flanke von INT2 soll Interrupt erzeugen
  in  temp, MCUCSR
  andi temp, 0b10111111  ; ISC2 löschen => fallende Flanke
  out MCUCSR, temp

  in  temp, GICR
  ori temp, 0b00100000  ; INT2 external interrupt request 2 enable
  out GICR, temp

  sei            ; Interrupts allgemein aktivieren
  
    ; #######################
    ; ### Arbeitsschleife ###
    ; #######################
loop:
  rjmp loop       ; loop forever

; ########################
; ### Interrupthandler ###
; ########################
    ; ############
    ; ### Int2 ###
    ; ############
INT2_Handler:
  push temp
  in   temp,sreg
  ; Anfang Nutzcode
  ; => PB0 toggeln
  push temp
  push temp2
  ldi  temp2, 0b00000001
  in   temp, PORTB
  eor  temp, temp2
  out  PORTB, temp
  pop  temp2
  pop  temp
  ; Ende Nutzcode
  out  sreg,temp
  pop  temp
  reti

; Simulation in AVR Studio
;
; !/ Keine Breakpoints
; 2/ Step (F11)
; 3/ PINB2 manipulieren und PORTB0 beobachten
;    PORTB0 toggelt, wenn PINB2 von HIGH => LOW wechselt
;.
; ENDE

Der komische Abschnitt Overriding Signals for Alternate Functions hat 
mich verwirrt, weil die dortigen Signale sonst im Datenblatt nicht 
vorkommen.