;Fahrtregler (korrekt: "Steller") für Modellbau-Funkfernsteuerung
;zur Ansteuerung einer H-Brücke mit positiven Impulsen.
;Die Impulsbreite des Empfangsdecoders sollte 1,0ms...1,5ms...2,0ms betragen.

;Tiny15 Version 1...


;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
;!!!Achtung!!! - Veränderte Anschlussbelegung gegenüber älteren Versionen!!!
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

;Anschlussbelegung:
;PB0 (Pin 5): (ISP-MOSI) Transistor für Bremslicht (bzw. Programmier-LED) gegen Masse
			 
;PB1 (Pin 6): (ISP-MISO) Transistor für Rückfahrlicht (bzw Test-LED) gegen Masse
;						und Programmiertaste gegen +5V

;PB2 (Pin 7); (ISP-SCK) Eingang Kanalimpuls
			  
;PB3 (Pin 2); PWM-Ausgang Vorwärts

;PB4 (Pin 3); PWM-Ausgang Rückwärts

;Diese Einstellungen dürfen vom Benutzer verändert werden:

.equ errors=20		;Anzahl erlaubter Impulsfehler und erforderlicher Neutralstellungen
.equ bremszeit=250	;Startwert Bremszeit (Differenz zu 256) in 20ms-Schritten (Kanalimpulse)
.equ neutral=150	;Vorgabe für Steuerknüppelmitte (1,5ms)
.equ sprz=5			;Mittenspreizung
.equ kalad=1022		;Adresse, wo der Brenner das Kalibrationsbyte hin schreibt...


;Die folgenden Einstellungen dürfen nicht ohne zwingenden Grund verändert werden...
.equ timstart=214	;Startwert Timer0 (Differenz bis 256...)
.equ taste=1		;Bit Programmiertaste und Rückfahrlicht in PortB
.equ rfs=1			;Bit Rückfahrscheinwerfer (gleich Programmiertaste) in PortB
.equ led=0			;Bit Programmier-LED bzw. Bremslicht in PortB
.equ brems=0		;Bit Bremslicht (gleich Programmier-LED) in PortB
.equ vor=3			;Bit Vorwärts in PortB und Richtungsregister
.equ zur=4			;Bit Rückwärts in PortB und Richtungsregister
.equ rfl=1			;Bit Rückfahrlicht in Richtungsregister



.def srsk=r1		;Sicherheitskopie vom Statusregister während ISR Timer0-Überlauf
.def srsk1=r2		;Sicherheitskopie vom Statusregister während ISR externer Interrupt
.def tsw=r3			;Timer-Startwert
.def tempo=r4		;Fahrtempo
.def max=r5			;Maximaltempo, Zählumfang PWM-Treppenzähler
.def tw=r6			;aktueller Scannwert Kanalimpulsbreite
.def sw=r7			;Nachlaufwert vom Scannwert Kanalimpulsbreite
.def mitte=r8		;Mittelwert Kanalimpuls (Stop-Bereich)
.def tou=r9			;Time-out für Fehlererkennung
.def zein=r10		;Zähler zum Einschalten (zählt Neutralstellungen)
.def zaus1=r11		;Fehler-Zähler zum Ausschalten bei Impulsbreitenfehler
.def zaus2=r12		;Fehler-Zähler zum Ausschalten bei Impulspausenfehler
.def taz=r13		;Tastenzeitzähler
.def ipv=r14		;Impulspausen-Vorteiler

.def temp=r16		;Tempo-Zwischenwert
.def flags=r17		;Flags zur Ereignissteuerung
	.equ imend=0		;Flag "Impulsende"
	.equ imanf=1		;Flag "Impulsanfang"
	.equ aktiv=2		;Flag "Ausgänge aktiv"
	.equ menak=3		;Flag "Menü aktiv"

	.equ drich=6		;Flag "Drehrichtung Motor"
	.equ richt=7		;Flag "Richtung"


.def ipz=r18		;Impulspausenzähler
.def pwz=r19		;PWM-Treppenzähler
.def ri=r20			;Fahrtrichtung
.def mp=r21			;Menüpunkt-Zähler
.def leb=r22		;Blinktakt LED
.def tmp=r23		;temporär

