RFM01_RX.asm

; general device setup

; this is for the Arduino

; 

.NOLIST                ; Disable listfile generation 

.include "m328def.inc"

.LIST

; ******************************************************************

; todays project:

; control The RFM01 RX Module with an ATMega 48/168/328

; Receive an FSK data stream with it

; constants @ 16 Mhz clk 

; ******************************************************************

; crystal osc. frequency

.equ  F_CPU    = 16000000

; this is for the 868 Mhz Module

; PLL ref is 5 Khz

; frequency is f = 860Mhz + FREQUENCY * 5khz 

.equ  FREQUENCY  = 1024  ; 865.120 Mhz

;

; bitrate setting : BR = 10E6 / 29 / (BITRATE+1)

.equ   BITRATE    = 71  ; 4800 baud

; 

;

.equ  ROMSTART  = 0x0100

.equ  RAMSTART  = SRAM_START

.equ  cr    = 0x0d

.equ  lf    = 0x0a

.equ  spc    = 0x20

.equ  MS10    = 0x34

.equ  MS30    = 0x60

.equ  MS100    = 0x91    ; roughly 100mS with wozwait @ 16Mhz

.equ  MS500    = 0xf9    ; roughly 500mS with wozwait @ 16Mhz

.equ  timeout    = 0x14    ; 20 seconds for display timeout

; serial 

.equ  baudrate  = 19200

.equ  ubrvalue  = (F_CPU /(16 * baudrate)) - 1

; DMX definitions

.equ  DMXSTART = SRAM_START

.equ  DMXCHANNELS  = 16 

.equ  DMXEND    = DMXSTART+DMXCHANNELS

; hardware ports

; pinning for RFM recommends port D  

.equ  RFMClk  =  7  ; SPI Clock Out 

.equ  RFMOut  =   6  ; SPI Data Out  

.equ  RFMIn  =   5

.equ  RFMCs  =   4  ; RFM Chip Select Out 

.equ  RFMFfit =   3  ; Control for Fif0

.equ  RFMIrq =   2  ; Register/Data IRQ 

.equ  RFMPort  = PortD ; this is Port to the RFM module 

.equ  RFMDir  = DDRD  ; DDR for RFM module

.equ  RFMPin  = PinD  ; and the input pins

;

.equ  LEDPort = PortB

.equ  LEDDir = DDRB

.equ  OVLed  = 5

.equ  VID  = 0  ; data valid wire

;

; 

; general usage       ;  written by

; irq registers

.def  irqstor    = r12    ; EXT IRQ routine SREG safe place

; general purpose non-immediate

.def  lowtemp   = r13

.def  chksum    = r14

; immediate registers

.def  temp  = r16  ;misc usage, general purpose

.def  del  = r17  ; delay counter

.def  counter = r18  ; bitbanger

.def  length  = r19  ; stringlength

.def  spihi  = r20  ; send to RFM

.def  spilo  = r21  ;

.def   ticker  = r22

; flags for operation 

;7  6  5  4  3  2  1  0

;valid

.def    flags = r25  ; flags    

.equ  valid    = 0x80

.equ  validbit  = 7

; **************   MAIN PROGRAM STARTS HERE *************************

.CSEG 

  .ORG  0x0  ; note that this table is 2-byte addresses 

  jmp  RESET          ; Reset Handler

  jmp  EXT_INT0       ; IRQ0 Handler

  jmp  EXT_INT1       ; IRQ1 Handler

  jmp  PC_INT0         ; PCINT0 Handler

  jmp  PC_INT1         ; PCINT1 Handler

  jmp  PC_INT2         ; PCINT2 Handler

  jmp  WDT     ; Watchdog Timer Handler

  jmp  TIM2_COMPA     ; Timer2 Compare A Handler

  jmp  TIM2_COMPB     ; Timer2 Compare B Handler

  jmp  TIM2_OVF       ; Timer2 Overflow Handler

  jmp  TIM1_CAPT      ; Timer1 Capture Handler

  jmp  TIM1_COMPA     ; Timer1 Compare A Handler

  jmp  TIM1_COMPB     ; Timer1 Compare B Handler

  jmp  TIM1_OVF       ; Timer1 Overflow Handler

  jmp  TIM0_COMPA     ; Timer0 Compare A Handler

  jmp  TIM0_COMPB     ; Timer0 Compare B Handler

  jmp  TIM0_OVF       ; Timer0 Overflow Handler

  jmp  SPI_STC        ; SPI Transfer Complete Handler

  jmp  USART_RXC      ; USART, RX Complete Handler

  jmp  USART_UDRE     ; USART, UDR Empty Handler

  jmp  USART_TXC      ; USART, TX Complete Handler

  jmp  ADC_INT     ; ADC Conversion Complete Handler

  jmp  EE_RDY         ; EEPROM Ready Handler

  jmp  ANA_COMP       ; Analog Comparator Handler

  jmp  TWI     ; 2-wire Serial Interface Handler

  jmp  SPM_RDY        ; Store Program Memory Ready Handler

