;Blink LED mit Timer ISR

.include "m328Pdef.inc"

.def temp = r16

.equ LED = PD3
.equ LED_PORT = PORTD
.equ LED_DDR = DDRD
.equ LED_PIN = PIND

.org 0x0000		; IRQ Tabelle

			jmp RESET

.org OC1Aaddr

			jmp Timer_ISR

RESET:
;------------------------------------------------------------------------------------------
			ldi temp, LOW(RAMEND)	; LOW-Byte der obersten RAM-Adresse
			out SPL, temp
			ldi temp, HIGH(RAMEND)	; HIGH-Byte der obersten RAM-Adresse
			out SPH, temp
;------------------------------------------------------------------------------------------
;setup port
			ldi temp, 1<<LED
			out LED_DDR, temp
			cbi LED_PORT, LED
;------------------------------------------------------------------------------------------
;setup IRQ timer 1: IRQ 500ms @ 16MHz clock
			ldi temp, 0x7A
			sts OCR1AH, temp
			ldi temp, 0x12-1
			sts OCR1AL, temp

			ldi temp, 1<<OCIE1A		; timer IRQ @ compare-match
			sts TIMSK1, temp

			in temp, TIFR1
			sbr temp, 1<<OCF1A
			out TIFR1, temp

			ldi temp, 1<<WGM12 | 1<<CS12	;CTC mode, clk/256, start timer

			sts TCCR1B, temp

;------------------------------------------------------------------------------------------
			sei						; enable interrupts
;------------------------------------------------------------------------------------------

mainloop:
			rjmp mainloop

;------------------------------------------------------------------------------------------
Timer_ISR:
			push temp
			in temp, SREG
			push temp

			sbi LED_PIN, LED	;Toggle LED

			pop temp
			out SREG, temp
			pop temp

			reti

signature:
.db "328 Blink 14-06-2025"