.include"tn15def.inc"
.cseg
.org 0              ;Reset- und Interrupt-Vektoren AT-Tiny15
 rjmp RESET         ;Reset handler
 rjmp impuls		;IRQ0 handler
 reti ;rjmp PIN_CHANGE    ;Pin change handler
 reti ;rjmp TIM1_CMP      ;Timer1 compare match
 reti ;rjmp TIM1_OVF      ;Timer1 overflow handler
 rjmp takt			;Timer0 overflow handler
 reti ;rjmp EE_RDY        ;EEPROM Ready handler
 reti ;rjmp ANA_COMP      ;Analog Comparator handler
 reti ;rjmp ADC           ;ADC Conversion Handler

RESET:

ldi r16, 0x7E ; <- hier den ausgelesenen Wert eintragen
out OSCCAL, r16
 
 
 ;  ORIGINAL
 ; |        | 
 ; |        |
 ; V        V
 ;ser temp			;Referenz für Vergleich Kalibration
 ;ldi zl,low(kalad)	;Adresse auf Kalibrationsbyte L (Taktfrequenzeinstellung AVR)
 ;ldi zh,high(kalad)	;und H (da schreibt der Brenner das automatisch hin...)
 ;lpm				;Kalibrationsbyte lesen
 ;cp r0,temp			;Kalibrationsbyte gültig?
 ;breq reset0		;nein, keine Kalibration durchführen
 ;out osccal,r0		;ja, Chip kalibrieren...
reset0:
 clr ri				;Fahrtrichtung ausschalten
 clr pwz			;PWM-Zähler
 clr mp				;Menüpunkt
 clr leb			;LED-Blinkzähler
 clr taz			;Tastenzeitzähler
 ldi flags,0		;Ereignis-Flags
 clr ipz			;Impulspause H
 clr ipv			;Impulspause L
 clr leb			;LED-Blinker
 ldi temp,errors	;Fehleranzahl
 mov tou,temp		;in Vorgabewert
 mov zein,tou		;in Einschaltzähler
 mov zaus1,tou		;in Impulsbreitenfehlerzähler
 mov zaus2,tou		;und in Impulspausenfehlerzähler
 ldi temp,15		;Watchdog auf 1,9s
 out wdtcr,temp		;einschalten
 ldi temp,neutral	;Mittelwert (Stop)
 mov mitte,temp		;zuweisen
 ldi temp,(neutral/3-sprz-1)	;Maximalwert Tempo
 mov max,temp		;zuweisen
 ldi temp,timstart	;Startwert für 
 mov tsw,temp		;Timer zuweisen
 ldi temp,0b00000110;Pull-Ups ein und Bremslicht und
 out portb,temp		;PWM-Impulsports aus
 ldi temp,24		;außer PWM-Impulsports erstmal
 out ddrb,temp		;alles als Eingang
 ldi temp,1			;externen Interrupt
 out mcucr,temp		;auf Pegelwechsel
 sbic pinb,taste	;Programmiertaste gedrückt?
 sbr flags,1<<menak	;ja, Programmiermodus ein
 ldi temp,0			;EEPROM-Adresse für
 out eear,temp		;Neutralstellung
 sbi eecr,eere		;EEPROM
 in temp,eedr		;lesen
 cpi temp,255		;EEPROM leer?
 breq reset1		;ja...
 mov mitte,temp		;nein, Werte aus EEPROM benutzen
 ldi temp,1			;EEPROM-Adresse für
 out eear,temp		;maximales Tempo
 sbi eecr,eere		;EEPROM
 in temp,eedr		;lesen
 cpi temp,255		;EEPROM leer?
 breq reset1		;ja...
 mov max,temp		;nein, Werte aus EEPROM benutzen
 ldi temp,2			;EEPROM-Adresse für
 out eear,temp		;Richtungsumkehr
 sbi eecr,eere		;EEPROM
 in temp,eedr		;lesen
 cpi temp,255		;EEPROM leer?
 breq reset1		;ja...
 andi temp,1<<richt	;nein, nur Richtungsbit
 or flags,temp		;im Register Flags setzen
 ldi temp,3			;EEPROM-Adresse für
 out eear,temp		;Rückfahrlicht-Umkehr
 sbi eecr,eere		;EEPROM
 in temp,eedr		;lesen
 cpi temp,255		;EEPROM leer?
 breq reset1		;ja...
 andi temp,1<<drich	;nein, nur Drehrichtungsbit
 or flags,temp		;im Register Flags setzen
