title [Bach      Chaconne in Dmin from Partita No. 2 for Solo Violin]
author [Arranged for MIDI by Andrew MacLean]
copyright [ 1999 Andrew MacLean ]

'NOT A FILE FOR BEGINNERS, I`M AFRAID. FOR A SIMPLER
'EXAMPLE, TAKE A LOOK AT WELCOME.ZEL

'LOAD THE ZEL GENERAL MIDI DEFINITIONS:
'IF YOU USE A NON-GM SYNTH, LOAD ITS DEFINITIONS HERE:  
include gm.zel

'D MINOR:
key d  

meter 3/4 duration 1/4  displacement 1/120

'SET UP THE PITCH BEND RANGE TO 12:  
setPitchBendRange12
wheel wz range -12 -> +12 rate 50

'SETS THE AMBIENCE: 
control effect1Depth 91

'WE USE THIS PATTERN TO INCREASE THE VELOCITY ON SELECTED NOTES:
note_pattern [ louder {!+10} louder2 {!+10} ]
'THESE WILL ADD !10 TO THE FIRST NOTE IN A MEASURE
'AND ANOTHER !10 TO EACH BEAT 
set emphasis { louder 1 4 louder2 1 12 effect1Depth=127 expression=127 }

'SET UP 6 OF THE TRACKS:
set reset { !!64 volume=100 pan=64 >>0 **1}
set effectFade {[effect1Depth 8:0:0-64]}
track TR1   $$1 @@6   ocarina  emphasis  pan=50  effectFade 
setPitchBendRange12 [4 volume=40 20+30]
track TR2   $$2 @@6   ocarina  emphasis  pan=50  effectFade 
setPitchBendRange12 volume=64
track TR3   $$3 @@5   ocarina  emphasis  pan=70  effectFade 
setPitchBendRange12 [4 volume=60 20+30]
track TR4   $$4 @@4   flute    volume=0 setPitchBendRange12
track TR5   $$5 @@5   whistle [effect1Depth=127 volume=75 ]
track TRD   $$10

'SET UP FIVE OF THE TRACK GROUPS, WE DO OTHERS AS WE NEED THEM:
track [ TG12345   [ TG12 [TR1 TR2 ] 
        TR3 TG45  [ TR4 TR5 ]]]
track [ TGG123 [TG123 [TR1 TR2 TR3]]]
track [ TGG12 [TG12]]  

'PAN FLUTE, WHISTLE, FLUTE, WOODWIND ONLY: 
TG12 W0 ++ [TR2 volume=0 8:0+100  ]
|1   tempo=30 4  a6f8d8!-20 a2 18+20
|2   E4bgd  E6a8gc# E2
|3   F4afd  D6f8b@ C2 
|4   b4gg@ a4fa@ tempo 6-5 gw5fwewfc#  
|5   gd2  e  f d  TG12345 ++ [TR1 whistle ] a6f8d8 tempo +5 a2 [TR2 @@-1]
|6   E4bgd  E6a8gc# E2
|7   F4afd D6f8b@ D2 [TR4 volume=100 acousticBass]
[TR2  @@5  nylonStringGuitar emphasis  pan=50   ]
|8   B4Deg@ A3C#ea@ G/w0F/ W0 G3 E
'USE THE WHEEL TO GIVE A SLEEPY FEEL
[TR3 |1 W0   wz 4  a6 a2w11E4 E6 E2w11F4 D6 C2 W0 ] 

[tempo=60 TR3 @@6 TR5 @@6 ] 
|9   f3Dd12 e f3 g/ a/ b3 a
|10  E2b4gd 3f E2ag8c#2 3b a3 g 
|11  E2a4fd2 3e D3f8b2 3Fa E3g Dfg@
|12  De3a4@ 3d C#2e4 3g f3 ACea@
|13  FDd12 3e f3 g/ a/ b3 a
|14  E2bg4d 3f E2ag8c#8 3b a3 g
|15  E2af4d 3e D3f8b2@ 3Fa E3g C#eb@
|16  tempo 8-5 +5 !!8+10 D3fa@ Egg@ D4e8a@ C#3 D  !!-10

