;Demoprogramm für 8-fach-PWM mit Tastensteuerung und Pollin-LCD 4x27.

;8 LEDs gegen Vcc an Port B (STK500)
;4 entprellte Tasten gegen GND für die einzelnen PWM-Kanäle an Port C
;Davon 2 Tasten (Dimm-Tasten) mit Repeat-Funktion bei Dauerdruck.
;LCD 4x27 an Port D

.nolist                     ;List der Include-Datei unterdrücken
.include "m8515def.inc"     ;vereinbarte Namen verwenden (lt. Datasheet)
.list                       ;Programm listen
.listmac                    ;Makros listen
.equ clock = 8000000        ;Taktfrequenz 8Mhz


.equ pwu = 100              ;PWM-Zählumfang (sollte 100 sein wegen %)
.equ timerwert = -100       ;Timer-Startwert (Reload)-100
.equ step=1                 ;Schrittweite für Änderung pro Tastendruck
.equ lep=portb              ;Port für LEDs
.equ tap=pinc               ;Tastenport
 .equ EEWRITE  = 5
 .equ EEREAD   = 4          ;Taste zurück (braucht kein Mensch...)

   ; .equ ruck      = 4          ;Taste zurück (braucht kein Mensch...)
    .equ dimplus   = 3          ;Taste Dimmen plus  
    .equ dimminus  = 2          ;Taste Dimmen minus
    .equ chanplus  = 1          ;Taste Kanal hoch
    .equ chanminus = 0          ;Taste Kanal runter
.equ dimtast=(1<<dimplus)|(1<<dimminus)|(1<<EEWRITE)|(1<<EEREAD) ;Maske auf 
;.equ alltast=dimtast|(1<<chanplus)|(1<<chanminus)|(1<<ruck)
.equ alltast=255

.equ twz0=250               ;Startwert Tastendruckdauer
.equ twz1=30                ;Wiederholwert für Tasten

;Array mit 8 Sollwerten in Registern, damit die Software-PWM schnell wird
.def soll0 = r0             ;Sollwert Kanal 1
.def soll1 = r1             ;Sollwert Kanal 2
.def soll2 = r2             ;Sollwert Kanal 3
.def soll3 = r3             ;Sollwert Kanal 4
.def soll4 = r4             ;Sollwert Kanal 5
.def soll5 = r5             ;Sollwert Kanal 6
.def soll6 = r6             ;Sollwert Kanal 7
.def soll7 = r7             ;Sollwert Kanal 8

.def tsw = r8               ;Timer-Startwert
.def sregtemp = r9          ;Sicherheitskopie SREG

.def tz0 = r11              ;Tasten-Prellzähler Bit0
.def tz1 = r12              ;Tasten-Prellzähler Bit1
.def tas = r13              ;Tastenstatus (gültig)
.def null = r14             ;immer 0 
.def kanal = r15            ;aktuelle Kanalnummer



.def DATA  = r16           ;EEPROM DATEN
.def EEH  = r17           ;EEPROM HIGH REGISTER
.def EEL  = r18           ;EEPROM LOW REGISTER

.def temp = r19             ;temporär (exklusiv in der ISR)
.def tfl = r20              ;Flags für Tasten, die gedrückt wurden
.def twz=r21                ;Tasten-Wiederholzähler




.def pwz = r22              ;PWM-Zähler
.def flags = r23            ;Steuerflags
    .equ lcdcontroller1 = 6     ;Flag für Controller 1
    .equ lcdcontroller2 = 5     ;Flag für Controller 2

.def wl=r24                 ;Working L
.def wh=r25                 ;Working H


.cseg
.org 0              ;Reset- und Interrupt-Vektoren AT-Mega 8515
 rjmp RESET         ;Reset Handler
 rjmp nix;EXT_INT0      ;IRQ0 Handler
 rjmp nix;EXT_INT1      ;IRQ1 Handler
 rjmp nix;TIM1_CAPT     ;Timer1 Capture Handler
 rjmp nix;TIM1_COMPA    ;Timer1 Compare A Handler
 rjmp nix;TIM1_COMPB    ;Timer1 Compare B Handler
 rjmp nix;TIM1_OVF      ;Timer1 Overflow Handler
 rjmp TIM0_OVF      ;Timer0 Overflow Handler
 rjmp nix;SPI_STC       ;SPI Transfer Complete Handler
 rjmp nix;USART_RXC     ;USART RX Complete Handler
 rjmp nix;USART_UDRE    ;UDR0 Empty Handler
 rjmp nix;USART_TXC     ;USART TX Complete Handler
 rjmp nix;ANA_COMP      ;Analog Comparator Handler
 rjmp nix;EXT_INT2      ;IRQ2 Handler
 rjmp nix;TIM0_COMP     ;Timer0 Compare Handler
 rjmp nix;EE_RDY        ;EEPROM Ready Handler
 rjmp nix;SPM_RDY       ;Store Program memory Ready Handler
