Die Ausgangsgleichungen:

gl1:k1*sin(t1/sqrt(L*C))=k4*sin((toff-t3)/sqrt(L*C));

gl2:k3*sin(t3/sqrt(L*C))=k2*sin((ton-t1)/sqrt(L*C));

Der Übersicht k1/k4=u, k3/k2=v und sqrt(L·C)=r substituieren:

gl1/k4, k1=k4*u$
gl1a: subst(r, sqrt(L*C), %);

gl2/k2, k3=k2*v$
gl2a: subst(r, sqrt(L*C), %);

Anwendung des Additionstheorems:

gl1b: trigexpand(expand(gl1a));

gl2b: trigexpand(expand(gl2a));

Cos durch sin ausdrücken:

gl1c: subst(sqrt(1-sin(t3/r)^2), cos(t3/r), gl1b);

gl2c: subst(sqrt(1-sin(t1/r)^2), cos(t1/r), gl2b);

sin(t1/r)=x1 und sin(t3/r)=x3 substituieren:

subst(x1, sin(t1/r), [gl1c, gl2c])$
[gl1d, gl2d]: subst(x3, sin(t3/r), %)$
gl1d;
gl2d;

Gleichungen so umstellen, dass die Wurzeln nicht mehr in einer Summe stehen:

gl1e: gl1d-part(gl1d,2,2);
gl2e: gl2d-part(gl2d,2,2);

Quadrieren, um die Wurzeln wegzubekommen:

gl1f: gl1e^2;
gl2f: gl2e^2;

Alles auf die linke Seite bringen und die Beziehung sin²(x)+cos²(x)=1 anwenden:

gl1g: trigsimp(gl1f-rhs(gl1f));
gl2g: trigsimp(gl2f-rhs(gl2f));

cos(ton/r)=s und cos(toff/s)=t substituieren:

gl1h: subst(t, cos(toff/r), gl1g);
gl2h: subst(s, cos(ton/r), gl2g);

x3² bzw. x1² eliminieren, so dass jeweils eine lineare Gleichung in x3 und x1 entsteht:

gl3: factor(v^2*gl1h-gl2h);
gl4: factor(gl1h-u^2*gl2h);

Diese Gleichungen nach x3 bzw. x1 auflösen

gl3a: solve(gl3, x3);
gl4a: solve(gl4, x1);

1. Gleichung in die 2. Gleichung und
2. Gleichung in die 1. Gleichung einsetzen:

gl5: gl4a, gl3a;
gl6: gl3a, gl4a;

Anmerkung: Wenn man diese Gleichungen durch x1 bzw. x3 dividiert, sieht man, dass sie biquadratisch sind.
Da Maxima aber auch allgemeine Gleichungen 4. Grades lösen kann, ist dieser Schritt hier nicht notwendig.

1. Gleichungen nach x1 und 2. Gleichung nach x3 auflösen, es gibt jeweils 4 Lösungen:

gl5a: factor(solve(gl5, x1));
gl6a: factor(solve(gl6, x3));

Anhand eines Beispiels ermitteln, welche der 4 Lösungen die gewünschte ist:

sqrt(200e-6*100e-6)$
bsp:[r=%, u=2.5, v=3.2, s=cos(70e-6/%), t=cos(30e-6/%)];

x1=r*asin(map(rhs, gl5a)), bsp;

x3=r*asin(map(rhs, gl6a)), bsp;

Die jeweils 4. Lösung entspricht der des iterativen Verfahrens, also lauten die allgemeinen Lösungen

t1=r*asin(x1);
t3=r*asin(x3);

wobei

gl5a[4];
gl6a[4];
s=cos(ton/r);
t=cos(toff/r);
u=k1/k4;
v=k3/k2;
r=sqrt(L*C);