reset1:
 ldi temp,9			;Vorteiler 1:16
 out tccr1,temp		;für Timer1 (Impulsbreitenmessung)
 mov sw,mitte		;Start in Neutralstellung
 ldi temp,64		;externen Interrupt
 out gimsk,temp		;einschalten
 ldi temp,1			;Vorteiler Timer0 auf 1:1 einstellen, 
 out tccr0,temp		;erzeugt PWM-Takt...
 out tcnt0,tsw		;Startwert in Timer0 setzen
 ldi temp,2			;Bit 1 in Timer-Interrupt-Mask-Register
 out timsk,temp		;schaltet Timer0-Überlauf-IRQ frei
 sei				;gibt Interrupt-Betrieb frei

main:
 sbrc flags,imend	;Impulsende erreicht?
 rjmp main0			;nein...
 sbrc flags,imanf	;Impulsanfang?
 rjmp main2			;nein...
 rjmp main

main0:
;Impulsende,
;Im Sinne der Störunterdrückung erfolgt eine langsame Übernahme der Impulsbreitenänderung,
;also alle 20ms (je Kanalimpulsende) nur um jeweils eine Stufe
 mov temp,sw		;Hilfskopie vom alten Impulsbreitenwert
 cp sw,tw			;Wertänderung?
 breq trgh1			;nein...
 brmi trgh			;ja, größer geworden...
 					;ja, kleiner geworden, also verkleinern
 dec temp			;Referenz wegen Hysterese auch verkleinern
 cp temp,tw			;immer noch unterschiedlich? (dann war Abstand größer als 1)
 breq trgh1			;nein, noch nix ändern...
 dec sw				;ja, verkleinern
 rjmp trgh1			;weg hier...
trgh:			;größer geworden
 inc temp			;Referenz wegen Hysterese auch vergrößern
 cp temp,tw			;immer noch unterschiedlich? (dann war Abstand größer als 1)
 breq trgh1			;nein, noch nix ändern...
 inc sw				;ja, vergrößern
trgh1: 
 mov temp,sw		;Scannwert sichern
 cbr flags,1<<imend	;Impulsbehandlung fertig

 cp sw,mitte		;langer Impuls?
 brmi kurz			;kurzer...
lang:		;langer
 sub temp,mitte		;nein, Vorwärts oder Rückwärts?
 subi temp,sprz		;Stop-Bereich in der Mitte
 brmi mstop			;ja...
 sbrs flags,richt	;Richtungsumkehr deaktiviert?
 rjmp forward		;ja, Vorwärts...
 sbrc flags,richt	;Richtungsumkehr aktiviert?
 rjmp revers		;ja, Rückwärts...
kurz:		;kurzer
 mov temp,mitte		;Differenz zwischen Neutralwert
 sub temp,sw		;und aktuellem Impulswert
 subi temp,sprz		;Stop-Bereich in der Mitte
 brmi mstop			;ja...
 sbrs flags,richt	;Richtungsumkehr deaktiviert?
 rjmp revers		;ja, Rückwärts...
forward:	;vorwärts
 sbrs flags,aktiv	;Anlage aktiv?
 rjmp fahrt			;nein, keine Fahrtrichtung setzen...
 clr ri				;Fahrtrichtung erstmal deaktivieren (Kurzschluss-Schutz für Brücke)
 sbrs flags,drich	;Drehichtungsumkehr aktiviert?
 sbr ri,1<<vor		;Fahrtrichtung vorwärts setzen
 sbrc flags,drich	;Richtungsumkehr deaktiviert?
 sbr ri,1<<zur		;Fahrtrichtung rückwärts setzen
 rjmp fahrt			;
revers:		;rückwärts
 sbrs flags,aktiv	;Anlage aktiv?
 rjmp fahrt			;nein, keine Fahrtrichtung setzen...
 clr ri				;Fahrtrichtung erstmal deaktivieren (Kurzschluss-Schutz für Brücke)
 sbr ri,1<<rfl		;Rückfahrlicht setzen
 sbrs flags,drich	;Drehrichtungsumkehr aktiviert?
 sbr ri,1<<zur		;Fahrtrichtung rückwärts setzen
 sbrc flags,drich	;Drehrichtungsumkehr deaktiviert?
 sbr ri,1<<vor		;Fahrtrichtung vorwärts setzen
