BootLoader.ino

#include "test.h"

#include <SPI.h>

// RAM Datalines

int d0 = A0;

int d1 = A1;

int d2 = A2;

int d3 = A3;

int d4 = A4;

int d5 = A5;

int d6 = 6;

int d7 = 7;

// RAM Control

int cs_ram = 4;

int we_ram = 3;

int oe_ram = 2;

// RAM Addresslines

int miso = 11;

int mosi = 12;

int sck = 13;

int oe_sr = 10;

int ce1_sr = 8;

int ce2_sr = 9;

// MPU Control

int reset = 5;

void vSetReset(bool active)

{

  digitalWrite(reset, !active);

}

void vSetChipSelectRam(bool select)

{

  digitalWrite(cs_ram, !select);

}

void vSetWriteRam(bool active)

{

  digitalWrite(we_ram, !active);

}

void vSetReadRam(bool active)

{

  digitalWrite(oe_ram, !active);

}

void vSetChipSelectSr1(bool select)

{

  digitalWrite(ce1_sr, select);

}

void vSetChipSelectSr2(bool select)

{

  digitalWrite(ce2_sr, select);

}

void vSetOutputEnableSr(bool active)

{

  digitalWrite(oe_sr, !active);

}

void vWriteLowerAddress(byte lowAddress)

{

  vSetChipSelectSr1(true);

  SPI.transfer(lowAddress);

  vSetChipSelectSr1(false);

}

void vWriteHighAddress(byte highAddress)

{

  vSetChipSelectSr2(true);

  SPI.transfer(highAddress);

  vSetChipSelectSr2(false);

}

void vWriteAddress(uint16_t addr)

{

  vWriteLowerAddress((byte)(addr & 0xff));

  vWriteHighAddress((byte)((addr >> 8) & 0xff));

}

void writeToAddress(uint16_t addr, byte data)

{

  vSetChipSelectRam(false);

  vSetWriteRam(false);

  vSetReadRam(false);

  vSetOutputEnableSr(false);

  vWriteAddress(addr);

  pinMode(d0, OUTPUT);

  pinMode(d1, OUTPUT);

  pinMode(d2, OUTPUT);

  pinMode(d3, OUTPUT);

  pinMode(d4, OUTPUT);

  pinMode(d5, OUTPUT);

  pinMode(d6, OUTPUT);

  pinMode(d7, OUTPUT);

  digitalWrite(d0, (data >> 0) & 0x1);

  digitalWrite(d1, (data >> 1) & 0x1);

  digitalWrite(d2, (data >> 2) & 0x1);

  digitalWrite(d3, (data >> 3) & 0x1);

  digitalWrite(d4, (data >> 4) & 0x1);

  digitalWrite(d5, (data >> 5) & 0x1);

  digitalWrite(d6, (data >> 6) & 0x1);

  digitalWrite(d7, (data >> 7) & 0x1);

  vSetOutputEnableSr(true);

  vSetChipSelectRam(true);

  vSetWriteRam(true);

  //delay(100);

  vSetWriteRam(false);

  vSetChipSelectRam(false);

  vSetOutputEnableSr(false);

}

void readFromAddress(uint16_t addr, byte *data)

{

  vSetChipSelectRam(false);

  vSetWriteRam(false);

  vSetReadRam(false);

  vSetOutputEnableSr(false);

  vWriteAddress(addr);

  pinMode(d0, INPUT);

  pinMode(d1, INPUT);

  pinMode(d2, INPUT);

  pinMode(d3, INPUT);

  pinMode(d4, INPUT);

  pinMode(d5, INPUT);

  pinMode(d6, INPUT);

  pinMode(d7, INPUT);

  vSetOutputEnableSr(true);

  vSetChipSelectRam(true);

  vSetReadRam(true);

  //delay(100);

  *data = 0;

  *data |= ((byte)digitalRead(d0) << 0);

  *data |= ((byte)digitalRead(d1) << 1);

  *data |= ((byte)digitalRead(d2) << 2);

  *data |= ((byte)digitalRead(d3) << 3);

  *data |= ((byte)digitalRead(d4) << 4);

  *data |= ((byte)digitalRead(d5) << 5);

  *data |= ((byte)digitalRead(d6) << 6);

  *data |= ((byte)digitalRead(d7) << 7);

  vSetReadRam(false);

  vSetChipSelectRam(false);

  vSetOutputEnableSr(false);

}

void setup() {

  // MPU Control

  pinMode(reset, OUTPUT);

  // RAM Control

  pinMode(cs_ram, OUTPUT);

  pinMode(we_ram, OUTPUT);

  pinMode(oe_ram, OUTPUT);

  // RAM Addresslines

  pinMode(oe_sr, OUTPUT);

  pinMode(ce1_sr, OUTPUT);

  pinMode(ce2_sr, OUTPUT);

  SPI.begin();

  SPI.setClockDivider(SPI_CLOCK_DIV2);

  SPI.setDataMode(SPI_MODE0);

  vSetReset(true);

  vSetChipSelectRam(false);

  vSetWriteRam(false);

  vSetReadRam(false);

  vSetChipSelectSr1(false);

  vSetChipSelectSr2(false);

  vSetOutputEnableSr(false);

  Serial.begin(9600);

}

void loop() {

  byte data;

  prog_uchar *prog = program;

  for (uint16_t i = 0; i < programSize; i++)

  {

    writeToAddress(i, pgm_read_byte_near(prog));

    prog++;

  }

  prog = program;

  bool progOk = true;

  for (uint16_t i = 0; i < programSize; i++)

  {

    byte data;

    readFromAddress(i, &data);

    if (data != pgm_read_byte_near(prog))

    {

      progOk = false;

      break;

    }

    prog++;

  }

  if (progOk)

    Serial.println("Memory Ok start Z80 Booting ...");

  else

    Serial.println("Memory not Ok. Freeze System");

  pinMode(cs_ram, INPUT);

  pinMode(we_ram, INPUT);

  pinMode(oe_ram, INPUT);

  pinMode(d0, INPUT);

  pinMode(d1, INPUT);

  pinMode(d2, INPUT);

  pinMode(d3, INPUT);

  pinMode(d4, INPUT);

  pinMode(d5, INPUT);

  pinMode(d6, INPUT);

  pinMode(d7, INPUT);

  if (!progOk)

    while (1) ;

  vSetReset(false);

  while(1) ;

}