;**************************************************************************
Wait_50mS:								; Warte 50ms (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (1<<CS02)|(0<<CS01)|(1<<CS00) ; / 1024
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 222				; 50ms
	rjmp	Wait_XuS

;**************************************************************************
Wait_15mS:								; Warte 15ms (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (1<<CS02)|(0<<CS01)|(1<<CS00) ; / 1024
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 65				; 15ms
	rjmp	Wait_XuS
;**************************************************************************
Wait_4_1mS:								; Warte 4,1ms (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (1<<CS02)|(0<<CS01)|(0<<CS00) ; / 256
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 75				; 4.1ms
	rjmp	Wait_XuS
;**************************************************************************
Wait_480uS:								; Warte 480µs (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (0<<CS02)|(1<<CS01)|(1<<CS00) ; / 64
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 33				; 480us
	rjmp	Wait_XuS
;**************************************************************************
Wait_100uS:								; Warte 100us (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (0<<CS02)|(1<<CS01)|(0<<CS00) ; / 8
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 53				; 100us
	rjmp	Wait_XuS
;**************************************************************************
Wait_70uS:								; Warte 70us (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (0<<CS02)|(1<<CS01)|(0<<CS00) ; / 8
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 36				; 70us
	rjmp	Wait_XuS
;**************************************************************************
Wait_45uS:								; Warte 40us (4,8MHZ)
; -------------------------------------------------------------------------
	ldi     Temp_Wait, (0<<CS02)|(0<<CS01)|(1<<CS00) ; / 1
	out     TCCR0B, Temp_Wait
	ldi		Temp_Wait, 180				; 45us
;**************************************************************************
Wait_XuS:								; Warte 40us (4,8MHZ)
; -------------------------------------------------------------------------
	out		OCR0A, Temp_Wait			; 
	out		TCNT0, NULL					; lösche TCNT0

	in		Temp_Wait, TIFR0
	sbr		Temp_Wait, (1<<OCF0A)		; OCF1A = 0
	out		TIFR0, Temp_Wait			; cleared by writing a logic ONE !!!
Loop_Wait_X:
	in		Temp_Wait, TIFR0			; read the Timer Interrupt Flag Register
	sbrs	Temp_Wait, OCF0A			; test the overflow flag (use bit#)
	rjmp	Loop_Wait_X					; jump if Flag not set
	ret

;**************************************************************************
Wait_4uS:								;
;--------------------------------------------------------------------------
	rcall	Wait_2us					; 2,5 us
;--------------------------------------------------------------------------
Wait_2us:								; 2,5 us
;--------------------------------------------------------------------------
	ldi		Temp_Wait, 3				; [1] 
	dec		Temp_Wait					; [1]
	brne	PC-1						; [2/1]
	ret

;**************************************************************************
Wait_Loop:
;--------------------------------------------------------------------------
	ldi		Temp0, 20 *5				; Wait: ~5 sec
Loop_Wait_50mS:
	sbic	PINB, Taste					; Taste gedrückt ??	
	rcall	Wait_50mS					; sonst weiter warten
	dec		Temp0
	brne	Loop_Wait_50mS
	ret

;**************************************************************************