TR4 |17  ~d8d3b1@e8e3a1@g8g3d1f8f3g1f8f3b1@e8e3a1@g8g3d1f8f3c#1@
[tempo [  4+0 +8 4-0 -7 4+0 ]8 ] 
TG12345 [TR3  |17 bowedGlass @@-1 ] [TR1 @@4]
|17  <8D3d2 3E F3 G/ A/ B3 FD
|18  E3C#4 B A3C^4 G A3 F#C
|19  G3b4 F E3b&4 D/ C#/ D3 Eb
|20  F3a Gb^ E3C# FD G3E EC#
|21  F3D2 3D/ E/ F3 G/ A/ B3 FD
|22  E3C#4 B A3C^4 G A3 F#C
|23  G3b^4 F E3b&4 D/ C#/ D3 EDg#
|24  F3D4a G E4D3a4 C#/ b^/ C#3 ga@


TR4 [TR1 @@6]
|25 ~f8d4g8a4d8g4d8a4f8e4g8a4f8b4@g8a4@
tempo 24=75  TR3 |25 volume=100 nylonStringGuitar
TGG12
|25  f2d ~F2EDC#D
|26  g2d a b c#2 b2 a2 g2
|27  f2d g a b2@ d2 g2 D C#
|28  D2 f2g@ ea2@ ~fgbagfe
|29  fd break on aDFFEGFEDC#D  
|30  gbf#gc#egbagEg
|31  fc#da@b@dgabE&C#D 
|32  g#b^DFEG^C#Da@eDC#


[ TR1 ++ pizzicatoStrings !!30 @@-1 
  TR2 ++ nylonStringGuitar
  TR3 ++ whistle **0.5 shift 5 pan=127 ]
