.include "tn2313def.inc"


.def temp1 = r16
.def temp2 = r17
.def temp3 = r18
.def flag  = r19

.def SubCount = r21
.def Sekunden = r22
.def Minuten  = r23
.def Stunden  = r24


.org 0x0000

	rjmp Main

.org 0x0004

	rjmp timer1_compare

.include "D:\lcd-routines.asm"

Main:

	ldi temp1, low(RAMEND)
	out SPL, temp1

	rcall lcd_init2
	rcall lcd_clear2
	rcall lcd_init
	rcall lcd_clear

	ldi temp1, high(39999)
	out OCR1AH, temp1
	ldi temp1, low(39999)
	out OCR1AL, temp1

	ldi temp1, (1<<WGM12) | (1<<CS10)
	out TCCR1B, temp1

	ldi temp1, 1<<OCIE1A
	out TIMSK, temp1

	clr Sekunden
	clr Minuten
	clr Stunden
	clr SubCount
	clr flag

	sei

Loop:

	cpi flag, 0
	breq Loop
	ldi flag, 0

	rcall lcd_clear
	mov temp1, Stunden
	rcall lcd_number
	ldi temp1, ':'
	rcall lcd_data
	mov temp1, Minuten
	rcall lcd_number
	ldi temp1, ':'
	rcall lcd_data
	mov temp1, Sekunden
	rcall lcd_number

	rjmp Loop

timer1_compare:
	
	push temp1
	in temp1, sreg

	inc SubCount
	cpi SubCount, 100
	brne end_isr

	clr SubCount
	inc Sekunden
	cpi Sekunden, 60
	brne Ausgabe

	clr Sekunden
	inc Minuten
	cpi Minuten, 60
	brne Ausgabe

	clr Minuten
	inc Stunden
	cpi Stunden, 24
	brne Ausgabe

	clr Stunden

Ausgabe:

	ldi flag, 1

end_isr:

	out sreg, temp1
	pop temp1
	reti

lcd_number:

	push temp2
	ldi temp2, '0'

lcd_number10:

	subi temp1, 10
	brcs lcd_number1
	inc temp2
	rjmp lcd_number10

lcd_number1:

	push temp1
	mov temp1, temp2
	rcall lcd_data
	pop temp1
	subi temp1, -10

	ldi temp2, '0'
	add temp1, temp2
	rcall lcd_data
	
	pop temp2
	ret