;- - - - - - - - - - - - - - - - - - - - - - - - - -
; Verbindung DCF77-Soft-Clock (nach G.Schmidt)
; mit LCD, seriell, 9600 Baud, 8-N-1 
; (RXD/TXD gekreuzt)  
; MCU ATTiny4313; 
; CPU Takt 4,096 MHz
; LCD 2x16, (HD44780) Vierbitmodus
; PortB LCD Ausgabe: 	  R/W=GND
; PB7 PB6 PB5 PB4 PB3 PB2 PB1 PB0
; n/a LED ena rs  D7  D6  D5  D4
;- - - - - - - - - - - - - - - - - - - - - - - - - -
;ATtiny4313 memory use summary [bytes]:
;Segment   Begin    End   Code Data Used Size  Use%
;[.cseg] 0x000000 0x0001fc  496  12  508 4096 12.4%
;[.dseg] 0x000060 0x000060    0   0    0  256  0.0%
;[.eseg] 0x000000 0x000000    0   0    0  256  0.0%
;Assembly complete, 0 errors. 2 warnings
; Rev.:23052009-18032018
;- - - - - - - - - - - - - - - - - - - - - - - - - - 
;
.nolist
.include "tn4313def.inc";"2313def.inc"
.list
;
;	Konstanten:
.equ	daten = portb
.equ	mctakt = 4096000 ; Quarzfrequenz 
.equ	baud = 9600 	; Baudrate
.equ	bdteiler = 26	; (mctakt/(16*baud))-1;Baudr.-Teiler
.equ	rs	= 4	; Portbitzuweisung RS-Bits
.equ	ena	= 5	; Portbitzuweisung Enable-Bits
.equ	lit	= 6	; Portbitzuweisung LED-Hintergrundlicht
.equ	zeit1	= 65535	; Ladewert 1 fuer Zeitschleifen
.equ	zeit2	= 65535	; Ladewert 2 fuer Zeitschleifen
.equ	zeit3	= 65525	; Ladewert 3 fuer Zeitschleifen	
;
;	Register-Definitionen:
.def	temp	= r16	; Temporaerregister 1
.def	temp1	= r17	; Temporaerregister 2
.def	temp2	= r18	; Temporaerregister 3
;
;	Speicher- und Einsprungadressenzuordnungen:
.cseg				; Codesegment
.org	0x0000			; Anfangsadresse bei Null
rjmp	main			; Sprung zum Hauptprogramm	
;
main: 
ldi	temp, low(ramend)	; Stackpointer initialisieren
out	SPL, temp		; (Highbyte fehlt bei ATTiny2313)
ldi temp, high(ramend)
out SPH, temp
ser	temp			; Portzuweisung  
out	DDRB, temp		; Port B Ausgang fuer LCD
ldi	temp, 0b00000010	; Port D Bit0 RXD, Bit1 TXD
out	ddrd, temp		 
ldi	temp, 0xFF		; Pullups auch fuer RXD aktiv
out	portd, temp
ldi	temp, bdteiler		; Baudratengenerator
out	UBRR, temp 		; Teiler setzen in UBRR
ldi	temp, 0x18	; (1<<RXEN)|(1<<TXEN) RXD und TXD enable
out	UCSRB, temp 	; (UCR)in UART Control-Register
rcall lcd_init		; Aufruf LCD-Initialisierung
sbi	daten, lit		; Hintergrundbeleuchtung ein
rcall tx_string1	; Soft-Clock-Initialisierung
rcall verz4			; Pause fuer Decoder-Menueaufruf
rcall verz4
rcall verz4
rcall verz4
rcall tx_string2		; Steuerbefehl senden
rcall verz4
sbi	daten, lit
rcall rx_seriell	; Kommunikation DCF77-Decoder-LCD
rjmp endlosschleife
;
tx_string1:		; DCF77-Decoder initialisieren
ldi	ZL,	LOW(dec_init1*2)	; Adresse des Strings in den
ldi	ZH,	HIGH(dec_init1*2)	; Z-Pointer laden
rcall	print		; Funktion print aufrufen
rcall	verz3		; kurze Pause zwischen Zeichen
ret
;
tx_string2:		; DCF77-Decoder weiter initialisieren
ldi	ZL,	LOW(dec_init2*2)	; Adresse des Strings in den
ldi	ZH,	HIGH(dec_init2*2)	; Z-Pointer laden
rcall	print		; Funktion print2 aufrufen
rcall	verz3		; kurze Pause zwischen Zeichen
ret
;
print:
lpm			; erstes Byte des Strings nach R0 lesen
tst	R0		; R0 auf 0 testen
breq	print_end	; wenn 0, dann zu print_end
mov	temp,	r0	; Inhalt von R0 nach temp kopieren
rcall	ausgabe		; Ausgabefunktion aktivieren
adiw	ZL:ZH,	1	; Adresse des Z-Pointers um 1 erhoehen
rjmp	print		; zum Anfang springen, um naechstes 
;			; Byte aus dem cseg-Label dec_init1 zu holen
print_end:		; Beenden der Leseroutine
ret
;
ausgabe:		; uebergibt Inhalt von "temp" an TX
cbi	daten,	lit
rcall	verz4
rcall	tx_ready	; Aufruf UART Senderoutine
sbi	daten,	lit
rcall	verz4
cbi	daten,	lit
ret
;
dec_init1:			; Konstanten Decoder-Init-String 1
.db ' ', 0x0D, '?', 0x0D, 0	; Aufruf Liste der commands im Menue  
;
dec_init2:			; Konstanten Decoder-Init-String 2
.db	'd', 's', 0x0A, 0x0D, 0	; sekuendliche Datums/Zeitausgabe
;
tx_ready:		; Warteschleife fuer tx_readyschaft
sbis UCSRA,	UDRE	; (USR)wartet bis Sender bereit
rjmp tx_ready	; Frage, ob Sender noch beschaeftigt
out	UDR, temp		; sendet Zeichen ueber UART
nop
ret
;
rx_seriell:		; ser. Ausgabe Decoder nach LCD
sbis UCSRA,	RXC	; (USR) Frage, ob Empfaengerpuffer leer 
rjmp rx_seriell
in temp, UDR		; Uebergabe Zeichen an temp
cpi	temp, ','	; Zeilenumbruch nach Komma im Datum
breq position_az2
cpi	temp, 0x0D	; Zeilenumbruch LCD nach Wagenvorschubbefehl
breq position_az1
rcall lcdchar		; zur LCD-Ausgaberoutine
ret
;
position_az1:		; setzt LCD-Anzeige auf Anfang Zeile 1
push temp
ldi	temp, 0x80
rcall lcdcmd
pop	temp
ret
;
position_az2:		; setzt LCD-Anzeige auf Anfang Zeile 2
push temp
ldi	temp, 0xC0
rcall lcdcmd
pop	temp
ret
;
endlosschleife:		; Programm verbleibt im Empfangsmodus...
rcall	rx_seriell	; ...so werden auch Meldungen ausgegeben
rjmp	endlosschleife
;
lcd_init:
rcall	verz4		; Einschaltverzoegerung LCD
push	temp		; Sicherung Temporaerregister
push	temp1		; und Statusregister auf Stapel
push	temp2
in		temp2,	SREG
push	temp2
rcall	lcd_reset	; LCD-Bus-Reset
rcall	lcd_achtbit	; LCD-Init: acht Bit
rcall	lcd_acht_vier	; LCD-Init: acht zu vier Bit
rcall	lcd_vier_zwei	; LCD-Init: vier Bit, 2 Zeilen
rcall	lcd_on_off	; LCD-Init: Displaypuffer aus
rcall	lcd_clear	; LCD-Init: Anzeige loeschen
rcall	lcd_entrymode	; LCD-Init: Entry Mode Set
pop	temp2		; Wiederherstellung Temporaer-
out	SREG, temp2	; und Statusregister 
pop	temp2
pop	temp1
pop	temp
ret
;
lcd_reset:		; LCD-Bus-Reset:
push temp		; Temporaeregister auf Stack retten
cbi	daten, rs	; RS-Bit auf "low"
ldi	temp, 0x00	; Reset des LCD-Ausgabeports
out	daten, temp
rcall enable		; Enable-Impuls toggeln
rcall verz3
pop	temp
ret
;
lcd_achtbit:		; Acht-Bit Init:
;			; geaenderte Portbitbelegung!
;			; PortB LCD Ausgabe:  R/W=GND
; 			; PB7 PB6 PB5 PB4 PB3 PB2 PB1 PB0
; 			; n/a LED ena rs  D7  D6  D5  D4
push	temp		 
cbi	daten,	rs	; dreimal hex 0x03 ausgeben
ldi	temp,	0x03	; rs=0
out	daten,	temp	; jedesmal Enableimpuls senden
rcall	enable		
rcall	verz3		 
cbi	daten,	rs		 
out	daten,	temp
rcall	enable
rcall	verz3
cbi	daten,	rs
out	daten,	temp
rcall	enable
rcall	verz3
pop	temp
ret
;
lcd_acht_vier:	; Acht-zu-Vier-Bit-Modus-Wechsel 
push	temp
cbi	daten,	rs
ldi	temp,	0x02	; zunaechst nur 4-Bit-Modus,
out	daten,	temp	; untere vier Daten-Bits werden
rcall	enable		; ignoriert, aber immer noch
rcall	verz3		; 8-Bit-Befehlsbreite
pop	temp
ret
;
lcd_vier_zwei:	; Vier-Bit-Modus; zwei Zeilen 
push	temp
cbi	daten,	rs	; dann 4-Bit-Modus
ldi	temp,	0x28	; und zweizeilig,
rcall	lcdcmd	; ab hier bereits Steuerbefehle
rcall	verz3		; im Vierbit-Modus senden
pop	temp
ret
;
lcd_on_off:		; On Off Control, Display ein/ausschalten:
push	temp
cbi	daten,	rs
ldi	temp,	0x08	; Display ausschalten,
rcall	lcdcmd		; Cursor aus, Blinken aus
rcall	verz3
pop	temp
ret
;
lcd_clear:		; Anzeige loeschen:
push	temp
cbi	daten,	rs	; Anzeige wird im "Space"-
ldi	temp,	0x01	; Modus geloescht
rcall	lcdcmd		; braucht mehr Zeit
rcall	verz4
pop	temp
ret
;
lcd_entrymode:	; Entry/Shift Mode Set:
push	temp
cbi	daten,	rs
ldi	temp,	0x06 	; Cursor von links nach rechts 
rcall	lcdcmd		; kein Schieben
rcall	verz3
cbi	daten,	rs
ldi	temp,	0x10 	; kein Schieben, Cursorbewegung
rcall	lcdcmd		; nach rechts 
rcall	verz3
cbi	daten,	rs
ldi	temp,	0x0C	; Anzeige wieder einschalten  
rcall	lcdcmd		; Cursor aus, Blinken aus
rcall	verz3
cbi	daten,	rs
ldi	temp,	0x01	; Anzeige nochmals loeschen
rcall	lcdcmd
rcall	verz3
pop	temp
ret
;
;lcdchar:	; gibt Charakter auf LCD aus (alte Portbelegung)
;cbi	daten,	licht
;push	temp			; rettet temp auf Stapel
;mov	temp1,	temp		; Kopie des Wertes fuer weitere;
;				; Operation unten
;andi 	temp,	0b11110000	; unteres Nibble ausblenden
;ori	temp,	0b00000111	; RS, etc. auf "high" maskieren Port B
;sbi	daten,	rs		; setzt RS-Bit auf "high"
;out 	daten,	temp		; Ausgabe oberes Nibble auf D4-D7
;rcall	enable			; ruft Enableimpuls auf
;swap 	temp1			; Nibble-Vertauschen, Wert aus temp
;				; kopiert, s.o.
;andi	temp1,	0b11110000	; unteres Nibble ausblenden
;ori	temp1,	0b00000111	; RS, etc. auf "high" maskieren Port B
;sbi	daten,	rs		; nochmals RS auf "high"
;out	daten,	temp1		; Ausgabe unteres Nibble auf D4-D7 
;rcall	enable			; ruft Enableimpuls auf
;sbi	daten,	licht		; Beleuchtung "ein"
;pop	temp			; Wiederherstellung von temp
;ret
;
lcdchar:		; gibt Charakter auf "temp" ueber LCD aus
cbi daten,lit		; LCD-Hintergrundbeleuchtung aus
push temp		; rettet temps auf Stapel
push temp1
mov temp1, temp		; Kopie fuer Nachfolge-Operation
andi temp, 0xF0		; unteres Daten-Nibble ausblenden
swap temp		; an Portbelegung anpassen...
andi temp, 0x0F		; oberes Portbit-Nibble ausblenden
ori temp, 0b00010000 	; RS=high
out daten,temp		; Ausgabe D4-D7-Daten-Nibble auf Port D0-D3
rcall enable		; Enableimpuls 
andi temp1, 0x0F	; oberes Portbit-Nibble ausblenden	
ori temp1, 0b00010000 	; RS=high
out daten,temp1		; Ausgabe D0-D3-Daten-Nibble auf D0-D3
rcall enable		; Enableimpuls
sbi daten,lit		; Hintergrundbeleuchtung ein
pop temp1			; Zurueckholen von temps
pop temp
ret
;
;lcdcmd:	; sendet Steuerzeichen an LCD (alte Portbelegung)
;push	temp			; rettet temp auf Stapel
;mov	temp1,	temp		; Kopie des Wertes fuer weitere;	
;				; Operation unten
;andi 	temp,	0b11110000	; unteres Nibble ausblenden
;cbi	daten,	rs		; setzt RS auf "low"
;out 	daten,	temp		; Ausgabe oberes Nibble auf D4-D7 
;rcall	enable			; Aufruf Enableimpuls
;swap 	temp1			; Nibble-Vertauschen, Wert aus temp;
;				; kopiert, siehe oben
;andi 	temp1,	0b11110000	; unteres Nibble ausblenden
;cbi	daten,	rs		; setzt RS nochmals auf "low"
;out	daten,	temp1		; Ausgabe unteres Nibble auf D4-D7 
;rcall	enable
;pop	temp			; Wiederherstellung von temp
;ret
;
lcdcmd:		; sendet Steuerzeichen auf "temp" an LCD
push temp			; rettet "temps" auf Stapel
push temp1
mov temp1,temp		; Kopie fuer Nachfolge-Operation
andi temp, 0xF0		; unteres Daten-Nibble ausblenden
swap temp			; an Portbelegung anpassen...
andi temp, 0x0F		; oberes Portbit-Nibble ausblenden; RS=0
out daten,temp		; Ausgabe D4-D7-Daten-Nibble auf Port D0-D3
rcall enable		; Enableimpuls 
andi temp1, 0x0F	; oberes Portbit-Nibble ausblenden; RS=0
out daten,temp1		; Ausgabe D0-D3-Daten-Nibble auf D0-D3
rcall enable		; Enableimpuls senden
pop temp1		; Zurueckholen von temps
pop temp
ret
;
enable:			; Enableimpuls-Generierung
nop
sbi daten, ena		; Portbit "Enable" auf high
nop			; Zeitverzoegerung mindestens
nop			; 1000 ns laut Datenblatt LCD
nop
nop
nop
nop
cbi daten, ena		; Portbit "Enable" auf low zuruecksetzen
nop
ret
;
;- - - - - - - - Verzoegerungsschleifen fuer LCD - - - - - - -
verz3:			; ca. 20 ms Verzoegerung:
push temp		; Sicherung von Temporaerregistern...
push temp1		; und Statusregister auf Stapel
push temp2
in temp2, SREG		; kann hier auch entfallen,
push temp2		; bei Interrupts notwendig
clr	xl		; Loeschen von Registerpaar r26:r27
clr	xh
ldi xl,	low(zeit1)	; laedt Zaehlregisterpaar
ldi xh,	high(zeit1)	; mit oben deklariertem Wert...
rjmp	schleifeb	; ..."zeit1"
;
verz4:			; ca. 200 ms Verzoegerung:
push temp		; Sicherung auf Stapel
push temp1
push temp2
in temp2, SREG
push temp2
clr	xl		; Loeschung Registerpaar
clr	xh
ldi xl, low(zeit2) 	; laedt Zaehlregisterpaar
ldi xh, high(zeit2)	; mit deklariertem Wert...
rjmp schleifea		; ..."zeit2"
;			; Sprung auf "schleifea"
schleifea:		; 16-Bit-Subtraktionsschleife (a):
sbiw xl:xh,	1	; decrementiert Doppelregister
brne schleifea		; zaehlt bis Null
rjmp verz5		; Sprung zum zweiten Durchlauf...
;			; "verz5",verdoppelt Verzoegerung
verz5:	
clr	xl		; Loeschung Doppelregister
clr	xh
ldi xl, low(zeit3) 	; laedt Zaehlregisterpaar...
ldi xh, high(zeit3)	; ...mit Wert "zeit3"
rjmp schleifeb		; Sprung auf "schleifeb"
;
schleifeb:
sbiw xl:xh,	1	; decrementiert Doppelregister
brne schleifeb		; zaehlt bis Null
pop	temp2		; Wiederherstellung "geretteter"
out	SREG, temp2	; Register
pop	temp2
pop	temp1
pop	temp
ret
;
;***FIN***