fahrt:
 inc temp			;Hysterese kompensieren
 mov tempo,temp		;Tempo setzen
 sbrc flags,menak	;Menümodus aktiv?
 rjmp fahrt4		;ja, kein Bremslicht schalten, Bremslicht gilt als Programmiersignal...
 tst tempo			;nein, Menü nicht aktiv, Fahren? (oder Stehen?)
 breq fahrt4		;Stehen, also nix tun...
 ldi leb,bremszeit	;Fahren, also Verzögerung definieren, die beim Stehen abläuft,
 cbi ddrb,brems		;Bremslichtport zwar ausschalten (als Eingang, daher hochohmig),
 sbi portb,brems	;aber auf H-Pegel, damit es beim Einschalten leuchtet.
 rjmp fahrt4		;das Einschalten überspringen...
fahrt4:
 lsr temp			;Tempo-Kopie durch 2 teilen (Sicherheitsabstand schaffen)
 cp temp,max		;Tempo größer als Maxwert? (Impulsbreitenfehler, Imp. zu kurz oder zu lang)
 brmi fahrt1		;nein...
 dec zaus1			;ja, Impulsbreitenfehlerzähler reduzieren
 breq fahrt2		;abgelaufen?
 cbr flags,1<<aktiv	;Anlage deaktivieren
 clr ri				;Fahrrichtung deaktivieren (sofortiger Stop)
 mov zein,tou		;Einschaltzähler auf Startwert setzen
fahrt2:
 rjmp main1			;...
fahrt1:
 mov zein,tou		;Einschaltzähler auf Startwert setzen
 mov zaus1,tou		;Impulsbreitenfehlerzähler auf Startwert setzen
 rjmp main1			;...
mstop:		;Mittelstellung (gespreizt)
 sbrs flags,menak	;Menümodus aktiv?
 sbi ddrb,brems		;nein, also Bremslichtport freischalten, H-Pegel wirkt, bis TAZ 0 erreicht
 clr ri				;Richtung löschen
 clr tempo			;Tempo löschen
 dec zein			;Einschaltzähler runter,
 brne main1			;abgelaufen?
 sbr flags,1<<aktiv	;Anlage aktivieren

main1:			;Menü...
 sbrs flags,menak	;Menü-Modus aktiv??
 rjmp main			;nein...
menutaste:		;Warten auf Loslassen der Programmiertaste
 sbrs mp,5			;Tastenflag in Menüpunkt gesetzt?
 rjmp menublink		;nein...
 inc taz			;Tastenzeit-Zähler hochzählen
 sbrs taz,7			;LEB unter 128?
 cbi portb,led		;ja, LED aus
 sbrc taz,7			;LEB über 127?
 sbi portb,led		;ja, LED ein
 sbis pinb,taste	;Programmiertaste noch gedrückt?
 andi mp,15			;nein, Blinkflag und Tastenflag im Menüpunktzähler abschalten
 rjmp menu1			;und zur Auswertung...
menublink:		;Dialogblinken für Menü
 sbrs mp,4			;Dialogausgabe aktiv?
 rjmp menu0			;nein...
 sbrs leb,3			;Blinkpause?
 rjmp menuLEDaus	;ja...
 andi mp,15			;Blinkflag mal schnell ausblenden
 mov tmp,leb		;Kopie von Blinkzähler
 swap tmp			;Nur Bit 4,5,6, aber unten nutzen
 andi tmp,7			;das andere löschen
 cp tmp,mp			;Menüpunkt mit LED-Blinkzähler vergleichen,
 brpl menuLEDaus	;genug geblinkt...
 sbi portb,led		;LED einschalten
 rjmp menutastan	;weiter...
menuLEDaus:
 cbi portb,led		;LED ausschalten
menutastan:
 ori mp,16			;Blinkflag wieder an
 sbis pinb,taste	;Programmiertaste schon gedrückt?
 rjmp main			;nein, noch nicht...
 clr taz			;ja, Tastendauerzähler löschen...
 ori mp,32			;Tastenflag im Menüpunktzähler setzen
 rjmp main			;fertig...
menu0:
 cpi mp,0			;Menüpunkt 0? (Taste noch vom Start gedrückt, LED ein)
 brne menu1			;nein...
 sbi portb,led		;LED einschalten
 sbi ddrb,led		;und Port als Ausgang
 sbis pinb,taste	;Taste noch gedrückt?
 ldi mp,(1+16)		;nein, Punkt 1, aber blinkend
 rjmp main			;fertig