TGG123 ++
[tempo -12 ] [tempo +25 1+0 -24.7 1-0  ]48~ [tempo +12 ]
|33  [TR4 ++ d8g#4c#8f#4b8@e4a8@e4f^8g#4c#8a4b^8b&4f8c#4]  
|33  D2FBAG#d
|34  c#2EAGF#c^
|35  b2@DGF^Eb&@ 
|36  a@FEDC#2aEg 
|37  fdfaDFBAG#B^GE
|38  C#EAGF#AFC^afdc 
|39  b^@dgf#gE&DC#B&AG#A
|40  FEDEb&ag#ac#g^fe

[tempo -10 [+25 1+0 -25 1-0  ]52~ +10 ]
[TR1 ++ acousticBass pan=10 ]
TR4 |41 f4gda@dcbdg@c#fa@gdgc#f#c^bcgg#g^a 
TGG12 ++ [TR3 shift 0 ]

|41  fdef gab^C# Dfed 
|42  a@eDC# df#a C^CbCa
|43  bgfe& dcb@a@ g@gE&D 
|44  C#Eag fDed a@eDC# TGG123 ++
|45  GEFC# DC^ba gfed
|46  c#bag f#dad c^b@ca@
|47  b@g@a@b@ cdef# gaba 
|48  g#aef g^c#dg#@ a@fec#

[TR1 ++ bowedGlass TR2 ++ synthVox @@+1 TR5 ++ acousticBass @@5 ]
track [TGG1235 [TG1235 [TR1 TR2 TR3 TR5]]]

[TR4++ reset bowedGlass @@+2 
|49 1D 8D1 4C 8C 4b 8b 4a 8g 4d 4a 4G 4c 4g 4F 4b 4f 4E 4a 4E 4G]
TGG1235++
|49  dDagfedcb@Dgf 
|50  eCgfedcb@a@Cfe& 
|51  dbfe&dcb@a@g@bed 
|52  c#a@ceaeaC#Egae
|53  fdfaDaDFb GAB tempo 3-10 
|54  EcegCgCEa +10 FGA 3-10
|55  Db@dfbfbDg +10 EFG 3-10 
|56  C#aCEAEAC#@E@ +10 GFE -10


[TR1 reset nylonStringGuitar TR2 reset whistle
 TR3 reset bowedGlass TR5 reset synthVox ]
[track TG12_45 [ TG12 TG1235 ]] TG12_45
|57  break off  D2F a2 d2 D2F G2b1 a b g
|58  C2E g2 c2 C2E F2a1 g a f
|59  D2b f2 b2@ D2b E2g1 f g e
|60  a2f1 e D2f 1d D1e2a@ C# A2D1 b^ AC#2 G A E 
|61  F2D1 ~C#Da D2f1 ~efdb@gDB
|62  E2C1 ~bCg C2e1 ~deca@fCA
|63  D2f1 ~e&fd b2d1  ~cdb@g@e^bG
|64  ~a@eC#G ~a@fDF ~a@gC#E 


TGG123 ++ 
[ TR1 ++ nylonStringGuitar @@6 **4 pan=127 [ 3:0-127 3:0+127 ]4
TR2 ++ harp @@6  **8 pan=0 [ 3:0+127 3:0-127 ]4
TR3 ++ bowedGlass volume=64  ] 


|65  Dd ~a/gf1edcb@a@b@D/Cbagf
|66  ec ~g/fe1dcb@a@g@a@C/bagfe&
|67  db@ ~f/e&d1cb@d/cb1@a@g@b/agfe^d break on
|68  c#/b^@a@b@cdefgab&agfedc1E/DC#b^ag
|69  fd/ef1afdfab/CDEFGAB
|70  Ec/de1gecega/bCDEFGA
|71  Db/@cd1fdb@dfg/abCDEFG
|72  C#/BAGFEDC^bagfedc#b@a@b@cdefge

[TR2 ++ ocarina **0.4 shift 10 pan=64 TR3 ++ harp TR1++ **1 ]
|73  f/defgab^C#DbCDEFGA B&dc^/3dcb1@
|74  c/def#gabCDabCDEF#G Acb/3cba1@
|75  b@/def#gabCDgabCDEF#GABAGF^ED
|76  C#/AGFEDCb^abCDEFGAB&GEC a/gfe [d8] tempo 1.5-40


[TR2++ whistle **1 shift 0 pan=0 ]
track [TG23 [TR2 TR3]]
TG23 ++ [TR3++ whistle volume=127 @@+1 pan=127 TR2++ effect1Depth=0 ]
|77  tempo +35 effect1Depth 48+127 daDEFDbag#b^DF 
|78  ceaCECagf#aCE&
|79  b@dgbDbgfegbC#
|80  a@dfaDafda@egC#

|81  effect1Depth 8:0-127 dBBG#GF^FDDb^g#e
|82  c#AAF#FE&EC^Caf#d
|83  b^@GGE&EC#Cb&bge^c#
|84  a@c#ceeg/fg1b/ab1C/DE1g
set one {
|85  f/ab^C#DCbaFEDCDEFGAGFEB&AGF @@+1
|86  c/ef#g#agfeCb&agabCDEDCbF^EDC#
|87  D/EFEDFEDFEDFEDFEDGFEDCba 
|88  g/abagbagbagbagbagfedc#b^@a@g@ | }

one TR1 |85 reset nylonStringGuitar @@-1 volume=40 4:0+30 one
@@-1 duration /8 effect1Depth=0


set ifn {nylonStringGuitar} [ tempo=70 20:0:0+7 ] 
TR1 ++ ifn @@5 !!64 volume=100 **1 [pan=64 20:0:0-64 ]effect1Depth=0 emphasis
TR2 ++ ifn @@5 !!64 volume=100 **1 [pan=64 20:0:0+64 ]effect1Depth=0
TR3 ++ ifn @@5 !!64 volume=100 **1 [pan=64 20:0:0+24 ]effect1Depth=0
TR4 ++ ifn @@5 !!64 volume=100 **1 [pan=64 20:0:0-24 ]effect1Depth=0
TR5 ++ acousticBass !!100  [volume=0 20:0:0+100 ] @@4 effect1Depth=0
track TR6 ++ $$6 ocarina [volume=0 20:0:0+110] effect1Depth=0
track TR7 ++ $$7 bowedGlass !!100  [volume=0 20:0:0+90 ] @@6 effect1Depth=127
track [TGG57 [TG57 [ TR5 TR7 ]]] 

set arp1 { [ TR6 ++ *4 ?1*?4?2?3 ] [TGG57 ++ ?1*4 ] [ TR1 ++  ?1*4   
1 TR2 ++  ?2*4 1  TR3 ++  ?3*4 1 TR4  ++  ?2*4 1 ]?4~  } 

set changeArp1 { set arp1 { [ TR6 ++ *4 ?1*?4?2?3 ] [TGG57 ++  ?1*4 ]2 
[ TR1 ++  ?1*4  1 TR2 ++  ?2*4 1  TR3 ++  ?3*4 1 TR4  ++  ?2*4 1 ]?4~  } }

break off ++ 
     {arp1,f,d,A,6,
     e,d,G,4,e,C#,G,2,
     d,d,F,4,d,a,F,2,
     g@,b,E,1,g@,a,F,1,g@,g,E,1,g@,f,D,1,a@,e,D,1,a@,e,C#,1,
     d,f,D,2,a@,f,D,2,b@,f,D,2,
     c^,f#,E&,2,b@,f#,E&,2,a@,f#,E&,2,
     b@,g,D,2,a@,f^,D,2,g@,e^,D,2, 
     a@,f,D,2,a@,e,D,2,a@,g,C#,2, [TR1 @@6]
     d,f,D,2,d,f,a,2,d,f,b,2,
     d,f#,C,2,d,f,b,2,d,f,a,2,
     d,g,b,2,e,C#,B,2,f^,D,A,2,
     g,D,G,1,g,D,F,1,a,D,E,2,a,C#,E,2, [TR2 @@6]
     d,D,F,2,d,a,F,2,d,b,F,2,
     d,C^,F#,2,d,b,F#,2,d,a,F#,2,
     d,b,G,2,d,a,F^,2,a#@,g,a^E,2,
     d,f^,aD,2,a@,e,C#,4,
     d,f^,D,2,d,a,F,2,d,a,CF,2,
     g@,gb,F^,2,g@,gb,E,2,a@,f,E&,2,[TR3 @@6]
     b@,f,E&,2,b@,f,DB,2,b@g,D,E^,2,
     a@a,D,E,2,a@e,C#,A,2,a@e,C#,G,2,
     d,a,F^,2,da,D,F#,2,da,C^,F#,2, 
'110' d,b,G,2,d,b^,G#,2,e,D,G#,2, 
     f,C^,A,2,f#,E&,C@,2,g,D,B^,2, 
     g#,F^,D@,2,a,E^,D@,2,a,E^,C#@,2, changeArp1
     d,F^,D@,2,b&,F,D@,2,a,F,D@,2,
     g#,E^,D@,2,a,E,C#@,2,g^,E,C#@,2,[TR4 @@6] 
     f#,D,C^@,2,g^,D,B^,2,f^,D,B^,2, 
     e,C#,B&,2,f,D,A,2,e,C#,F,2, 
     d,D,F#,2,a@,a,C^F^,2,b^@,g,DF,2,  
     c,g^,CE,2,g^@,g,E&,2,a@,f^,E&,2, 
     b&@,f^,D,2,b@,g,D,2,a@,f,D,2,
     g#@,e^,D,2,a@,e,D,2,a@,e,C#,2} break on


duration /8
TR1 @@6  ++ distortionGuitar pan=64 effect1Depth=127
TR2 @@7  ++ overdriveGuitar  pan=62 effect1Depth=127
TGG123   ++
[TR4 @@4 ++ slapBass2 volume=127 !!127 |121 d22 d2 c22 c2 b22@ b2@ a6@ ] 

set [ s {crashCymbal1 0 snareDrum1 0 kickDrum1 }] 
[TRD |119 [snareDrum1 1 ]48 volume=0 2:0:0+100 ] 
[TRD++ volume=127 !!127  s  22 [ s  2 s  22 ]3~ ]
tempo -20 2+20 @@-1

|121 emphasis d4!1 FEDEDCDCbCbabCDEF2d!1
|122 c4!1 EDCDCbCbabagabCDE&2c!1
|123 b4@!1 DCbCbabagagfgabCD2b2@!1
|124 a@!1ab^C#D2 TR4++ a2@g5@ 1 TGG123++ abCD2 TR4++ g2@a7@ 1 
TGG123++ DCbC2g duration /4


TR4++  |f4 d4 b4 d4 c#8 d4 b8 g4aaddc^bcb&abag#a8d4@
TGG123++
|125 fedc# dfga babg| break off
|126 d4gbE ~3c#8gaE6 E2
|127 d4faF ~4b8@fD6 D2
|128 g4@gDB ~3a4@fDA a4@EC#G
|129 ~3d4aDG  d4aDF# c2 F^2
|130 b4@gDF c4gCE b&2@ E&2
|131 ~4 a4@fE& ~6 b4@fD a2@ D2 tempo 12-10 !!12+10
|132 ~6 g#2@ D2 ~16 a8@eC#6 D2 key D


|133 d20D tempo-40 [volume 10-127 ] 4 
track [ TG4555 [TR4 TR5 TR5 TR5]]
TR4 volume=64
TG4555++ (oboe)(whistle) @@+2 effect1Depth=55   
f6d8 tempo 8+40  g2 
|134 e4c f6a8@ g a 
|135 d4b@ e6g8@ f g 
|136 f2a4@ e2 e6c8 a2
|137 f4d b2f6d a2 g2 f2d
|138 e4c2 b2@ f1a6@ g a g f2 e2a@
|139 d4b2@ a2@ g6@e2 g f e2 d2g@
|140 C2ga@ D2f e6a8@ a2 

(clarinet)(clarinet) 
|141 f2wewdwewfwg#d4 ()(e2 d2d6 e2 f2 g#2d) 
|142 a2wbwCwDwbwCe4c ()(b2 C2e6a@ D2 b2 C2ga@)
|143 D2wFwEwDwCwbfb@ ()(F2 E2b6gg@ D2 C2 b2gg@)
|144 duration /2 awbwCwDwEwCfa2@ ()( d ea3@ f g ea@) 

| 2 (frenchHorn)(tuba @@-1 )
[TR1++ @@4 |145 reset acousticBass 2 d3 d a2 a3 a d2 d3 d c2 d3  ]
|145 D2f1d e F3Dd1 e f FDg
|146 E2C1a b A3C1 1a b GC
|147 FD EC Gb Fa BDg Abf
|148 Gce FDd E4d2a4 C2 [D8dd@]

TGG123++ tempo =80
[TR1++ reset marimba @@7 ]
[TR2++ reset marimba @@6 shift 15 ]
[TR3++ volume=30 pizzicatoStrings effect1Depth=0]
[TR5++ tuba]
'set double { ?1   }  
|149 tempo -10 duration /4 TGG123++ D1d2 TR5++ ~Cbag#bDFE2 TGG123++ E2b2gd tempo 4:0:0+20
|150 E2Cac1 TR5++ ~dcb@a@cegf2 TGG123++ E2Cfa#@ 
|151 D2fb1@ TR5++ ~cdb@g@b@dfe2 TGG123++ D2eg#@ 
|152 C1e2a@ TR5++ ~babCEGBAGFEf12c12b12@a12@ TR2 tempo+10

|153 ~FAFDaDafdfed
|154 ~cAECaCaecedc
|155 ~b@G#Dbgbgeb@dcb@ duration /4 

TGG123 ++ ()()(volume 16+70)
|156 break on a@b@cdeca@c egfe 
|157 fda@dfdafDaFD
|158 AECEAEC@AE@C@F@C@ 
|159 D@F@D@BFBDFbDCb 
|160 CECaeacea@ceg


set sh { [TR2 shift +1] }
track [ TG13 [ TR1 TR3 ] TGG13_23 [ TG13 TG23 ]]
[TR2 ++ shift 0 @@6 | emphasis] [TR3++  ocarina |emphasis ]
TGG13_23 ++ '(((@@6 )(@@6 shift 0 )))
|161 fdAAAFDafda@d sh
|162 ecAAAECaeca@c sh
|163 db@AAAFDbDG#BG sh
|164 AEAAACEEEaCg sh
|165 fdaaafdfaDFb@ sh
|166 ceaaaeceaCEa@ sh
|167 b@daaadb@dg#bDe sh
'tempo 36+20
|168 a@eaaaeaCECag 



TG12 [TR2++  ocarina]
|169 fa@a@a@a@AA break off FD FD Da Da FD **2/3
|170 EC a@ a@ a@ a@ A A EC EC Ca Ca EC **/2
|171 Dg# a@ a@ a@ a@ B B G#b G#b ED ED GD **/3
|172 AC a@ a@ a@ a@ Aa Aa Aa Ab Gb GC GC **/4
|173 FD d d d d a a a ab bg Cg Cg  **/5
|174 Df d d d d D@D D@D D@D D@E C@E C@F C@F **/6
|175 BG d d d d BG BG BG C@G D@F D@F D@F **/8 
|176 GF GE GE GE FE FDf FDf FDf EDg ECa ECa ECa [FDd] **1 

[tempo -10]
TGG12++ (( tuba reset @@5 volume=100 )( reset soloVox @@4 volume=70 ))
track [  TG125 [TR1 TR2 TR5] TGX [TG125 TG12 TG12]]
[TR5++ tuba @@4 !!127] 
TGX++
|177 duration /2 F2Dd F3D FD   
|178 FD E E3D1 C b Ea#
|179 Eb2 D C^3b1 a g Cf 
|180 C^g2 b C# Bag Abf GCe
|181 F2Dd1 f F3Db1 a g FDf
|182 E2Dg1 e E3Ca1 g f ECe
|183 AC^f FDd BDgg@ AC Gb Fa 
|184 Eg Df C3e4a@ D
|185 D2fa@ a3fd afd
|186 a2fc^ a3fc4 af
|187 b2gb@ b3ge bge
|188 Cga2@ Df D3e1 d e2 1C
|189 D2d F3Dad FDad
|190 F2adc^ F3adc Fadc
|191 F2Dgb@ E3agc# Eagc
|192 Ea2fd D D3e1a2@ f g2 1C
|193 D2f1 e F3Dd FDd
|194 G2De A3Df ADf
|195 B2Dg B3Eg# BEg
|196 C@Ea2 D@F D2@E4a C2@
|197 D2@Fd D3@Fd DFd
|198 C2@Ea C^3@Fd C@Fd
|199 B2g1g2 d E3Dg# EDg#
|200 ED2a F GC3ea@ B A  GCea@ 
|201 duration /4 F4Dd set arpx { ?1 ?2 ?2 ?1 } 
TGG12++ ((ocarina @@+1 volume=80)(soloVox @@6 volume=100)) 
{arpx,d,Fa,dc,Fa,db,Fb,db,Fb,da@,Fb,dg@,Eb,eg@,AC,eg@,Ce,eg#@,BD}
ea@ ED FD ea@ {arpx,ea@,G^C}
|205 d GD GD d  ad Fa bd Fb C^d FC FC Cd
|206 dg@ Eb Eb dg@ eg@ Eb eg@ Eb eg#@ ED ED eg#@ 
|207 tempo 48=56 ea@ ED ED ea@ ea@ EC fa@ EC ga#@ EC EC ga#@
|208 D2fb@ B2Deg@ C6e8a@ D2 key d [TR2 ++ D2!63]


[track TG1222 [TR1 TR2 TR2 TR2 ]] 
TG1222++ (baritoneSax accent 10 @@5 effect1Depth=80 rate 100 volume=100)(@@6 **1 HammondOrgan volume=70 )
[TR4++ acousticBass @@4 volume=110 reset !!110 d12 c12 b12@ a12@ d12 g12@ b12@ a12@ ] 
|209  duration /4 C/w4D3+/d4 4 W b6f8d b2 tempo -1
|210 b3!e3c E b g W0 <5 +1 aw3e W0 c2 a2ec
|211 a3!db@ D '<6'a -1 f# '<6'g dw3b2@ W g2b@
|212 g^3a@ E C# a b& +1 g c#2 a2ec 
|213 f3d d f a D C# D E [ F!w3aw12F3 ][tempo -5 6 +5] [volume 36+17 ]
|214 ()b6dg@ 3d  g b  <4 E&!wDwE! C f a@
'|215 E&3!+10f3b@ C# D a b f# g d e g
|215 E&3!+10f3b@ C# D awbwf#wg W0 dw5e W g W0
|216 C#2ga@ D2fg@ D3ea@ b^ C# E G a tempo 18+25


break on TGG123++ [TR1++ ocarina TR2++ ocarina >>12 TR3 ++ @@5 bowedGlass volume=40 ]
|217 daC#GFDCDdDCD 
|218 W0 [wz displacement /120 ] egC#AGDCDeDCD 
|219 W0 faC#BADCDfDCD
|220 gbDBEDC#EaDCE 
|221 FDagfa[TR4 !!100 ++ @+1 tuba dcb^4@ ]dcb^@gDF 
|222 ECgfeg[TR4 ++ @+1 cb@a4@ ]cb@a@fCE&
|223 Dbfe&df[TR4 ++  bag4 ]b@a@g@c#eb 
|224 [TR4 ++  a4g4a4] afdbgec#ea@gfe 

|225 TR2 >>0 [TR5++ @@5 volume=100 !!70 d9] dab^C#DFGAB& [B5]  TR5++ g/fefg1c^9 
|226 TR2++ cgabCEFGA  [A5] TR5++ f/edef1b9@ 
|227 TR2++  b@D@/C@BC@D1@GB/AGAB1EG/FEFG
|228 C#E/DCDECg1b/agabgedc#defge
break off TGG12++
set fig1 { ?1 a } [TR1++ duration /4 nylonStringGuitar  effect1Depth=0 **1 
[volume=20 200+60] [pan=0 144+127]]
[TR2++ whistle **/2 [pan=127 144-127]]  tempo+10
|229 {fig1,fd,a,b,a,g,f,ec,b,a,g,f,e,db@,a,g,f,e,d,
           ea@,f,g,b,a,g,
           df,a,g#,g^,f#,f^,
           ec,g,f#,f^,e,e&,
           db@,e^,f^,f#,g^,g#,
           aa@,ab@,ac,ac#,b^d,C#e,
|          Df,Cd,bg,bf,be,bd,
|          be,bc,af,ae,ad,ac,
|239       ad,ab^@,ge,gd,gc#,gb@,
|240       gc#,ec,ac,ga@,fb^@,ec#}


track [TG11_123 [TR1 TR1 TG123]] TG11_123++
[TR2++ ocarina  volume=55 **2.5 @@+1]
'[TR3++ ]
|241 fd a break on duration /6  dfa faD aDF bDG gDB
|242 eCB ceg egC gCE aCE fCA 
|243 dbA bdf dfb fbD gbE& e&bG
|244 e^C#B fDA gEG g#DF aDE aC#E 


TGG12++ [TR2 ++ pan=64] [TR1 ++  pan=64]
|245 dAGFFEDDCbbagbCDEF
|246 cGFEEDCCbaagfabCDE&
|247 b@FE&DDCbbaggfe^edc#cb^@ duration /8
|248 a2@b^1@c#defgab^C#DEFGFEDCbagfe
|249 duration /2 break off d 2 TGG123++ 
[TR1++ whistle **1 volume=60 pan=0 @@6 effect1Depth=60
TR2++ **1 pan=50 volume=60 whistle @@6 effect1Depth=60
TR3++ pan=127 ocarina @@5 volume=60 effect1Depth=60 ] [tempo -20 36-20 ] a3f4d aaa 
|250 E2bgd E3a4gc# EEE 
|251 F2afd D3f4b@ C 
|252 b2gg@ a2fa@ g/c#2 f/ e/ f/ 
|253 g/d1 e/ f/ d/  [effect1Depth 36=0] TGG12++ ((pan=50)(pan=50)) 
!!+30 volume +10 b2fd a2f#c 
|254 D2gb@ C2f#a@ b2gg@ 
|255 ~c#/egbagEg f2d TR1++
|256 fg2@ e e3a4@ d [volume 3 9-50]
|257 d12