.INCLUDE "m1284pdef.inc"

;Hardware ####################################################################

;gemeinsam für beide Känale: interne Pullups aktivieren oder nicht
.EQU ENC_PULLUPS	= 1
;-----------------------------------------------------------------------------

;Symbole für den Hardwarekram, anpassbar, solange sichergestellt ist, dass
;unterschiedliche Interrupts für die beiden Encoderkanäle benutzt werden und
;natürlich auch unterschiedliche Pins. 
;Sprich: ENC_A_IVEC und ENC_B_IVEC müssen verschieden sein und 
;ENC_A_PRT+ENC_A_BIT und ENC_B_PRT+ENC_B_BIT müssen verschieden sein.
;Und natürlich muss alles zueinander "passig" deklariert sein und auch zur 
;Zielhardware passen... 
;-----------------------------------------------------------------------------
.EQU ENC_A_PCINT	= 1						;auf null setzen für INTx

.EQU ENC_A_PIN		= PIND
.EQU ENC_A_BIT		= PIND2
.IF ENC_PULLUPS
.EQU ENC_A_PRT		= PORTD					;muss konfiguriert werden, wenn Pullups aktiv sein sollen  
.ENDIF


.IF ENC_A_PCINT
.EQU ENC_A_MSK		= PCMSK3				;muss konfiguriert werden für PCINT  
.ELSE
.EQU ENC_A_SNSREG	=						;diese drei Werte müssen konfiguriert
.EQU ENC_A_SNSMSK	=						;werden für INTx. Und zwar für Sensibilität
.EQU ENC_A_SNSVAL	=						;in beiden Richtungen.
.ENDIF

.EQU ENC_A_IMSKREG	= PCICR
.EQU ENC_A_IFLGREG	= PCIFR
.EQU ENC_A_IBIT		= PCIE3 

.EQU ENC_A_IVEC		= PCI3addr
;.............................................................................

.EQU ENC_B_PCINT	= 0						;auf !null setzen für PCINT

.EQU ENC_B_PIN		= PIND
.EQU ENC_B_BIT		= PIND3
.IF ENC_PULLUPS
.EQU ENC_B_PRT		= PORTD					;muss konfiguriert werden, wenn Pullups aktiv sein sollen  
.ENDIF

.IF ENC_B_PCINT
.EQU ENC_B_MSK		= 						;muss konfiguriert werden für PCINT  
.ELSE
.EQU ENC_B_SNSREG	= EICRA					;diese drei Werte müssen konfiguriert
.EQU ENC_B_SNSMSK	= (1<<ISC11)|(1<<ISC10)	;werden für INTx. Und zwar für Sensibilität
.EQU ENC_B_SNSVAL	= 1<<ISC10				;in beiden Richtungen.
.ENDIF

.EQU ENC_B_IMSKREG	= EIMSK
.EQU ENC_B_IFLGREG	= EIFR
.EQU ENC_B_IBIT		= INT1

.EQU ENC_B_IVEC		= Int1addr

;Helpermacros für MMIO-Unterstützung #########################################

.MACRO UIN
.IF @1 < $40
	in @0,@1
.ELSE
	lds @0,@1
.ENDIF
.ENDMACRO				

.MACRO UOUT
.IF @0 < $40
	out @0,@1
.ELSE
	sts @0,@1
.ENDIF
.ENDMACRO

;reservierte Register ########################################################

.DEF NULL = R11		;immer 0
.DEF CNT0 = R12		;vier Register für den 32Bit-Zähler
.DEF CNT1 = R13
.DEF CNT2 = R14
.DEF CNT3 = R15
.DEF TMP  = R16		;scratch
.DEF STAT = R17		;Status des Decoders 

;interne Statusflags #########################################################

;So nur zu verstehen außerhalb der ISRs, bestenfalls ab dem common-Teil der ISRs
;innerhalb der Einzel-ISRs wird die Bedeutung aus Optimierungsgründen
;gelegentlich verändert 
.EQU STAT_A = 0		;letzter bekannter Status von Kanal A
.EQU STAT_B = 1		;letzter bekannter Status von Kanal B
.EQU STAT_D = 2		;aktuelle Zählrichtung (gültig, wenn STAT_V gesetzt ist, 1=negativ)
.EQU STAT_V = 3		;Zählrichtung ist gültig (ab allerersten Interupt immer der Fall)

;Vektortabelle ###############################################################

.CSEG
.ORG 0
	rjmp init
.IF ENC_A_IVEC < ENC_B_IVEC
.ORG ENC_A_IVEC
	rjmp enc_a_handler
.ORG ENC_B_IVEC
	rjmp enc_b_handler
.ELSE
.ORG ENC_B_IVEC
	rjmp enc_b_handler
.ORG ENC_A_IVEC
	rjmp enc_a_handler
.ENDIF

;Code ########################################################################

.CSEG

