.equ SCL_PIN = 2
.equ SDA_PIN = 3
.equ lcd_update = 0

.equ clock_ram_address = 0x0150
.equ Sekunden_Adress = clock_ram_address
.equ Minuten_Adress = clock_ram_address + 1
.equ Stunden_Adress = clock_ram_address + 2
.equ Wochentag_Adress = clock_ram_address + 3
.equ Tag_Adress = clock_ram_address + 4
.equ Monat_Adress = clock_ram_address + 5
.equ Jahr_Adress = clock_ram_address + 6

.def zeit_h				=	r7
.def zeit_m				=	r8
.def zeit_s				=	r9
.def zeit_d				= 	r10

;_____________________________________________________________

TWI_start:
		ldi temp1, 0b00100000
		sts TWBR, temp1				;TWI Bit Rate

		ldi temp1, 1<<TWPS1
		sts TWSR, temp1

		ldi temp1, 0xFF
		sts TWDR, temp1
		
		ret
;_____________________________________________________________
TWI_Uhr_lesen:

			cli

			ldi XL, low(clock_ram_address)
			ldi XH, high(clock_ram_address)

			rcall TWI_init				;Bus frei+Start-Bit senden

			ldi temp1, 0b11010000		;Slave address+Write
			rcall TWI_address_send

			ldi temp1, 0			;Adress-Byte senden
			rcall TWI_byte_send
;			rcall TWI_stop

			rcall TWI_init				;Start-Bit senden
			ldi temp1, 0b11010001		;Slave address + read
			rcall TWI_address_send		

			clr temp1
			ldi temp1, 1<<TWINT|1<<TWEA|1<<TWEN
			sts TWCR, temp1			


	TWI_cr_next:
			ldi temp3, 7
		cr_next2:

			rcall TWI_read_byte

			rcall BCD_to_BIN	;BCD von Uhr nach Binär wandeln

			st X+, temp1

			ldi temp1, 1<<TWINT|1<<TWEA|1<<TWEN		;ACK
			sts TWCR, temp1

			dec temp3			;7 Bytes lesen
			brne cr_next2

			clr temp1			;Übertragung beenden
			ldi temp1, 1<<TWINT|0<<TWEA|1<<TWEN		;NACK
			sts TWCR, temp1
			

			rcall TWI_stop
			clr temp1
			sts TWCR, temp1				
			
			sei

			lds zeit_s, Sekunden_Adress
			lds zeit_m, Minuten_Adress
			lds zeit_h, Stunden_Adress
			lds zeit_d, Wochentag_Adress

			lds temp1, Monat_adress
			subi temp1,4
			cpi temp1, 6	;Monat ist 4-10
			brcs twi_end

			sbrs flag_register, 5	;Sommerzeit-Flag setzen

		twi_end:
			ret
;_______________________________________________________
TWI_read_byte:
			rcall TWINT_wait
						
			lds temp1, TWSR
			andi temp1, 0xF8

			lds temp1, TWDR
			ret
;_______________________________________________________
TWI_DS1307_set_adress: 				;Setzt die RAM-Adresse
			push temp2
			rcall TWI_init
			mov temp2, temp1
			ldi temp1, 0b11010000		;Slave address+Write
			rcall TWI_address_send

			mov temp1, temp2			;Adress-Byte senden
			rcall TWI_byte_send
			pop temp2
			ret
;_________________________________________________________
TWI_address_send:				;Sendet die TWI-Adresse + RW-Bit
			sts TWDR, temp1
			clr temp1
			ldi temp1,1<<TWINT|1<<TWEN
			sts TWCR, temp1

			rcall TWINT_wait

			lds temp1, TWSR
			andi temp1, 0xF8

			cpi temp1, 0x18		;Wr+ACK
			breq TWI_as_next
			cpi temp1, 0x40		;Rd+ACK
			breq TWI_as_next
			rjmp TWI_error
	TWI_as_next:
			ret
;___________________________________________________________
TWINT_wait:
			lds temp1, TWCR
			sbrs temp1, TWINT
			rjmp TWINT_wait
			ret
;_________________________________________________________
TWI_byte_send:
			sts TWDR, temp1
			ldi temp1, 1<<TWINT|1<<TWEN
			sts TWCR, temp1

			rcall TWINT_wait

			lds temp1, TWSR
			andi temp1, 0xF8

			cpi temp1, 0x28
			breq bs_next
			rjmp TWI_error
	bs_next:
			ret
