Ansteuerung DS 1302 (Timekeeping) über I2C-Bus (

[Hölscher (Gast)]

Hallo Mikrocontroller Freunde

Hat jemand vieleicht ein paar Infos zur Ansteuerung eines
Timekeepingship DS1302 über den I2C-Bus.

z.B 1) Initialisierung des DS1302
    2) Funktion des I2C-Buses

Ich verwende das Flash-Board AT89S8252 und den Compiler von Keil
uVision2 7.0

Ich würde mich sehr über Quellcodeauszüge freuen.

Mit freundlichen Grüßen
Christian Kölscher

[Peter D. (peda)]

Zum I2C findest Du hier was:

http://www.specs.de/users/danni/appl/hard/i2c/index.htm


RTC-Chips verwende ich normaler Weise keine, die Netzspannung fällt
einfach zu selten aus in Germany. D.h. es reicht der interne Timer des
MC völlig aus.

Nur wenns doch mal mobil sein soll, nehme ich den DS1994. Der ist so
schön unkompliziert, da Batterie gleich mit drin und nur ein Anschluß
benötigt.


Peter

[Hölscher (Gast)]

Hallo Peter vielen Dank für die schnelle Antwort.

Kannst du mir etwas zu meiner Vorgehensweise zum Anschluss sagen:
Ich habe

1)  3-Anschlüsse des DS1302 (SCLK, I/O, !RST) an den Port3
    (P3_5, P3_4, P3_3)angeschlossen.

Ist das eigentlich egal an welche Ports ich den I2C-Bus anschließe?

Ich würde mich freuen wenn ich eine Bestätigung bekommen würde, dann
kann ich schon mal den Hardware Anschluss als richtig ansehen.

Mit freundlichen Grüßen
Christian

P.S. Ich taste mich so langsam an mein Problem. Ich soll eine
     Steuerung aufbauen mit LCD-Display, Timekeeping DS1302, und
     Termofühler. Habe aber noch nicht so viele Erfahrungen mit der
     Programierung von uC

[Peter D. (peda)]

"SCLK, I/O, !RST"

Das klingt aber nicht nach I2C, da heißen die Signale SDA und SCL.


Peter

[Hölscher (Gast)]

Das sind die Pin Bezeichnungen von dem DS1302 Chip.

#define RST   P3_3  // Reset Eingang !RST
#define SDA   P1_0  // Serial Imput Output I/O
#define SCL   P1_1  // Serial Clock SCLK

Auszug aus der Eingebundenen HEADER Datei
Header file for the Atmel AT89S8252.
/*------------------------------------------------
P1 (0x90) Bit Registers
------------------------------------------------*/
sbit P1_0 = 0x90;
sbit P1_1 = 0x91;
sbit P1_2 = 0x92;
sbit P1_3 = 0x93;
sbit P1_4 = 0x94;
sbit P1_5 = 0x95;
sbit P1_6 = 0x96;
sbit P1_7 = 0x97;

sbit T2   = 0x90;       /* External input to Timer/Counter 2, clock out
*/
sbit T2EX = 0x91;       /* Timer/Counter 2 capture/reload trigger & dir
ctl */

sbit SS   = 0x94;       /* SPI: SS - Slave port select input */
sbit MOSI = 0x95;       /* SPI: MOSI - Master data output, slave data
input */
sbit MISO = 0x96;       /* SPI: MISO - Master data input, slave data
sbit SCK  = 0x97;       /* SPI: SCK - Master clock output, slave clock
input */

Vieleicht kannst du da mehr mit anfangen
Mit freundlichen Grüßen
Christian

[Hölscher (Gast)]

So hat ein wenig länger gedauert,aber...ich kann den chip nicht über den
I2C-Bus ansteuern.

Es sind doch nur drei kleine Leitungen die mich verzweifeln lassen.

Vieleicht kann mir ja jemand helfen..

Quellcode währe sehr schön

Mit freundlichen Grßen
Christian

[Jörg Maaßen (Gast)]

@Hölcher

Der DS1302 hat garkeine I2C-Schnittstelle sondern eine
SPI-Schnittstelle.

Wenn Du mit I2C arbeiten möchtest dann ist der DS1307 Dein Bauteil.
Selbe Funktion wie DS1302 nur mit I2C-schnittstelle. Dann klappt's
auch mit dem programmieren ;-)

Gruß Jörg

[Hölscher (Gast)]

Hallo Jörg vielen Dank für die Antwort.
Ich bin zur Zeit dabei den Baustein über SPI anzusteuern.
Hast du vieleicht eine Vorgehensweise für mich oder ein Beispiel zur
Ansteuerung?

Mit freundlichen Grüßen
Christian

[Thomas S. (zeilentrafo)]

Der DS1302 wird weder mit I2C noch mit SPI angesprochen. Es wird ein 
Drei-Draht-Protokoll verwendet, dessen Knackpunkt ist, dass die 
Antworten der RTC bei der fallenden Flanke anliegen, die zu schreibenden 
Daten jedoch bei der steigenden Flanke der CLK anliegen sollen. Daher 
hat im Datenblatt die Lese-Funktion einen CLK-Impuls weniger.

Hier ist das mal mit den Grundfunktionen Read / Write in Arduino 
umgesetzt. Es läuft auf einem ProMini mit 8 MHz und einen Seeeduino XIAO 
(beide nativ mit 3,3 Volt).

In der Setup-Funktion werden Std. Min und Sekunden gesetzt. Beachte, 
dass hier die Hex-Schreibweise der zweistelligen BCD entspricht.

// Three Wire PINS:
const int CE = 3;          // Chip Enable
const int SCLK = 5;        // Clock
const int IO = 4;          // IO-Pin

