; vim: fileencoding=utf-8: ts=4: sw=4: expandtab:

FAC1        .set    $63         ; 6 bytes
FAC2        .set    $6a         ; 6 bytes
FREKZP      .set    $fa         ; 5 bytes
VDCAREG     .set    $d600
VDCDREG     .set    $d601
DISPHI      .set    12
DISPLO      .set    13
UPDHI       .set    18
UPDLO       .set    19
DATA        .set    31

COUNTER     .set    $fa

            .code
            .org    $1c20-33
            .include "header_1c20.s"

            .proc _run
            lda     #0          ;@  DisplayArea-address $0000
            ldy     #0
            jsr     prepupdate

            ldy     #0
            lda     #8
            sta     COUNTER
loop:       lda     #$66
            ldx     #DATA
            jsr     setreg
            iny
            bne     loop
            dec     COUNTER
            bne     loop

            lda     #8          ;@  Attributes-address $0800
            ldy     #0
            jsr     prepupdate

            ldy     #0
            lda     #8
            sta     COUNTER
loop2:      tya
            and     #$0f
            ldx     #DATA
            jsr     setreg
            iny
            bne     loop2
            dec     COUNTER
            bne     loop2
            rts
            .endproc

            .proc   setreg      ; X:VDC address register   A: data
setreg:     stx     VDCAREG
l1:         bit     VDCAREG
            bpl     l1
            sta     VDCDREG
            rts
            .endproc

            .proc   prepupdate  ; A:data_hi   Y:data_lo
            ldx     #UPDHI
            jsr     setreg
            ldx     #UPDLO
            tya
            jsr     setreg
            rts
            .endproc