.def	temp	=	r16
.def	temp1	=	r17
.def	temp2	=	r18
.def	para1	=	r20
.def	para2	=	r21


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;	LCD Display

.equ	ChipClock	=	8000
		; in kHZ
.equ	LCD_PORT	=	PORTC	; port where LCD is connected to
.equ	LCD_SDAT	=	4		; first pin of DATA (0 or 4 allowed!)
.equ	LCD_RS		=	0		; pin -> RS
.equ	LCD_RW		=	1		; pin -> RW
.equ	LCD_E		=	2		; pin -> E

;	command flags
.equ	LCD_CLR				=	0x01      ; DB0: clear display
.equ	LCD_HOME			=	0x02      ; DB1: return to home position
.equ	LCD_ENTRY_MODE		=	0x04      ; DB2: set entry mode
.equ	LCD_ENTRY_INC		=	0x02      ;   DB1: 1=increment, 0=decrement
.equ	LCD_ENTRY_SHIFT		=	0x01      ;   DB2: 1=display shift on
.equ	LCD_ON				=	0x08      ; DB3: turn lcd/cursor on
.equ	LCD_ON_DISPLAY		=	0x04      ;   DB2: turn display on
.equ	LCD_ON_CURSOR		=	0x02      ;   DB1: turn cursor on
.equ	LCD_ON_BLINK		=	0x01      ;     DB0: blinking cursor ?
.equ	LCD_MOVE			=	0x10      ; DB4: move cursor/display
.equ	LCD_MOVE_DISP		=	0x08      ;   DB3: move display (0-> cursor) ?
.equ	LCD_MOVE_RIGHT		=	0x04      ;   DB2: move right (0-> left) ?
.equ	LCD_FUNCTION		=	0x20      ; DB5: function set
.equ	LCD_FUNCTION_8BIT	=	0x10      ;   DB4: set 8BIT mode (0->4BIT mode)
.equ	LCD_FUNCTION_2LINES	=	0x08      ;   DB3: two lines (0->one line)
.equ	LCD_FUNCTION_10DOTS	=	0x04      ;   DB2: 5x10 font (0->5x7 font)
.equ	LCD_CGRAM			=	0x40      ; DB6: set CG RAM address
.equ	LCD_DDRAM			=	0x80      ; DB7: set DD RAM address
.equ	LCD_BUSY			=	0x80      ; DB7: LCD is busy

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;	Program

; [...]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                 LCD-Routinen                ;;
;;                 ============                ;;
;;              (c)andreas-s@web.de            ;;
;;          modified by wmark@hurrikane.de     ;;
;;                                             ;;
;; 4bit-Interface                              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

 
 
 ;sendet ein Datenbyte an das LCD
lcd_data:
           mov temp2, temp1             ;"Sicherungskopie" für
                                        ;die Übertragung des 2.Nibbles
;.if LCD_SDAT
		swap temp2                   ;Vertauschen
;.else
;		swap temp1
;.endif
           andi temp1, 0x0f<<LCD_SDAT   ;oberes Nibble auf Null setzen
           sbr temp1, 1<<LCD_RS         ;entspricht 0b00010000
           out LCD_PORT, temp1             ;ausgeben
           rcall lcd_enable             ;Enable-Routine aufrufen
                                        ;2. Nibble, kein swap da es schon
                                        ;an der richtigen stelle ist
           andi temp2, 0x0f<<LCD_SDAT   ;obere Hälfte auf Null setzen 
           sbr temp2, 1<<LCD_RS         ;entspricht 0b00010000
           out LCD_PORT, temp2             ;ausgeben
           rcall lcd_enable             ;Enable-Routine aufrufen
           rcall delay50us              ;Delay-Routine aufrufen
           ret                          ;zurück zum Hauptprogramm

 ;sendet einen Befehl an das LCD
lcd_command:                            ;wie lcd_data, nur ohne RS zu setzen
           mov temp2, temp1
;.if LCD_SDAT
		swap temp2                   ;Vertauschen
;.else
;		swap temp1
;.endif
           andi temp1, 0x0f<<LCD_SDAT
           out LCD_PORT, temp1
           rcall lcd_enable
           andi temp2, 0x0f<<LCD_SDAT
           out LCD_PORT, temp2
           rcall lcd_enable
           rcall delay50us
           ret

 ;erzeugt den Enable-Puls
lcd_enable:
           sbi LCD_PORT, LCD_E         ;Enable high
           nop                          ;3 Taktzyklen warten
           nop
           nop
           cbi LCD_PORT, LCD_E         ;Enable wieder low
           ret                          ;Und wieder zurück                     

 ;Pause nach jeder Übertragung
delay50us:                              ;50us Pause (plus zwei op)
           ldi  temp1, ((50*(ChipClock/1000)) / 3)
delay50us_:dec  temp1
           brne delay50us_
           ret                          ;wieder zurück

 ;Längere Pause für manche Befehle
delay5ms:                               ;5ms Pause
           ldi  temp1, (0x21 * ChipClock/4000)
WGLOOP0:   ldi  temp2, 0xC9
WGLOOP1:   dec  temp2
           brne WGLOOP1
           dec  temp1
           brne WGLOOP0
           ret                          ;wieder zurück

 ;Initialisierung: muss ganz am Anfang des Programms aufgerufen werden
lcd_init:
		   ldi temp, 0xff				; PortC als Ausgang einstellen
		   out DDRC, temp
           ldi	temp3,50
powerupwait:
           rcall	delay5ms
           dec	temp3
           brne	powerupwait
           ldi temp1, 0x03<<LCD_SDAT    ;muss 3mal hintereinander gesendet
           out LCD_PORT, temp1             ;werden zur Initialisierung
           rcall lcd_enable             ;1
           rcall delay5ms
           rcall lcd_enable             ;2
           rcall delay5ms
           rcall lcd_enable             ;und 3!
           rcall delay5ms
           ldi temp1, 0x02<<LCD_SDAT    ;4bit-Modus einstellen
           out LCD_PORT, temp1
           rcall lcd_enable
           rcall delay5ms
           ldi temp1, LCD_FUNCTION | LCD_FUNCTION_2LINES        ; noch was einstellen...
           rcall lcd_command
           ldi temp1, LCD_ON | LCD_ON_DISPLAY        ;...nochwas...
           rcall lcd_command
           ldi temp1, LCD_ENTRY_MODE        ;endlich fertig
           rcall lcd_command
           ret

 ;Sendet den Befehl zur Löschung des Displays
lcd_clear:
           ldi temp1, LCD_CLR   ;Display löschen
           rcall lcd_command
           rcall delay5ms
           ret