nix:                    ;unbenutzte Interrupts
 rjmp nix
 reti                   ;zurück...


.include"LCD_4x27.inc"      ;LCD-Routinen für 4-Zeilen-LCDs mit HD44780

;Da nur wenige LCD Ausgabefunktionen benötigt werden, wurde auf das Einbinden
;der Ausgaberoutinensammlung verzichtet und die beiden benötigten Routinen
;und deren Macros hier heschrieben. Auf Registersicherung wurde verzichtet,
;da die Ausgabe nur in der Initialisierung bzw. der Mainloop erfolgt. 
;Die 8-Bit-Ausgaberoutine wurde so verändert, dass die Zahl immer drei
;Ausgabepositionen belegt, also eine feste Breite hat, Ist die erste Ziffer
;eine 0, so wird sie als Leerzeichen ausgegeben. Damit ist die Anzeige von
;00% bis 100% möglich, ohne dass die Ausgabeposition flattert.

.macro print83 ;Reg.
 mov xl,@0                  ;Quellregister kopieren
 rcall lcd_print83          ;Routine aufrufen
.endmacro


.macro printf   ;Startadresse des Strings im Flash als Label
                ;Gibt einen String aus dem Flash an LCD aus
                ;Ein Parameter beschreibt die Startadresse, das Ende ist $00
 ldi zh,high(2*@0)          ;Pointer
 ldi zl,low(2*@0)           ;setzen
 rcall lcd_printf           ;Aufruf...
.endmacro


lcd_print83:    ;gibt Wert in XL dreistellig aus (mit Führungsleerzeichen)
 ldi wl,-1+'0'              ;Hunderter-Stelle als ASCII-Zeichen, Zahl ist pos.
 inc wl                     ;Hunderter hoch und
 subi xl,100                ;100 subtrahieren bis zum Unterlauf
 brsh pc-2                  ;Unterlauf? nein, 2 Zeilen hoch
 cpi wl,'0'                 ;ja, ist Ziffer = "0"?
 brne pc+2                  ;nein, nicht verändern...
 ldi wl,' '                 ;ja, durch Leerzeichen ersetzen
 rcall lcd_data             ;Hunderter ausgeben...
 ldi wl,10+'0'              ;Zehner-Stelle als ASCII-Zeichen, Zahl ist neg.
 dec wl                     ;Zehner runter und
 subi xl,-10                ;10 addieren bis zum Überlauf
 brlo pc-2                  ;Überlauf? nein, 2 Zeilen hoch...
 rcall lcd_data             ;ja, Zehner Stelle ausgeben...
 ldi wl,'0'                 ;ASCII-0
 add wl,xl                  ;Einer addieren (Rest war ja positiv)
 rcall lcd_data             ;Einer ausgeben...
 ret                        ;zurück


lcd_printf:     ;Wird vom Makro aufgerufen. Gibt Flash-String an LCD aus.
 push wl
 lpm wl,z+                  ;Zeichen holen
 tst wl                     ;Ende-Kennung? 
 breq pc+3                  ;ja...
 rcall lcd_data             ;nein, ausgeben
 rjmp pc-4                  ;nochmal
 pop wl
 ret

;----------------------------------------------------------------------------

reset:
;Stackpointer initialisieren:
 ldi wl,low(ramend)         
 out SPL,wl
 ldi wl,high(ramend)
 out SPH,wl
;PWM-Ausgänge (LEDs) initialisieren:
 ldi wl, 0xff               ;Port für LEDs (PWM-Ausgänge)
 out lep-1,wl               ;= Ausgang (DDRx=PORTx-1)
;Tasten-Eingänge initialisieren:
 ldi wl, alltast            ;pull-ups für Tasten 
 out tap+2,wl               ;einschalten (PORTx=PINx+2)
;Die Initialisierung der LCD-Ports erfolgt in der LCD-Include-Datei!!!

;alle 8 PWMs erstmal auf 0
 clr soll0
 clr soll1
 clr soll2
 clr soll3
 clr soll4
 clr soll5
 clr soll6
 clr soll7

 clr null                   ;immer 0 
 clr tz0                    ;Definierte Startbedingung 
 clr tz1                    ;für Tastenentprellung
 clr tas
 clr tfl
 clr twz
 clr kanal                  ;mit Kanal 1 (0) beginnen

