// Ersatzboard Drucksensor für Pluggit V4
// https://www.mikrocontroller.net/topic/477458
// Eingesetzer Controller: ATTINY85 / 1MHz int
// Sensoren: 2 Stück Sensirion SDP-810-500Pa

// Erstellt: 15.08.21  Daniel F.

// neu V2: Testfunktion um beide Ausgänge auf 10V zu schalten
// neu V2: Dämpfung des Sensorsignals
// neu V3: PWM nun auf Pins 9&10 mit 12bit Auflösung
// neu V3: Nachbildung auch von der neueren SDP1000-L05-Platine wenn Pin2 auf GND gesetzt ist
// neu V4: Umstellung auf ATTINY85


const int PWM10VS1 = 3960;   //PWM(0...4095) für Justage 10V-Ausgangsspannung Sensor1 (Abgleich Analogschaltung Spannungsverstärker)
const int PWM10VS2 = 3960;   //PWM(0...4095) für Justage 10V-Ausgangsspannung Sensor2 (Abgleich Analogschaltung Spannungsverstärker)

#include <Wire.h>

volatile int Dac[2];
volatile uint8_t* Port[] = { &OCR1A, &OCR1B };
volatile int Cycle = 0;

// Overflow interrupt
ISR (TIMER1_OVF_vect) {
  static int rem[2];
  for (int chan=0; chan<2; chan++) {
    int remain;
    if (Cycle == 0) remain = Dac[chan]; else remain = rem[chan];
    if (remain >= 256) { *Port[chan] = 255; remain = remain - 256; }
    else { *Port[chan] = remain; remain = 0; }
    rem[chan] = remain;
  }
  Cycle = (Cycle + 1) & 0x0F;
}


void analogWrite12 (int chan, int value) {
  cli(); Dac[chan] = value; sei();
}


float Druck1=0.0;
float Druck2=0.0;
int PWM1=0;
int PWM2=0;
boolean SDP1000L05;


void setup() {
  // Timer/Counter1 doing PWM on OC1A (PB1) and OC1B (PB4)
  TCCR1 = 1<<PWM1A | 1<<COM1A0 | 1<<CS10;
  GTCCR = 1<<PWM1B | 1<<COM1B0;
  TIMSK = TIMSK | 1<<TOIE1;
  
  pinMode(1, OUTPUT);                  //PWM-Ausgang Druck1
  pinMode(4, OUTPUT);                  //PWM-Ausgang Druck2
  
  Wire.begin();
  SDP1000L05 = !digitalRead(3);         //wenn Pin3 auf GND dann eine SDP1000L05-Platine (Null=1V) nachbilden 
  }


void loop() {

  multiplexer(0);                       // Schalte I2C-Multiplexer PCA9540B auf Kanal0 (Sensor1)
  
  Druck1=(Druck1+SDP810lesen())/2.0;    // Drucksensor1 lesen und Dämpfung
  
  multiplexer(1);                       // Schalte I2C-Multiplexer PCA9540B auf Kanal1 (Sensor2)
  
  Druck2=(Druck2+SDP810lesen())/2.0;    // Drucksensor2 lesen und Dämpfung

  if (SDP1000L05) {                                                 //Nachbildung der neuen Platine mit SDP1000L05-Sensoren
    PWM1 = mapf(Druck1, -6.43, 146.3, PWM10VS1*0.0825, PWM10VS1/2.0);  //Druckbereich auf Ausgangssignal anpassen
    PWM2 = mapf(Druck2, -6.43, 146.3, PWM10VS1*0.0825, PWM10VS2/2.0);  //-6.4Pa=0.825V bis 146.3Pa=5.00V

    PWM1 = constrain(PWM1, 0, PWM10VS1/2);                          //Wertebereich PWM begrenzen, max 5.0V
    PWM2 = constrain(PWM2, 0, PWM10VS2/2); 
  }
  else{                                                             //Nachbildung der alten Platine mit SMI5552-003-D-Sensoren
    PWM1 = mapf(Druck1, -70.0, 284.0, 0.0, PWM10VS1);               //Druckbereich auf Ausgangssignal anpassen
    PWM2 = mapf(Druck2, -70.0, 284.0, 0.0, PWM10VS2);               //-70Pa=0.0V bis 284Pa=10.0V
    
    PWM1 = constrain(PWM1, 0, PWM10VS1);                            //Wertebereich PWM begrenzen, max 10.0V
    PWM2 = constrain(PWM2, 0, PWM10VS2); 
  }

  analogWrite12(1, PWM1);   //1=PB4 Sensor1
  analogWrite12(0, PWM2);   //0=PB1 Sensor2

}

void multiplexer(bool kanal){
  Wire.beginTransmission(0x70); // I2C-Multiplexer PCA9540B
  Wire.write(0x04+kanal);       // Kanal 0 oder 1
  Wire.endTransmission(); 
}


float SDP810lesen(){
  
  int Druck=0;
  
  // Lesebefehl an Drucksensor (SDP810) senden
  Wire.beginTransmission(0x25);   // transmit to device
  Wire.write(0x36);               // Measurement triggering
  Wire.write(0x2F);               // Measurement triggering
  Wire.endTransmission();         // stop transmitting

  delay(50);                      // Messzeit=45ms

  // 2 Bytes anfordern
  Wire.requestFrom(0x25, 2);      // request 2 bytes from slave device

  // und lesen
  if (2 <= Wire.available()) {
    Druck = Wire.read();          // high byte lesen
    Druck = Druck << 8;           // nach links schieben
    Druck |= Wire.read();         // low byte lesen OR high byte
  }
  return Druck/56.0;              // anpassen auf Pa (Teiler ist Normal 60, nach Korrektur mit ca 1m 4mm-Schlauch neuer Teiler 56)
}


int mapf(float x, float in_min, float in_max, float out_min, float out_max)
{
    return (x - in_min) * (out_max - out_min) / (in_max - in_min) + out_min;
}