;

; IRQ stubs

EXT_INT0:

EXT_INT1:

PC_INT0:

PC_INT1:

PC_INT2:

WDT:

TIM2_COMPA:

TIM2_COMPB:

TIM2_OVF:

TIM1_CAPT:

TIM1_COMPA:

TIM1_COMPB:

TIM1_OVF:

TIM0_COMPA:

TIM0_COMPB:

TIM0_OVF:

SPI_STC:

USART_RXC:

USART_UDRE:

USART_TXC:

ADC_INT:

EE_RDY:

ANA_COMP:

TWI:

SPM_RDY:  reti

;

RESET:  cli    

  ldi  temp,low(RAMEND)  ; stackpointer

  sts  SPL,temp

  ldi  temp,high(RAMEND)

  sts  SPH,temp

; variable init

  clr  flags    ; reset anything

; hardware init

  rcall  init_ports  ; initialize  

  cbi  LEDPort, OVLED

;*********************************************************

; main program

main:  ldi  ticker,0xff  ; periodical calls

  clr  chksum  

  ldi  YH,High(DMXSTART)

  ldi  YL,low(DMXSTART)

  rcall  w30us

; reset the FIFO 

  ldi  spihi,0xce

  ldi  spilo,0x84

  rcall  spiout

  nop

; restart the FIFO

  ldi  spihi,0xce

  ldi  spilo,0x87

  rcall  spiout

  nop

main1:

  dec  ticker        ; timeouter

  rcall  rfmread      ; try to read something from the receiver

  sbrs  flags, validbit  ; if theres something valid throw it on the console

  rjmp  main1

; received something

  mov  spihi,temp    ; status 

  rcall  usbout

  cpi  YL,low(DMXEND)

  brcs  main1

  sbi  LEDPort,OVLED  ; LED flashes on full buffer 

  rcall  w100ms

  cbi  LEDPort,OVLED

  rjmp  main

; subprograms

;

; write a word from program space to RFM module

; pointer is in Z and is incremented

writedw: lpm  spilo,Z+

  lpm  spihi,Z+

; send a single word via SPI from spihi and spilo with chipselect 

spiout:  cbi  RFMPort,RFMCs  ; select 

  ldi  counter,16  ; 16 bitbangs

spio1:  rol  spilo    ; data into carry

  rol  spihi    ; this carry we send

  brcc  spiolo    ; data is lo

  sbi  RFMPort,RFMOut    

  rjmp  spio2

spiolo:  cbi  RFMPort,RFMOut

  nop

spio2:  nop

  sbi  RFMPort,RFMClk  ; strobe pulse

  nop

  nop

  cbi  RFMPort,RFMClk  ; set clock low

  nop

  nop

  dec  counter    ; next bit

  brne  spio1

  nop

  cbi  RFMPort,RFMOut  

  nop

  nop

  sbi  RFMPort,RFMCs

  ret

; read RFM01 status byte into spihi, spilo and the next data byte from the fifo

; the read command starts and continues with a 0 

; data will be stored at Y

rfmread:       ; read command

  cbi  RFMPort,RFMOut  ; set to lo for the rest of this run

  nop

  cbi  RFMPort,RFMCs  ; select rx

  ldi  counter,16  ; 16, read in the statusword

  nop

  sbi  RFMPort,RFMClk  ; strobe in the next bit

  nop

  clc

  sbis  RFMPin,RFMIn  ; read

  rjmp  rfmr2    ; no fifo there, skip this receiption

  sec

  rol  spilo    ; into 16 bit rollers

  rol  spihi

  dec  counter

rfmr1:  nop

  sbi  RFMPort,RFMClk  ; strobe in the next bit

  nop

  clc

  sbic  RFMPin,RFMIn  ; read

  sec

  rol  spilo    ; into 16 bit rollers

  rol  spihi

  cbi  RFMPort,RFMClk

  dec  counter

  brne  rfmr1

; now get the databyte

; read in 8 bits

  ldi  counter,8

rfmr6:  nop

  nop

  nop

  sbi  RFMPort,RFMClk  ; strobe pulse

  clc

  nop

  nop

  sbic  RFMPin, RFMIn  ; is it high ?

  sec

  rol  temp    ; from carry into lowest