;Initialisierung Timer0
 ldi wl,1                   ;Vorteiler 1:1
 out tccr0,wl               ;für Timer0
 ldi wl,1<<toie0            ;Überlauf-Interrupt
 out timsk,wl               ;für Timer0 freigeben
 ldi wl,timerwert+12        ;Timer-Startwert, korregiert mit Int-Aufruf12
 mov tsw,wl                 ;definieren
 out tcnt0,tsw              ;und ausgeben
 sei                        ;Interrupts global freigeben
 rcall lcd_init             ;LCD initialisieren      
;Ende der Initialisierung, Programm 'fällt' jetzt in die Hauptschleife

locate 0,0                  ;feststehenden Text Zeile 0
printf txt_zeile0           ;ausgeben
locate 1,0                  ;feststehenden Text Zeile 1
printf txt_zeile1           ;ausgeben
locate 2,0                  ;feststehenden Text Zeile 2
printf txt_zeile2           ;ausgeben
locate 3,0                  ;feststehenden Text Zeile 3
printf txt_zeile3           ;ausgeben


mainloop:               ;Hauptschleife, Endlosschleife
;hier passiert:
;- LCD-Ausgabe,
;- Abfrage von Ereignissen und Reaktion darauf

 locate 0,0+8               ;Ausgabeposition Sollwert
 print83 soll0              ;Sollwert ausgeben

 locate 1,0+8               ;Ausgabeposition Sollwert
 print83 soll1              ;Sollwert ausgeben

 locate 2,0+8               ;Ausgabeposition Sollwert
 print83 soll2              ;Sollwert ausgeben

 locate 3,0+8               ;Ausgabeposition Sollwert
 print83 soll3              ;Sollwert ausgeben

.equ rsp=15      ;Position rechte Spalte

 locate 0,rsp+8             ;Ausgabeposition Sollwert
 print83 soll4              ;Sollwert ausgeben

 locate 1,rsp+8             ;Ausgabeposition Sollwert
 print83 soll5              ;Sollwert ausgeben

 locate 2,rsp+8             ;Ausgabeposition Sollwert
 print83 soll6              ;Sollwert ausgeben

 locate 3,rsp+8             ;Ausgabeposition Sollwert
 print83 soll7              ;Sollwert ausgeben
 rcall tasten               ;eventuelle Tastendrücke abarbeiten

 locate 1,13                ;Position Mitte zweite Zeile
 ldi wl,'1'                 ;Kanalnummer
 add wl,kanal               ;zur Ziffer wandeln
 rcall lcd_data             ;und ausgeben...

 rjmp mainloop              ;fertig, Endlosschleife...

tasten:                 ;UP, fragt entprellte Tasten ab
;zuerst die Kanaltasten:
 sbrc tfl,chanplus          ;Kanal-Plus-Taste betätigt? - nein...
 inc kanal                  ;ja, Kanalnummer erhöhen
 sbrc tfl,chanminus         ;Kanal-Minus-Taste betätigt? - nein...
 dec kanal                  ;ja, Kanalnummer vermindern
 ldi wl,7                   ;Wertebereich (Zählumfang) auf
 and kanal,wl               ;0..7 begrenzen (untere 3 Bits maskieren)

sbrc tfl, EEWRITE          rcall EEPROM_write
sbrc tfl, EEREAD         rcall EEPROM_read

;jetzt die Dimmtasten:
 andi tfl,dimtast           ;alle Tasten außer den Dimmtasten rücksetzen
 brne dimm                  ;war eine Dimmtaste betätigt? - ja...
tasten_e:               ;Ende des UP
 ret                        ;nein, zurück...

dimm:                   ;ändert Sollwert des aktiven Kanals
 clr zh                     ;Pointer auf Sollwert des aktuellen
 mov zl,kanal               ;Kanals (Kanal als Index auf Array)
 ld wl,z                    ;Kopie des Sollwertes holen
 sbrs tfl,dimplus           ;Taste Dimm+? - ja...
 rjmp dimm1                 ;nein, weiter...
;Dimplus-Taste wurde betätigt
 subi wl,-step              ;ja, Sollwert vergrößern
 cpi wl,pwu                 ;PWM-Zählumfang überschritten?
 brcs dimm1                 ;nein...
 ldi wl,pwu                 ;ja, auf PWM-Zählumfang begrenzen
dimm1:
 sbrs tfl,dimminus          ;Taste Dimm-? - ja...
 rjmp dimm2                 ;nein, weiter...
;Dimminus-Taste wurde betätigt
 subi wl,step               ;ja, Sollwert vermindern
 brcc dimm2                 ;Unterlauf? nein...
 clr wl                     ;ja, auf 0 setzen
dimm2:
 cbr tfl,dimtast            ;Dimmtasten zurücksetzen (Job ist ja  erledigt)
 st z,wl                    ;Sollwert ins Array zurückschreiben
 rjmp tasten_e              ;fertig...
 

