.include "m644def.inc"

.cseg
.equ CS_LCD = 2

.def temp_0 = r16
.def temp_1 = r17
.def temp_2 = r18
.def temp_3 = r19
.def lcddata = r20
.def lcdcommand = r21
.def lcdbyte = r22

.org 0x0000 rjmp MAIN
;------------------------------------------------------------
MAIN:		ldi	temp_0, LOW(RAMEND)
			out	SPL, temp_0
			ldi	temp_0, HIGH(RAMEND)
			out	SPH, temp_0

			;CS(LCD)
			ldi temp_0, (1<<DDA2)
			out DDRA, temp_0
			ldi temp_0, (1<<PA2)
			out PORTA, temp_0
			;SPI_SCK, SPI_MOSI, SPI_MOSI
			ldi temp_0, (1<<DDB7)|(0<<DDB6)|(1<<DDB5)
			out DDRB, temp_0
			
			rcall LCD_INIT

			END:
			ldi lcddata, 0x35
			rcall LCD_DATA
			rjmp END
;-------------------------------------------------------------------
SPI_INIT_5MHZ_LCD:	push temp_0
					ldi temp_0, (0<<SPI2X)
					out SPSR, temp_0
					ldi temp_0, (0<<SPIE)|(1<<SPE)|(1<<DORD)|(1<<MSTR)|(1<<CPOL)|(1<<CPHA)|(1<<SPR1)|(0<<SPR0)
					out SPCR, temp_0
					pop temp_0
					ret
;Initialize SPI:	Transfer LSB first
;					SCK = HIGH when idle
;					SCK = MCLK/64
;					Take over Data at the rising Edge
;-------------------------------------------------------------------
LCD_DATA:	push temp_0
			push temp_1
			push temp_2
			set	;Use it to send Data before call LCD_SEND
			mov lcdbyte, lcddata
			rcall LCD_SEND
			pop temp_2
			pop temp_1
			pop temp_0
			ret
;--------------------------------------------------------------------
LCD_COMMAND:push temp_0
			push temp_1
			push temp_2
			clt	;Use it to send Command before call LCD_SEND
			mov lcdbyte, lcdcommand
			rcall LCD_SEND
			pop temp_2
			pop temp_1
			pop temp_0
			ret
;----------------------------------------------------------------------
LCD_SEND:	;Prepare Data/ Command
			rcall SPI_INIT_5MHZ_LCD
			;Start Byte
			ldi temp_0, 0b00011111
			bld temp_0, 6
			;Data - lower Nibble
			mov temp_1, lcdbyte
			andi temp_1, 0b00001111
			;Data - higher Nibble
			swap lcdbyte
			andi lcdbyte, 0b00001111

			;Send Data/ Command
			cbi PORTA, CS_LCD
			nop
			;Start Byte
			out SPDR, temp_0
			rcall WAIT_SPI
			;Data - lower Nibble
			out SPDR, temp_1
			rcall WAIT_SPI
			;Data - higher Nibble
			out SPDR, lcdbyte
			rcall WAIT_SPI
			sbi PORTA, CS_LCD

			rcall CHECK_BF
			ret
;-----------------------------------------------------------------------
CHECK_BF:	;Prepare Command
			rcall SPI_INIT_5MHZ_LCD
			;Start Byte
			ldi temp_0, 0b00111111
			;Read BF
BUSY:		rcall WAIT_8us
			cbi PORTA, CS_LCD
			;Start Byte
			out SPDR, temp_0
			rcall WAIT_SPI
			nop
			nop
			in temp_1, SPDR
			rcall WAIT_SPI
			sbi PORTA, CS_LCD
			sbrc temp_1, 7
			rjmp BUSY
			ret
;-------------------------------------------------------------------------
LCD_INIT:	rcall WAIT_20ms
			;Function set - 8 Bit Modus, clear RE Bit
			ldi	lcdcommand, 0b00110000
			rcall LCD_COMMAND
			;Entry mode set - increment cursor automaticly after write data
			ldi	lcdcommand, 0b00000110
			rcall LCD_COMMAND
			;Function Set - 8 Bit Modus, set RE Bit & enable cursor blink mode BE=1
			ldi	lcdcommand, 0b00110110
			rcall LCD_COMMAND
			;Extended function set - enable 4 line modus & invertin cursor
			ldi	lcdcommand, 0b00001011
			rcall LCD_COMMAND
			;set SEGRAM adress (Icons) - set start adress of the icon line
			ldi	lcdcommand, 0b01000000
			rcall LCD_COMMAND
			;write 0x00 16 times to erase the icons
			ldi	lcddata, 0x00
			ldi temp_2, 0x10 ;Loop Counter
NEXT_ICON:	rcall LCD_DATA
			dec temp_2
			cpi temp_2, 0x00
			brne NEXT_ICON
			;Function set - 8 Bit Modus, clear RE Bit
			ldi	lcdcommand, 0b00110000
			rcall LCD_COMMAND
			;Display ON/OFF control - Display on, cursor off & cursor blink enable
			ldi	lcdcommand, 0b00001100
			rcall LCD_COMMAND
			;Clear Display - clear all signs on display and set cursor to column 1, row 1
			ldi	lcdcommand, 0b00000001
			rcall LCD_COMMAND
			ret
;-----------------------------------------------------------------
WAIT_SPI:	in temp_2, SPSR
			bst temp_2,7
			brts END_WAIT
			jmp WAIT_SPI
END_WAIT:	ret
;----------------------------------------------------------------
WAIT_20ms:	ldi temp_0,0x34
			Loop3:	ldi temp_1,0x34
				Loop2:	ldi temp_2,0x34
					Loop1: 	dec temp_2
							brne Loop1
						dec temp_1
						brne Loop2
					dec temp_0
					brne Loop3
			ret
;-----------------------------------------------------------------
WAIT_8us:	ldi temp_0,0x4A
Loop_8us:	dec temp_0
			brne Loop_8us
			ret