// ThreeWireWait
const int TWW = 20;        // µSeconds

void ThreeWireWrite (uint8_t Register, uint8_t Data)  {

  pinMode (IO, OUTPUT);
  digitalWrite (CE, HIGH);
  delayMicroseconds (TWW + TWW);

  for (uint8_t bits = 0; bits < 8; bits ++)  {
    digitalWrite (IO, (Register & 1 << bits) ? HIGH : LOW);
    delayMicroseconds(TWW / 2);
    digitalWrite (SCLK, HIGH);
    delayMicroseconds (TWW);
    digitalWrite (SCLK, LOW);
    delayMicroseconds (TWW);
  }

  for (uint8_t bits = 0; bits < 8; bits ++)  {
    digitalWrite (IO, (Data & 1 << bits) ? HIGH : LOW);
    delayMicroseconds (TWW / 2);
    digitalWrite (SCLK, HIGH);
    delayMicroseconds (TWW);
    digitalWrite (SCLK, LOW);
    delayMicroseconds (TWW);
  }
  delayMicroseconds (TWW + TWW);
  digitalWrite (CE, LOW);
}


uint8_t ThreeWireRead (uint8_t Register)  {
  uint8_t Data = 0;
  pinMode (IO, OUTPUT);
  digitalWrite(CE, HIGH);
  delayMicroseconds(TWW + TWW);

  for (uint8_t bits = 0; bits < 8; bits ++)  {

    digitalWrite(SCLK, LOW);
    delayMicroseconds(TWW);
    digitalWrite(IO, (Register & 1 << bits) ? HIGH : LOW);
    delayMicroseconds(TWW / 2);
    digitalWrite(SCLK, HIGH);
    delayMicroseconds(TWW);
  }

  pinMode(IO, INPUT);

  for (uint8_t bits = 0; bits < 7; bits++)  {
    delayMicroseconds(TWW / 2);
    digitalWrite(SCLK, LOW);
    delayMicroseconds(TWW / 2);
    Data = (digitalRead(IO)) ? Data | 0x80 : Data;
    Data = Data >> 1;
    delayMicroseconds(TWW / 2);
    digitalWrite(SCLK, HIGH);
    delayMicroseconds(TWW / 2);
  }

  digitalWrite(SCLK, LOW);
  pinMode (IO, OUTPUT);
  digitalWrite (IO, LOW);
  delayMicroseconds(TWW + TWW);
  digitalWrite (CE, LOW);
  return Data;
}

void setup() {

  // DS1302 Three Wire
  pinMode (CE, OUTPUT);
  pinMode (SCLK, OUTPUT);
  pinMode (IO, OUTPUT);

  // initial state ThreeWire
  digitalWrite (CE, LOW);
  digitalWrite (SCLK, LOW);

  Serial.begin(9600);

  Serial.println(" ");
  Serial.println("DS1302");

  ThreeWireWrite (0x80, 0x01);   // set Seconds to One
  ThreeWireWrite (0x82, 0x45);   // set Minutes to 45
  ThreeWireWrite (0x84, 0x21);   // set hrs to 21
}

void loop() {
  delay(960);
  uint8_t Hours = (ThreeWireRead(0x85));
  Serial.print(((Hours >> 4) * 10) + (Hours & 0x0F));
  Serial.print(" hrs ");
  delay(2);
  uint8_t Minutes = (ThreeWireRead(0x83));
  Serial.print(((Minutes >> 4) * 10) + (Minutes & 0x0F));
  Serial.print(" min ");
  delay(2);
  uint8_t Seconds = (ThreeWireRead(0x81));
  Serial.print(((Seconds >> 4) * 10) + (Seconds & 0x0F));
  Serial.println(" Sec");
}

[Thomas S. (zeilentrafo)]

muss die READ-Funktion korrigieren. So wie oben wird das 8. Bit 
unterschlagen. Habe das bemerkt, als die Arbeit mit dem TCS-Register 
begann. Bei den Uhrzeiten war das nicht aufgefallen.

Bitte daher ersetzen mit:

uint8_t ThreeWireRead (uint8_t Register)  {
  uint8_t Data = 0;

  pinMode (IO, OUTPUT);
  digitalWrite(CE, HIGH);
  delayMicroseconds(TWW + TWW);

  for (uint8_t bits = 0; bits < 8; bits ++)  {

    digitalWrite(SCLK, LOW);
    delayMicroseconds(TWW);

    digitalWrite(IO, (Register & 1 << bits) ? HIGH : LOW);
    delayMicroseconds(TWW / 2);
    digitalWrite(SCLK, HIGH);
    delayMicroseconds(TWW);
  }

  pinMode(IO, INPUT);

  for (uint8_t bits = 0; bits < 8; bits++)  {

    delayMicroseconds(TWW / 2);
    digitalWrite(SCLK, LOW);
    delayMicroseconds(TWW / 2);

    Data = (digitalRead(IO)) ? (Data >> 1) | 0x80 : Data >> 1;

    delayMicroseconds(TWW / 2);
    digitalWrite(SCLK, HIGH);
    delayMicroseconds(TWW / 2);
  }

  digitalWrite(SCLK, LOW);
  pinMode (IO, OUTPUT);
  digitalWrite (IO, LOW);
  delayMicroseconds(TWW + TWW);
  digitalWrite (CE, LOW);
  return Data;
}

[Magnus M. (magnetus)]

Thomas S. schrieb:
> Beachte,
> dass hier die Hex-Schreibweise der zweistelligen BCD entspricht.

Ich schätze dass sich der TO nach 18(!) Jahren nicht mehr für deinen 
Beitrag interessiert....