#include <util/atomic.h>
#define AtomicSection ATOMIC_BLOCK(ATOMIC_RESTORESTATE)
/* 
 Arduino Mega2560
 Timer 2: CTC, Mode 2
  
 Pinouts  >>> http://www.pighixxx.net/pinoutspg/boards/
 Uno      >>> http://www.pighixxx.net/portfolio-items/uno/?portfolioID=314
 Mega2560 >>> http://www.pighixxx.net/portfolio-items/mega/?portfolioID=314
*/



//const byte pin_T2 = 10;
const byte pin_T2 = LED_BUILTIN;


void setup(void) {
  Serial.begin(9600);
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(pin_T2, OUTPUT);

  Serial.print("OCR2A");  Serial.print('\t'); formatiere_Byte (OCR2A);    
  Serial.print("OCR2B");  Serial.print('\t'); formatiere_Byte (OCR2B);
  Serial.print("TCCR2A"); Serial.print('\t'); formatiere_Byte (TCCR2A);
  Serial.print("TCCR2B"); Serial.print('\t'); formatiere_Byte (TCCR2B); 
  Serial.print("TIMSK2"); Serial.print('\t'); formatiere_Byte (TIMSK2);  
  Serial.flush();
  
  set_Timer2();   
 
  Serial.println();
  Serial.print("OCR2A");  Serial.print('\t'); formatiere_Byte (OCR2A);    
  Serial.print("OCR2B");  Serial.print('\t'); formatiere_Byte (OCR2B);
  Serial.print("TCCR2A"); Serial.print('\t'); formatiere_Byte (TCCR2A);
  Serial.print("TCCR2B"); Serial.print('\t'); formatiere_Byte (TCCR2B); 
  Serial.print("TIMSK2"); Serial.print('\t'); formatiere_Byte (TIMSK2);
  
}

void loop(void) {
  
}


// ****** Funktionen ******* //
    
void set_Timer2()         // CTC, Mode 2
{
  AtomicSection
  {
    // erst die Control Register setzen
    TCCR2A = (1<<WGM21);    // Mode 2
    TCCR2B = (1<<CS22);     // Prescaler 64
  
    // dann die davon abhaengigen.
    OCR2A = 249;            // Compare
    TIMSK2 = (1<<OCIE2A);   // Compare Match A
    TCNT2 = 0;              // Reset Counter Register    
  }             
}  


ISR(TIMER2_COMPA_vect)          // Timer 2 Interrupt 
{  
  static bool state = LOW;
  state = !state;
  digitalWrite(pin_T2, state);                    
}


void formatiere_Byte (unsigned int data)
{
  Serial.print(F("data: "));
  for (char i=7;i>=4;i--) {
    Serial.print( (data >> i) & 0x01);
  }
  Serial.print("'");
  for (char i=3;i>=0;i--) {
    Serial.print( (data >> i) & 0x01);
  }
  Serial.println();
}