;PORTA
.equ PIN_LCD_Enable		= 6
.equ PIN_LCD_RS			= 7


;PORTB
.equ PIN_LCD_DB4		= 4
.equ PIN_LCD_DB5		= 5
.equ PIN_LCD_DB6		= 6
.equ PIN_LCD_DB7		= 7



text:
 .db  "TEXT",0				


PowerOn:

	ldi	temp, RAMEND				; Stack initialisieren
	out	sp, temp

	
	;PORTA und B Pullups
 	ldi temp, (0<<PIN_LCD_ENABLE)|(0<<PIN_LCD_RS)
 	out PortA, temp
	ldi temp, (0<<PIN_LCD_DB4)|(0<<PIN_LCD_DB5)|(0<<PIN_LCD_DB6)|(0<<PIN_LCD_DB7) 	
	out PortB, temp

	;Datenrichtung	
	;LCD_Enable und LCD_RS = Ausgang
	ldi temp, (1<<PIN_LCD_ENABLE)|(1<<PIN_LCD_RS)
 	out DDRA, temp
	;PIN_LCDs alle Ausgang
	ldi temp, (1<<PIN_LCD_DB4)|(1<<PIN_LCD_DB5)|(1<<PIN_LCD_DB6)|(1<<PIN_LCD_DB7)
 	out DDRB, temp

	rcall LCD_init
	rcall LCD_clear


start:
	rcall 	LCD_home
 	ldi   	ZL,Low(text*2)  		
 	ldi   	ZH,High(text*2)
 	rcall 	lcd_print	
	rjmp	start	




;***************************************************************************
;*
;* LCD-Routinen  4-Bit
;*                                             	
;* PIN_LCD_Enable	= PA6									
;* PIN_LCD_RS		= PA7									
;* PIN_LCD_DB4		= PB4									
;* PIN_LCD_DB5		= PB5									
;* PIN_LCD_DB6 		= PB6									
;* PIN_LCD_DB7		= PB7									
;*																
;****************************************************************************


;sendet Datenbyte an das LCD
lcd_data:
	
	sbi	PortA, PIN_LCD_RS
	push	AL		        ;"Sicherungskopie" 2.Nibbles
	andi  	AL, 0b11110000         	;unteres Nibble auf Null setzen
	out	PORTB,Al
	rcall 	lcd_enable             	;Enable-Routine aufrufen
    	pop   	AL                	;2. Nibble
    	swap  	AL			;untere 4 bits (Nibble) nach oben	
  	andi  	AL, 0b11110000         	;untere Hälfte auf Null setzen
    	sbr   	AL, 0b00000010	       	;
	out	PORTB,Al
	rcall 	lcd_enable              ;Enable-Routine aufrufen
    	rcall 	delay50us               ;warte
    	ret                             ;zurück zum Hauptprogramm
	

 ;sendet einen Befehl an das LCD
lcd_command:                            ; wie lcd_data, nur ohne RS zu setzen
    	cbi	PortA, PIN_LCD_RS
	push	AL
	andi	AL, 0b11110000
	out	PORTB,Al
	rcall	lcd_enable
	pop	AL
	swap	AL
	andi	AL, 0b11110000
	out	PortB,Al
	rcall	lcd_enable
	rcall	delay50us
	ret


 ;erzeugt den Enable-Puls
lcd_enable:
    
	sbi 	PORTA, PIN_LCD_Enable    	; Enable high
    	nop                          		; 3 Taktzyklen warten
    	nop
	nop
	nop
	cbi	PORTA, PIN_LCD_Enable     	; Enable wieder low
	ret                          		; und wieder zurück

 ;Pause nach jeder Übertragung
delay50us:                              	; bei 1Mhz
    	ldi	AL, 16                 
d5u:
	dec	AL
    	brne	d5u
    	ret                          		; wieder zurück

 ;Längere Pause für manche Befehle
delay5ms:
	ldi	AL,80				; bei 1 Mhz
d5m:
	push	al
	rcall	delay50us
	pop	al
	dec	al
	brne	d5m
	ret

 ;Initialisierung
lcd_init:
    	ldi	BL,50
powerupwait:
    	rcall	delay5ms
    	dec	BL
	brne	powerupwait

	ldi	AL, 0b00110000         		;
    	out	PORTB, AL              		;
	
	rcall	lcd_enable             		; 1. muss 3mal hintereinander gesendet
	rcall	delay5ms			;    werden zur Initialisierung
    	rcall	lcd_enable             		; 2.
    	rcall	delay5ms
    	rcall	lcd_enable             		; und 3!
    	rcall	delay5ms
	
	ldi	AL,	0b00100000		; 4bit Modus einstellen
	out	PortB,AL
	rcall	lcd_enable
	rcall	delay5ms	

	ldi	AL, 0b00101000         		; 4bit-Modus, 2 Zeilen
    	rcall	lcd_command			; Befehl senden
	ldi	AL, 0b00001100         		; LCD on
    	rcall	lcd_command			; Befehl senden
	ldi	AL, 0b00000100         		; Entry mode
    	rcall	lcd_command
    	ret

 ;Sendet den Befehl zur Löschung des Displays
lcd_clear:
    	ldi	AL, 0b00000001         		; Display löschen
    	rcall	lcd_command
    	rcall	delay5ms
    	ret
 ;Setzt Cursor-Position auf Anfang
lcd_home:
	ldi	AL, 0b00000010         		; Cursor an Anfang
   	rcall	lcd_command
   	rcall	delay5ms
   	ret	

; Erwartet die Position in AL			
lcd_cursor:
	sbr	AL, 0b10000000         		; Bit 7 setzen
	rcall	lcd_command
	rcall	delay5ms
    ret


lcd_print:
	lpm					; Laden
	tst	R0				; ist Zeichen =0
	breq	lcd_pend			; gehe zu end
	mov	AL,R0				; sonst Zeichen nach AL
	rcall	lcd_data			; Ausgabe
	adiw	ZL,1              		; Zeiger in ZL = ZL + 1(word)
	rjmp	lcd_print				
lcd_pend:
 	ret