ledtest2.asm

;********   ledtest2.asm   ********

; Testprogramm für AVR-Demoboard mit AT90S1200

; Durchzählen der LEDs per Timer0

; 

; Autor: J. Zimmermann    Status: getestet

; Datum: 08.06.1998    Version: 1.0

;

; Ing.-Büro Josef Zimmermann

; Copyleft nach GNU GPL

; 

; Konfiguration der Harware: Atmel Evaluationboard

; Verbindung per Flachbandkabel von LEDs mit PortB

;

; Für AVR-ASM V1.21 oder höher

; Bitte den sleep-Befehl nicht im Simulator verwenden!

;

; Die Art und Weise in der die Hardware-Register initialisiert werden ist nicht ganz 

; sauber. Besser wäre es zunächst das Register zu lesen, den Wert über Bit-Befehle zu

; ändern und dann zurück zu schreiben. Spätestens bei der Portierung auf einen anderen

; Controller der AVR-Familie kann es sonst zu Problemen kommen. Darüber hinaus muß bei

; der Portierung der Stackpointer initialisiert werden, was sich beim 90S1200 

; erübrigt, wegen des Hardwarestacks.

;

;********************************************

; Etwas Theorie zum Timer

; Es soll ein Timer_tic von 50ms erzeugt werden. Dieser steuert per Interrupt das 

; hochzählen des Ausgangsports. Das Demo-Board ist mit einem 4MHz-Quarz bestückt.

; Ein Interrupt wird beim Timer0 überlauf ausgelöst. Damit ergibt sich:

; 

; TCNT0 = 256 - (T_tic / ( T_clk * Kprescale)) 

; TCNT0 = 61 für T_tic = 50ms  T_clk = 1/4 us und Kprescale = 1024

;

; als Randbedingung für den Prescaler ist folgendes zu beachten:

; 

; Kprescale > (T_tic / (T_clk * 256))

;

; Wir T_tic größer als T_clk * 1024 * 256 kann man den Takt über einen Softwarezähler 

; weiter herunterteilen. Die Altenative wäre ein exter Takt (passender Frequenz) zum

; takten des Timer/Counters.

.include "1200def.inc"

.device AT90S1200

.def  Temp  =r16    ;temporary register

.def  L_Temp  =r17

;***** Reset- und Interrupt-Vektoren

RESET:  rjmp  ihMain    ;000 Reset Einsprung

  rjmp  ihIrq0    ;001 IRQ0

  rjmp  ihTimer0_ovf  ;002 Timer/Counter0 overflow

  rjmp  ihAna_cmp  ;003 Analog Comparator

;*** Initialisierung PortB, Timer0, Interrupte und IDLE-Mode  

ihMain:

  ser  Temp    ;Temp = 0xff

  out  DDRB,Temp  ;PORTB = alle Pins outputs

  out  PORTB, Temp  ;PORTB = 0xff -> alle LEDs aus, Low aktiv!

  ldi  L_Temp, 0x3d  ;TCNT0 := 61dez. = 0x3d  Timerregister mit Wert laden

  out  TCNT0, L_Temp

  ldi  L_Temp, 0x05  ;TCCR0 := 00000101b = 0x05  Prescalefaktor 1024 

  out  TCCR0, L_Temp

  ldi  L_Temp, 0x02  ;TIMSK := 00000010b = 0x02  Enable Timer0 overflow INT

  out  TIMSK, L_Temp

  sei      ;SREG Global Interrup enable

  ldi  L_Temp, 0x20  ;MCUCR := 00100000b = 0x20 IDLE MODE per "sleep"

  out  MCUCR, L_Temp

;*** Das eigentliches Hauptprogramm tut nichts, außer schlafen!   

; Achtung!!! "sleep" nicht auf dem Simulator verwenden! 

forever:      ; 

   sleep      ;CPU sagt gute Nacht bis der Timer klingelt. IDLE MODE!

  rjmp  forever    ;Und das ganze noch mal von vorne

;**** Timer overflow Interrupt 

; Die TOV0-Flag (im Register TIFR) wird automatisch mit Aufruf des Interruptvectors 

; zurückgesetzt. Die I-Flag (im Status-Register) wird mit RETI zurückgesetzt.

ihTimer0_ovf:

  ldi  L_Temp, 0x3d  ;TCNT0 := 0x31  Timerregister laden

  out  TCNT0, L_Temp

  out  PORTB,Temp  ;PORTB := Temp  

  dec  Temp    ;Temp := Temp - 1

  reti

;****** Ist etwas schiefgegangen? ****

; Diese Routinen dürfen eigentlich nicht angesprungen werden, da diese Interrupts 

; nicht frei gegeben sind. (Hilfreich beim debuggen) Die Routine endet in einer 

; Endlosschleife, weil kein RETI ausgeführt wird und damit der Global Interrupt 

; (I-Bit im Status Register) disabled bleibt!

; Es wird ein Fehler-Code auf die LEDs ausgegeben und das Programm hängt fest.

ihIRQ0:

  ldi  Temp, 0xfe  ;Wert für LED0 ein

  rjmp  INT_ERR    ;

ihAna_cmp:

  ldi  Temp, 0xfd  ;Wert für LED1 ein

  rjmp  INT_ERR

INT_ERR:

  out  PORTB, Temp  ;Error Wert an LEDs anzeigen

  rjmp  INT_ERR

VERSION:  .DB  "LEDTEST2.ASM FUER AVR 90S1200 Version 1.0 "