.include "m328Pdef.inc"
 
.def temp = R16
.def temp1 = R17
.def temp2 = R18

.equ F_CPU = 16000000                           ; Systemtakt in Hz
.equ BAUD  = 2400                               ; Baudrate
 
; Berechnungen
.equ UBRR_VAL   = ((F_CPU+BAUD*8)/(BAUD*16)-1)  ; clever runden
.equ BAUD_REAL  = (F_CPU/(16*(UBRR_VAL+1)))     ; Reale Baudrate
.equ BAUD_ERROR = ((BAUD_REAL*1000)/BAUD-1000)  ; Fehler in Promille
 
.if ((BAUD_ERROR>10) || (BAUD_ERROR<-10))       ; max. +/-10 Promille Fehler
  .error "Systematischer Fehler der Baudrate grösser 1 Prozent und damit zu hoch!"
.endif


;IRQ-Sprungtabelle

.org 0x00

	rjmp reset        ; Reset Handler

.org OC1Aaddr

	rjmp TIM1_COMPA   ; Timer1 CompareA Handler


reset:

	; Stackpointer initialisieren
 
	ldi temp, LOW(RAMEND)
	out SPL, temp
	ldi temp, HIGH(RAMEND)
	out SPH, temp

	; Frame-Format: 8N1
 
	ldi temp, 1<<UCSZ00 | 1<<UCSZ01
	sts UCSR0C, temp
 
	; Baudrate einstellen
 
	ldi temp, HIGH(UBRR_VAL)
	sts UBRR0H, temp
	ldi temp, LOW(UBRR_VAL)
	sts UBRR0L, temp
 

	; TX aktivieren


	ldi temp, 1<<TXEN0
	sts UCSR0B, temp

	;PortB einstellen, für LA

	ldi temp, 1<<DDB0 | 1<<DDB5
	out DDRB, temp
	cbi PORTB, PORTB0
	cbi PORTB, PORTB5

	; Timer1 stoppen und zurücksetzen (wurde vom Bootloader schon benutzt)

	ldi temp, 0
	sts TCCR1B, temp
	sts TCNT1H, temp
	sts TCNT1L, temp

	; Timer initalisieren. Interrupt alle 1 Sek
	
	ldi temp, 0x3D								;Output Compare mit 15.624 vorladen
	sts OCR1AH, temp
	ldi temp, 0x08
	sts OCR1AL, temp
	
	ldi temp, 1<<WGM12 | 1<<CS10 | 1<<CS12		; Timer1 CTC Modus, prescaler 1024 @ 16MHz
	sts TCCR1B, temp
	
	ldi temp, 1<<OCIE1A
	sts TIMSK1, temp

	sei


main:

	sbi PORTB, PORTB0
	sbi PORTB, PORTB5
	rjmp main


TIM1_COMPA:

	cbi PORTB, PORTB0
	cbi PORTB, PORTB5

	ldi temp1, 11
	ldi ZL, LOW(HW*2)
	ldi ZH, HIGH(HW*2)

txloop1:

	lpm temp, Z+

txloop2:
	lds temp2, UCSR0A
	sbrs temp2, UDRE0		; warten bis Sendepuffer bereit ist
	rjmp txloop2
	sts UDR0, temp			; Byte senden

	dec temp1
	cpi temp1, 0
	brne txloop1


txwait:						;warten bis Sendepuffer leer ist
	lds temp, UCSR0A
	sbrs temp, TXC0
	rjmp txwait

	reti

.CSEG

HW: .db "Hello World"