menu1:			;Neutralstellung...
 cpi mp,1			;Menüpunkt 1?
 brne menu2			;nein...
 ldi mp,(2+16)		;Munüpunkt 2 + Blinkflag setzen
 sbrs taz,7			;ja, war Taste länger als 128 Kanalimpulse (2,56 s) gedrückt?
 rjmp main			;nein...
 mov mitte,sw		;letzte Kanalimpulsbreite als Neutralstellung werten
 ldi temp,0			;Adresse 0
 out eear,temp		;in EEPROM-Adresse,
 out eedr,mitte		;Neutralwert in EEPROM-Datenregister,
 cli
 sbi eecr,eemwe		;Schreibschutz aufheben
 sbi eecr,eewe		;EEPROM schreiben
 sei
 rjmp main			;fertig
menu2:			;Vollgas voraus...
 cpi mp,2			;Menüpunkt 2?
 brne menu3			;nein...
 ldi mp,(3+16)		;Menüpunkt 3 + Blinkflag setzen
 sbrs taz,7			;ja, war Taste länger als 128 Kanalimpulse (2,56 s) gedrückt?
 rjmp main			;nein...
 cbr flags,1<<aktiv	;Fahrstrom deaktivieren (Schutz vor abrupter Tempo/Richtungsänderung)
 clr ri				;Fahrrichtung deaktivieren (Schutz vor abrupter Tempo/Richtungsänderung)
 cp sw,mitte		;Ist Vorwärts-Impuls länger oder kürzer?
 brmi menu2a		;kürzer...
 cbr flags,1<<richt	;Normalbetrieb, langer Impuls = vorwärts, Richtungsumkehr löschen
 mov temp,sw		;Tempowert
 sub temp,mitte		;extrahieren
 rjmp menu2b		;zum Speichern...
menu2a: 
 sbr flags,1<<richt	;Umkehrbetrieb, kurzer Impuls = vorwärts, Richtungsumkehr setzen
 mov temp,mitte		;Tempowert
 sub temp,sw		;extrahieren
menu2b:
 subi temp,(sprz+1)	;Mittenspreizung berücksichtigen
 mov max,temp		;Wert zuweisen
 ldi temp,1			;Adresse 1
 out eear,temp		;in EEPROM-Adresse,
 out eedr,max		;Maximal-Tempowert in EEPROM-Datenregister,
 cli
 sbi eecr,eemwe		;Schreibschutz aufheben
 sbi eecr,eewe		;EEPROM schreiben
 sei
menu2c:
 sbic eecr,eewe		;EEPROM noch beschäftigt?
 rjmp menu2c		;ja...
 ldi temp,2			;Adresse 2
 out eear,temp		;in EEPROM-Adresse,
 mov temp,flags		;Richtungsumkehr aus Flags
 andi temp,1<<richt	;ermitteln (isolieren)
 out eedr,temp		;Flag für Richtungsumkehr in EEPROM-Datenregister,
 cli
 sbi eecr,eemwe		;Schreibschutz aufheben
 sbi eecr,eewe		;EEPROM schreiben
 sei
 rjmp main			;fertig
menu3:			;Drehrichtungsumkehr...
 cpi mp,3			;Menüpunkt 3?
 brne menu4			;nein...
 ldi mp,(4+16)		;Menüpunkt 4 + Blinkflag setzen
 sbrs taz,7			;ja, war Taste länger als 128 Kanalimpulse (2,56 s) gedrückt?
 rjmp menuend		;nein...
 cbr flags,1<<aktiv	;Fahrstrom deaktivieren (Schutz vor abrupter Tempo/Richtungsänderung)
 clr ri				;Fahrrichtung deaktivieren (Schutz vor abrupter Tempo/Richtungsänderung)
 ldi temp,3			;Adresse 3
 out eear,temp		;in EEPROM-Adresse,
 cp sw,mitte		;langer Impuls, ist Eingabe-Impuls länger oder kürzer?
 sbrc flags,richt	;Richtungsumkehr?
 brmi menu3a		;nein, "nein"
 sbrs flags,richt	;Richtungsumkehr?
 brpl menu3a		;ja, "nein"
 cbr flags,1<<drich	;Normalbetrieb, langer Impuls = vorwärts
 rjmp menu3b		;...
menu3a: 
 sbr flags,1<<drich	;Umkehrbetrieb, kurzer Impuls = vorwärts
