;**********************************************************************************
;Beschreibung:
;Dieses Programm lässt eine LED am Pin0 des Ports B eines ATmega8 
;mit 2Hz blinken (Bei 4MHz Oszillator-Frequenz).
;Ein Timer (TC0) zählt nach oben bis zum Überlauf, woraufhin 
;ein TC0-Überlauf-Interrupt erzeugt wird und zur "TIM0_OVF"-ISR verzweigt wird,
;die dann die LED ein- oder ausschaltet.
;**********************************************************************************

.include "m8def.inc"  ;Die Definitionsdatei des ATmega8 einfügen.

.def temp   	= R16 ;Es werden in diesem Programm 2 Arbeitsregister benötigt.
.def temp2  	= R17 ;benötigt: R16 und R17 (ginge auch mit nur einem).

rjmp RESET ; Reset Handler
reti	; IRQ0 Handler
reti	; IRQ1 Handler
reti	; Timer2 Compare Handler
reti	; Timer2 Overflow Handler
reti	; Timer1 Capture Handler
reti	; Timer1 CompareA Handler
reti	; Timer1 CompareB Handler
reti	; Timer1 Overflow Handler
rjmp TIM0_OVF ; Timer0 Overflow Handler. Erzeugt ein Interrupt beim Timer0-Überlauf und springt zu "TIM0_OVF:"-ISR
reti	; SPI Transfer Complete Handler
reti	; USART RX Complete Handler
reti	; UDR Empty Handler
reti	; USART TX Complete Handler
reti	; ADC Conversion Complete Handler
reti	; EEPROM Ready Handler
reti	; Analog Comparator Handler
reti	; Two-wire Serial Interface Handler
reti	; Store Program Memory Ready Handler

reset:
ldi temp, LOW(RAMEND)	;Initialisieren des StackPointers:
out SPL, temp
ldi temp, HIGH(RAMEND)
out SPH, temp

			;Int. Oszillator kalibrieren:
ldi temp, $C2		;Diesen Wert im STK500-Steuerpanel ablesen unter "Advanced" (dort wird	
out OSCCAL, temp 	;auch die gewünschte Frequenz des int. Oszillators eingestellt).

ldi temp,  1<<TOIE0	;Ein INT auslösen,
out TIMSK, temp		;falls ein TC0-Überlauf-Interrupt auftritt.

ldi temp, 0b101 ;Timer0 starten mit Vorteiler 1:1024 (Teilt die Blinkfrequenz durch 1024)
out TCCR0, temp ;TCCR0 ist das Kontrollregister des Timers 0

ser temp	;Arbeitsregister "temp" mit Einsern füllen.
out DDRB, temp	;Datenrichtungsregister des Ports B mit Einsern aus "temp" füllen (= alle Pins des Ports als AUSGANG)
out PORTB, temp	;Alle Pins des Ports auf's High-Level bringen (=LED's am PortB löschen)


sei		;Interrupts zulassen
;------------------------------

loop:	;Warten auf Timer0-Überlauf in einer Endlosschleife.
	
rjmp loop

TIM0_OVF: ;Die Blink-ISR lässt die LED am Pin 0 am PORTB (=PB0) blinken.
	sbic PORTB, 0		;Nächsten Befehl überspringen, falls Bit0 abm PortB ist AUS (= LED ist EIN)	
		rjmp led_ein	;Ansonsten LED einschalten (s. unten).
	sbis PORTB,0		;Überspringen, falls Bit0 abm PortB ist EIN (= LED ist AUS)	
		rjmp led_aus	;Ansonsten LED ausschalten (s. unten).
	led_ein:		;Zum Einschalten:
		cbi PORTB, 0	;Bit 0 am PortB löschen
		rjmp end	;und beenden.
	led_aus:		;Zum Ausschalten:
		sbi PORTB, 0	;Bit 0 am PortB setzen.
	end:
	ldi temp, 12		;Hier wird der Timer0 mit einem Startwert (z.B. 12) vorbelegt.
	out TCNT0, temp	
reti				;ISR beenden.