; sr_100_reg.asm
;
; Created: 03.01.2024
; Author : Dosenoeffner
;
/* Mit aktiven 128 kHz Oszillator und dem zusaetzlichen
Vorteiler 1/32 laeuft der Controller mit rund 4 kHz.
Das Signal an EINGANG um eine Sekunde verzoegert an AUSGANG ausgegeben.
Die Abtastrate betraegt 1/136 s: 17 Register x 8 Bit
*/

#define EINGANG     4       // PB4
#define AUSGANG     1       // PB1
 
    clr r0
    clr r1
    clr r2
    clr r3
    clr r4
    clr r5
    clr r6
    clr r7
    clr r8
    clr r9
    clr r10
    clr r11
    clr r12
    clr r13
    clr r14
    clr r15
    clr r16

    clr r31
    ori r31, 1<<EINGANG // bit fuer Eingang
    com r31             // invertieren
    out DDRB, r31       // Rest auf Ausgang
    ldi r31,0x80
    out CLKPR,r31
    ldi r31,0x05
    out CLKPR,r31       // Vorteiler /32
    ldi r31,0x0f
    out PRR,r31         // alle Module abschalten

durchlauf:
    nop                 // Laufzeitkorrektur nach Bedarf
                        // ggf. r16 auslassen und kleine Warteschleife
    sbic PINB, EINGANG  
    rjmp c_auf_1
    clc
    rjmp continue
c_auf_1:
    nop                 // Laufzeitkorrektur
    sec                 // c = 0
continue:
    rol r0
    rol r1
    rol r2
    rol r3
    rol r4
    rol r5
    rol r6
    rol r7
    rol r8
    rol r9
    rol r10
    rol r11
    rol r12
    rol r13
    rol r14
    rol r15
    rol r16

    brcs auf1
    nop
    cbi PORTB, AUSGANG  // Ausgang = 0
    rjmp durchlauf
auf1:
    SBI PORTB, AUSGANG  // Ausgang = 1
    rjmp durchlauf