menu3b: 
 mov temp,flags		;Drehrichtungs-Umkehr aus Flags
 andi temp,1<<drich	;ermitteln (isolieren)
 out eedr,temp		;Flag für Drehrichtungs-Umkehr in EEPROM-Datenregister,
 cli
 sbi eecr,eemwe		;Schreibschutz aufheben
 sbi eecr,eewe		;EEPROM schreiben
 sei
 rjmp menuend		;fertig
menu4:
 rjmp main			;...
menuend:
 cbr flags,1<<menak	;Menümodus beenden
 rjmp main			;fertig

main2:			;Impulsbeginn...
 wdr				;Köter füttern
 cbr flags,1<<imanf	;Flag Impulsbeginn löschen
 inc leb			;Blinktakt LED
 cpi ipz,2			;Signalzyklus 16,384ms bis 24,567ms ??
 breq main2a		;ja...
 dec zaus2			;nein, Pausenfehlerzähler runter
 brne main2b		;abgelaufen? nein...
 cbr flags,1<<aktiv	;ja, Anlage deaktivieren (Pausenfehler)
 clr ri				;Fahrtrichtung deaktivieren (sofortiger Stop)
 mov zein,tou		;Einschaltzähler auf Startwert setzen
 clr ipz			;Impulspausenzähler auf 0 (Start Messung)
 clr ipv			;Vorteiler auch
 rjmp main			;...
main2a: 
 clr ipz			;Impulspausenzähler auf 0 (Start Messung)
 clr ipv			;Vorteiler auch
 mov zaus2,tou		;Pausenfehlerzähler auf Startwert, da Pause korrekt
main2b:
 sbrc flags,menak	;Menümodus aktiv?
 rjmp main			;ja, kein Bremslicht/Rückfahrlicht schalten,
 					;denn Bremslicht gilt als Programmiersignal,
					;und auf Rückfahrlicht liegt Programmiertaste...
 sbrs ri,rfl		;nein, Rückwärtsfahrt inaktiv?
 cbi ddrb,rfs		;ja, Rückfahrscheinwerfer aus
 sbrc ri,rfl		;Rückwärtsfahrt aktiv?
 sbi ddrb,rfs		;ja, Rückfahrscheinwerfer ein
 tst leb			;LED-Blinkzähler für Bremslicht missbrauchen
 brne main2c		;Nulldurchgang? nein...
 cbi portb,brems	;Bremslicht ausschalten (Pegel auf L, wird erst durch Fahren wieder H)
main2c:
 rjmp main			;fertig...

takt:		;ISR Überlauf Timer0 (PWM-Treppenzähler)
 out tcnt0,tsw		;Timer auf Startwert setzen
 in srsk,sreg		;Statusregister sichern
 inc ipv			;Impulspausenzähler erhöhen
 brne takt1			;Übertrag?
 inc ipz			;ja
takt1:
 sei				;andere Interrupts freigeben
 inc pwz			;PWM-Treppenzähler hoch
 cp pwz,tempo		;Fahrtwert erreicht?
 brmi takt2			;nein...
 cbi portb,vor		;ja, beide Ausgänge
 cbi portb,zur		;ausschalten
takt2:
 cp pwz,max			;max. PWM-Treppenzählerstand erreicht?
 brne takt3			;nein...
 clr pwz			;ja, von 0 beginnen
 cbi portb,vor		;PWM-ausschalten,
 cbi portb,zur		;falls noch an
 sbrc ri,vor		;Vorwärtsfahrt?
 sbi portb,vor		;ja, einschalten
 sbrc ri,zur		;Rückwärtsfahrt?
 sbi portb,zur		;ja einschalten
takt3:
 out sreg,srsk		;Statusregister wiederherstellen
 reti				;fertig...

impuls:		;ISR Impuls an Pin 6
 in srsk1,sreg		;Statusregister sichern
 sbis pinb,2		;Status ext. Interrupt?
 rjmp impend		;fallend, Impulsende...
 out tcnt1, ipz		;und Timer1 löschen (Start Messung)
 sbr flags,1<<imanf	;Impulsanfang-Flag setzen (Rest außerhalb der ISR bearbeiten)
 out sreg,srsk1		;Statusregister wiederherstellen
 reti				;fertig...
impend:		;Impulsende
 in tw,tcnt1		;Impulsbreite scannen
 sbr flags,1<<imend	;Impulsende-Flag setzen (Rest außerhalb der ISR bearbeiten)
 out sreg,srsk1		;Statusregister wiederherstellen
 reti				;fertig...

.db "(c) 02/2004 by ...HanneS... (Hannes.Lux@GMX.de) "