>D
;start, define variables
cnt=0
tmp=0
cntr=0
tmp=0
res=0

>B
;setup sensor
=>sensor53 r

>F
;100ms iterations
cntr+=1
switch cntr

case 10
print ===== ctr: %cntr% wakeup start ===== 
;set serial protocol
sml(-1 1 "2400:8N1")
; end 2f just like in the minicom3 software 
sml(1 1 "2f")
;send (132x)  0x55 with 2400 baud (wakeup sequence)
for cnt 1 132 1
sml(1 1 "55")
next

print ===== wakeup end, wait for the meter ===== 

case 15
print ===== ctr: %cntr% --SET BAUDRATE TO 2400:8E1-- ===== 

;switch serial protocol
sml(-1 1 "2400:8E1")
print  ===== request data ===== 
case 20
sml(1 1 "1040004016")        
case 26
sml(1 1 "105b005b16")
case 32
sml(1 1 "1040004016")        
case 38
res=sml(1 1 "105b005b16")

print ===== ctr: %cntr% sent successfully %res% =====


case 60
if tmp<1
then 
print  ===== 1x repeat for to ensure stable and reliable readout  =====
cntr=0 
tmp+=1
endif 

; repeat after a little less than hour to prevent the meter from falling asleep
case 35500
print  =====  --REPEAT SEQUENCE --  ===== 
cntr=0 
cnt=0
tmp=0 


ends


>M 1
+1,3,rE1,0,2400,K_WW,1
1,0C06bcd8@1,Total Energy,kWh,w_total,0
1,0C13bcd8@1000,Total volume,m³,v_total,3
1,0C2bbcd8@1,Current power,W,p_act,0
1,0C3bbcd8@1000,Current flow,m³/h,F_akt,3
1,025AuuUU@10,Flow temp,°C,t_flow,1
1,025euuUU@10,Return temp,°C,t_return,1
#