Tim0_OVF:                   ;ISR Timer0-Überlauf
 in sregtemp, sreg          ;Sreg sichern
 out tcnt0,tsw              ;Timer auf Startwert setzen
 inc pwz                    ;PWM-Treppenzähler erhöhen
 cpi pwz, pwu               ;PWM-Zählumfang erreicht?
 brne Time0_a               ;nein... (die 3 Punkte bedeuten bei mir Sprung)
;hier landet das Programm nur bei jeder hundertsten Runde
 clr pwz                    ;ja, von vorn zählen und Tasten abfragen
Tastenabfrage:  ;Entprellroutine (Algorithmus geklaut bei Peter Dannegger...)
 in temp,tap    ;Tastenport einlesen (gedrückt=L)
 com temp       ;invertieren (gedrückt=H)
 eor temp,tas   ;nur Änderungen werden H
 and tz0,temp   ;Prellzähler unveränderter Tasten löschen (Bit0)
 and tz1,temp   ;Prellzähler unveränderter Tasten löschen (Bit1)
 com tz0        ;L-Bit zählen 0,2,->1, 1,3,->0
 eor tz1,tz0    ;H-Bit zählen 0,2,->tz1 toggeln
 and temp,tz0   ;Änderungen nur dann erhalten, wenn im Prellzähler
 and temp,tz1   ;beide Bits gesetzt sind (Zählerstand 3)
 eor tas,temp   ;erhaltene Änderungen toggeln alten (gültigen) Tastenstatus
 and temp,tas   ;nur (neu) gedrückte Tastenbits bleiben erhalten
 or tfl,temp    ;und zugehörige Bits setzen (gelöscht wird nach Abarbeitung)
;tmp ist wieder frei, tas enthält den entprellten Tastenstatus,
;tfl die neu gerückten Tasten
Tastendauer:
 mov temp,tas       ;Tastenzustand kopieren
 andi temp,dimtast  ;nur Dimm-Tasten mit Wiederholfunktion stehen lassen
 tst temp           ;ist eine Taste betätigt?
 breq Tastendauer0  ;nein, Dauer auf Startwert...
 dec twz            ;ja, Zähler runter
 brne Tastenabfrage_e   ;Dauer abgelaufen? - nein...
 or tfl,temp        ;ja, noch aktive Tasten übernehmen
 ldi twz,twz1       ;und Zähler auf Wiederholwert setzen
Tastenabfrage_e:
 ;in "tfl" stehen jetzt wieder die Flags der länger betätigten Tasten
 ;sie werden nach Abarbeitung gelöscht

Time0_a:        ;Vergleich der einzelnen PWM-Werte mit dem PWM-Treppenzähler
                ;(Idee geklaut bei Peter Dannegger)
 cp pwz, soll7  ;Sollwert erreicht? (Ergebnis im Carry)
 rol temp       ;Carry-Bits "einsammeln", dieses wird bis Bit7 durchgeschoben
 cp pwz, soll6
 rol temp                   ;Bit 6
 cp pwz, soll5
 rol temp                   ;Bit 5
 cp pwz, soll4
 rol temp                   ;Bit 4
 cp pwz, soll3
 rol temp                   ;Bit 3
 cp pwz, soll2
 rol temp                   ;Bit 2
 cp pwz, soll1
 rol temp                   ;Bit 1
 cp pwz, soll0
 rol temp                   ;Bit 0
 com temp                   ;invertieren da low-aktive LED im STK500
 out lep, temp              ;Ausgabe
 out sreg, sregtemp         ;Sreg wiederherstellen
 reti                       ;ISR fertig...

Tastendauer0:       ;Reset Dauerzähler
 ldi twz,twz0           ;Tastendauerzähler auf Startwert
 rjmp Tastenabfrage_e   ;fertig...


txt_zeile0: .db "Kanal 1    %   Kanal 5    %",0
txt_zeile1: .db "Kanal 2    %   Kanal 6    %",0
txt_zeile2: .db "Kanal 3    %   Kanal 7    %",0
txt_zeile3: .db "Kanal 4    %   Kanal 8    %",0




EEPROM_read:
 ; Wait for completion of previous write
sbic EECR,EEWE
rjmp EEPROM_read
; Set up address (r18:r17) in address register
out EEARH, SOLL0 ;r0
out EEARL, r15
; Start eeprom read by writing EERE
sbi EECR,EERE
; Read data from data register
in SOLL0,EEDR
ret


EEPROM_write:
; Wait for completion of previous write
sbic EECR,EEWE 
rjmp EEPROM_write
; Set up address (r18:r17) in address register
out EEARH, SOLL0 ; R0
out EEARL, R15
; Write data (r16) to data register
out EEDR,SOLL0

; Write logical one to EEMWE
sbi EECR,EEMWE
; Start eeprom write by setting EEWE
sbi EECR,EEWE

ret