rfmr5:  nop

  nop

  cbi  RFMPort,RFMClk  ; clr the clock

  dec  counter

  brne  rfmr6

  nop  

  sbi  RFMPort,RFMCs  ; deselect RFM

  st  Y+,temp    ; store in RAM

  add  chksum,temp  ; add to the checksum

  sbr  flags,valid    ; we have a valid reception

  ret

rfmr2:  cbr  flags,valid  ; no valid reception detected

  cbi  RFMPort, RFMClk    ; unclock

  sbi  RFMPort,RFMCs  ; deselect RFM

  ret      

;

;send a single char from temp via uart  

usbout:  push  temp

;first wait for transmitter empty

usbo1:  lds  temp,UCSR0A

  sbrs  temp,UDRE0  ; test buffer empty

  rjmp  usbo1

; send the byte

  pop  temp    ; get the byte back

  sts  UDR0, temp  ; and send it

  ret

; steve wozniak's wait routine - this time for AVR 

; this is the  routine with del^2 

; this wait routine is ingenious and handles wide ranges of delay 

; as a hommage to steve i port it to all my embedded systems. 

; some presets

w500ms:  ldi  del,MS500    ; half a second

  rjmp  wozwait

w100ms:  ldi  del,MS100    ; 1/10 second

  rjmp  wozwait

w10ms:  ldi  del,MS10

  rjmp  wozwait

w30ms:  ldi  del,MS30

  rjmp  wozwait

w30us:  ldi  del,0x05     ;

; here now the core wait routine

wozwait: push  del

wwait2:  push  del

wwait1:  subi  del,1  

  brne  wwait1

  pop  del

  subi  del,1

  brne  wwait2

  pop  del

  subi  del,1

  brne  wozwait

  ret

; initialize ports

; Port B

; RFM   7  6  5  4  3  2  1  0

;  -  -  LED  -  -  -  Power  VID

; Port D

; LED  7  6  5  4  3  2  1  0

;  CLK  Out  In  Sel  FFIT  Irq  TXD  RXD

;

;

; Port B - RFM Module    

init_ports:

;  rcall  w500ms

  ldi  temp,0b00101100    ; enable pullups and preset RFM wires to low

  out  RFMPort,temp    ; 

  ldi  temp,0b11010010    ; RFMPort set outputs and clip LED

  out  RFMDir,temp    ; set outputs

  ldi  temp,0b00100010

  out  LEDDir, temp

  ldi  temp,0b00100011    ; LED on , Power on, pullup on VID

  out  LEDPort, temp    ; illuminate clipping led

  rcall  w100ms      ; 100 mSec

init_uart:

  ldi  temp, (1<<TXEN0)  ; must be enabled first

  sts  UCSR0B, temp

  ldi  temp, 0b00000110  ; async,8bit,no parity

  sts  UCSR0C, temp

  ldi  temp, 0b01000000

  sts  UCSR0A, temp

  ldi  temp,low(ubrvalue)  ; write our fixed baudrate

  sts  UBRR0L, temp

  ldi  temp,high(ubrvalue)

  andi  temp,0x0f    ; mask forbidden bits

  sts  UBRR0H, temp  

; clear all pending

  ldi  temp,0x03

  out  EIFR, temp

  out  TIFR0, temp

; initialize the radio RX module

  ldi  spihi,0xda    ; reset RFM module

  ldi  spilo,0x01

  rcall  spiout

  rcall  w100ms

init_rfm:

  ldi  ZH,high(rfminit << 1)  ; table start

  ldi  ZL,low(rfminit << 1)

  ldi  length,NUM_COMMANDS  ; number of words

init_rf1:

  rcall  writedw      ; stream to RFM

  rcall  w30us      ; wait a little

  dec  length      ; next word

  brne  init_rf1

  rcall  w100ms      ; 100 mSec

; init uart

  ret  

; init values for the RFM01 868 mhz rx

.equ  NUM_COMMANDS  = 11

rfminit:

  .dw  0x0000      ; dummy read

  .dw  0b1001000110001011  ; configuration, 868 mhz, 134 khz bandwidth

  .dw  0xa000 + FREQUENCY  ; frequency

  .dw  0xc800 + BITRATE  ; data rate 

  .dw  0xc6f7      ; AFC setting

  .dw  0xc400 + 0b10101101  ; data filter

  .dw  0xc240      ; low battery & clk divider

  .dw  0xc084      ; receiver settings

  .dw  0xce00 + 0b10000101  ; Output and FIFO mode

  .dw  0xce00 + 0b10000111  ; toggle Output and FIFO mode

  .dw  0xc085      ; rx on , -91 db

  .db  "Ende"