// Lädt Daten in den Patterngenerator.

// Die Schnittstelle aus der 'Konstanten.txt'-Datei verwenden.
#$rtb

// Variable erstellen.
string Pattern

string ScpiFehlerInfo
string SavePath
SavePath set #SavePath

// Die Fehlerliste löschen.
function scpi write *CLS


// Die Daten für den Patterngenerator einlesen.
Pattern set $file "T:\I2C-Pattern.txt"

// Den Patterngenerator deaktivieren.
function scpi write :PGENerator:PATTern:STATe OFF
ScpiFehlerInfo set "Fehler beim Dektivieren des Patterngenerators."
goto ScpiFehler

// Die Daten in den Pattergenerator laden.
function scpi write :PGENerator:FUNCtion ARBitrary
ScpiFehlerInfo set "Fehler beim Setzen der Funktion."
goto ScpiFehler

function scpi write :PGENerator:PATTern:ARBitrary:DATA:LENGth 2048
ScpiFehlerInfo set "Fehler beim Setzen der Länge der Daten."
goto ScpiFehler

function scpi write :PGENerator:PATTern:ARBitrary:DATA:SET $Pattern
ScpiFehlerInfo set "Fehler beim Laden der Daten in den Patterngenerator."
goto ScpiFehler

// Den Patterngenerator einstellen für das I2C-Protokoll.
function scpi write :PGENerator:PATTern:STIMe 0.000000125 // 125 ns
ScpiFehlerInfo set "Fehler beim Setzen von Sample Time."
goto ScpiFehler

function scpi write :PGENerator:PATTern:TRIGger:MODE CONTinuous
ScpiFehlerInfo set "Fehler beim Tigger Mode."
goto ScpiFehler

// Den Patterngenerator aktivieren.
function scpi write :PGENerator:PATTern:STATe ON
ScpiFehlerInfo set "Fehler beim Aktivieren des Patterngenerators."
goto ScpiFehler


// Das Skript beenden.
goto Ende



// Auf einen SCPI-Fehler prüfen, z.B.: -113,"Undefined header" oder 0,"No error"
label ScpiFehler
string ScpiFehlerText
integer ScpiFehlerNummer
ScpiFehlerText function scpi read :SYSTem:ERRor?
ScpiFehlerNummer set ScpiFehlerText
ScpiFehlerNummer equal 0
true return

// Den Fehler ausgeben und anzeigen.
print
print $ScpiFehlerInfo
print Fehler: $ScpiFehlerText
print
function message "/$ScpiFehlerInfo SCPI: /$ScpiFehlerText" ok error



// Skript Ende.
label Ende