enc_a_handler:
	UIN TMP,ENC_A_IMSKREG
	andi TMP,~(1<<ENC_A_IBIT)
	UOUT ENC_A_IMSKREG,TMP
	ldi TMP,1<<ENC_B_IBIT
	UOUT ENC_B_IFLGREG,TMP
	UIN TMP,ENC_B_IMSKREG
	ori TMP,1<<ENC_B_IBIT
	UOUT ENC_B_IMSKREG,TMP

	clr TMP
	sbic ENC_B_PIN,ENC_B_BIT
	ori TMP,1<<STAT_B
	eor TMP,STAT
	andi TMP,1<<STAT_B
	breq enc_a_step

	ori TMP,(1<<STAT_A)|(1<<STAT_D)
	eor STAT,TMP
	ldi TMP,2
	rjmp enc_common_cnt

enc_a_step:
	sbrc STAT,STAT_V
	rjmp enc_a_notfst

	ldi TMP,1<<STAT_D
	sbrs STAT,STAT_A
	eor STAT,TMP
	sbrs STAT,STAT_B
	eor STAT,TMP	
	ldi TMP,1<<STAT_V

enc_a_notfst:
	ori TMP,1<<STAT_A
	eor STAT,TMP
	ldi TMP,1
	rjmp enc_common_cnt
;-----------------------------------------------------------------------------

enc_b_handler:
	UIN TMP,ENC_B_IMSKREG
	andi TMP,~(1<<ENC_B_IBIT)
	UOUT ENC_B_IMSKREG,TMP
	ldi TMP,1<<ENC_A_IBIT
	UOUT ENC_A_IFLGREG,TMP
	UIN TMP,ENC_A_IMSKREG
	ori TMP,1<<ENC_A_IBIT
	UOUT ENC_A_IMSKREG,TMP

	clr TMP
	sbic ENC_A_PIN,ENC_A_BIT
	ori TMP,1<<STAT_A
	eor TMP,STAT
	andi TMP,1<<STAT_A
	breq enc_b_step

	ori TMP,(1<<STAT_B)|(1<<STAT_D)
	eor STAT,TMP
	ldi TMP,2
	rjmp enc_common_cnt

enc_b_step:
	sbrc STAT,STAT_V
	rjmp enc_b_notfst

	ldi TMP,1<<STAT_D
	sbrc STAT,STAT_A
	eor STAT,TMP
	sbrs STAT,STAT_B
	eor STAT,TMP	
	ldi TMP,1<<STAT_V

enc_b_notfst:
	ori TMP,1<<STAT_B
	eor STAT,TMP
	ldi TMP,1
;-----------------------------------------------------------------------------

enc_common_cnt:
	sbrs STAT,STAT_D
	rjmp enc_common_up
	sub CNT0,TMP
	sbc CNT1,NULL 
	sbc CNT2,NULL 
	sbc CNT3,NULL 
	reti

enc_common_up:
	add CNT0,TMP
	adc CNT1,NULL
	adc CNT2,NULL
	adc CNT3,NULL
	reti
;-----------------------------------------------------------------------------

init:
	clr NULL
	clr CNT0
	clr CNT1
	clr CNT2
	clr CNT3

.IF ENC_PULLUPS
	UIN TMP,ENC_A_PRT,TMP
	ori TMP,1<<ENC_A_BIT
	UOUT ENC_A_PRT,TMP
.ENDIF
.IF ENC_A_PCINT
	ldi TMP,1<<ENC_A_BIT
	UOUT ENC_A_MSK,TMP
.ELSE
	UIN TMP,ENC_A_SNSREG
	andi TMP,~ENC_A_SNSMSK
	ori TMP,ENC_A_SNSVAL
	UOUT ENC_A_SNSREG,TMP
.ENDIF

.IF ENC_PULLUPS
	UIN TMP,ENC_B_PRT
	ori TMP,1<<ENC_B_BIT
	UOUT ENC_B_PRT,TMP
.ENDIF
.IF ENC_B_PCINT
	ldi TMP,1<<ENC_B_BIT
	UOUT ENC_B_MSK,TMP
.ELSE
	UIN TMP,ENC_B_SNSREG
	andi TMP,~ENC_B_SNSMSK
	ori TMP,ENC_B_SNSVAL
	UOUT ENC_B_SNSREG,TMP
.ENDIF

	ldi TMP,1<<ENC_A_IBIT
	UOUT ENC_A_IFLGREG,TMP
	ldi TMP,1<<ENC_B_IBIT
	UOUT ENC_B_IFLGREG,R17

	clr STAT
	sbic ENC_A_PIN,ENC_A_BIT
	ori STAT,1<<STAT_A
	sbic ENC_B_PIN,ENC_B_BIT
	ori STAT,1<<STAT_B

	UIN TMP,ENC_A_IMSKREG
	ori TMP,1<<ENC_A_IBIT
	UOUT ENC_A_IMSKREG,TMP
	UIN TMP,ENC_B_IMSKREG
	ori TMP,1<<ENC_B_IBIT
	UOUT ENC_B_IMSKREG,TMP

	sei
;-----------------------------------------------------------------------------

main:
	rjmp main

;#############################################################################