;__________________________________________________________		
TWI_error:
			rcall lcd_clear
			ldi ZL, low( 2 * banner_err )	;Überschrift auf LCD
			ldi ZH, high( 2 * banner_err )
			rcall lcdstring
			ret
;__________________________________________________________
TWI_stop:
			clr temp1
			ldi temp1, 1<<TWINT|1<<TWSTO|1<<TWEN
			sts TWCR, temp1
			ret
;_______________________________________________________
TWI_Uhr_stellen:
			rcall TWI_init
			
			ldi temp1, 0b11010000		;Slave address+Write
			rcall TWI_address_send

			ldi temp1, 0			;Adress-Byte senden
			rcall TWI_byte_send

			mov temp1, zeit_s
			rcall BIN_to_BCD
			rcall TWI_byte_send

			mov temp1, zeit_m
			rcall BIN_to_BCD
			rcall TWI_byte_send

			mov temp1, zeit_h
			rcall BIN_to_BCD
			rcall TWI_byte_send

			mov temp1, zeit_d
			rcall TWI_byte_send

			lds temp1, Tag_Adress
			rcall BIN_to_BCD
			rcall TWI_byte_send

			lds temp1, Monat_Adress
			rcall BIN_to_BCD
			rcall TWI_byte_send

			lds temp1, Jahr_Adress
			rcall BIN_to_BCD
			rcall TWI_byte_send
		
			rcall TWI_stop
			clr temp1
			sts TWCR, temp1				
			ret
;__________________________________________________________
convert_ds1307_time:
			ldi XL, low(clock_ram_address)
			ldi XH, high(clock_ram_address)

			ld temp1, X
			andi temp1, 0b01111111		;Sekunden
			st	X+, temp1
			ld temp1, X
			andi temp1, 0b01111111		;Minuten
			st	X+, temp1
			ld temp1, X
			andi temp1, 0b00111111		;Stunden
			st	X+, temp1
			ret
;_____________________________________________________________
TWI_init:
			ldi temp1, 1<<TWINT|1<<TWSTA|1<<TWEN
			sts TWCR, temp1
	init1:
			lds temp1, TWCR
			sbrs temp1, TWINT
			rjmp init1
			
			lds temp1, TWSR
			andi temp1, 0xF8


			cpi temp1, 0x08
			breq init_no_error
			cpi temp1, 0x10
			breq init_no_error

			ret

	init_no_error:
			ret
;______________________________________________________________
BCD_to_BIN:
			push temp2
			push temp3
			mov temp3, temp1		;Zwischenspeichern
			swap temp1				;Oberes Nibble nach rechts
			andi temp1, 0x0F		;Oberes Nibble löschen
			mov temp2, temp1		;Wert speichern
			lsl temp1				;mal 2
			lsl temp1				;mal 2, macht mal4
			add temp1, temp2		;plus Ausgangswert, macht mal 5
			lsl temp1				;mal 2, macht mal 10
			andi temp3, 0x0F		;Unteres Nibble extrahieren
			add temp1, temp3		;Unteres Nibble noch dazu
									;fertig
			pop temp3
			pop temp2
			ret
;________________________________________________________________
BIN_to_BCD:
			push temp3
			ldi temp3, 10

			ldi zahl2, 0xff	;-1 

			BINBCD02:
			inc zahl2
			sub temp1, temp3
			brcc BINBCD02

			add temp1, temp3

			ldi zahl3, 0
			add zahl3, temp1
		
			mov temp1, zahl2
			swap temp1

			or temp1, zahl3

			pop temp3
			ret

;______________________________________________________________

Uhr_starten:
			rcall TWI_init
			
			ldi temp1, 0b11010000		;Slave address+Write
			rcall TWI_address_send

			ldi temp1, 0			;Adress-Byte senden
			rcall TWI_byte_send

			ldi temp1, 0
			rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 44
			rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 12
			rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 5
			;rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 24
			rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 12
			rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 10
			rcall BIN_to_BCD
			rcall TWI_byte_send

			ldi temp1, 0b00010000	;SQWE
			rcall TWI_byte_send
		
			rcall TWI_stop
			clr temp1
			sts TWCR, temp1				
			ret
;________________________________________________________
banner_DS1307:
    .DB "DS1307 RTC ", 0x00
banner_err:
    .DB "I2C Error", 0x00
banner_status:
	.DB "Status: ", 0x00, 0x00
init_err:
    .DB "Init Err", 0x00, 0x00

clock_values:
	.DB 0,0x47,0b00100000,4,0x03,0x12,0x09,0b00010000,0,0
nop