Taupunkt_V1_V2_THD_DS18B_3ok.ino

//*******************************************************

//* Ein Arduino Wochenendprojekt von Csaba Klacek       *

//* Thema: Taupunktberechnung und Steuerung mit Arduino *

//* Version 3ok                                         *

//*******************************************************

// Eine Steuerung ist im Moment noch nicht implementiert. 

// Eine LCD Anzeige wird noch in der Nächster Version verfügbar sein

/*     

Berechnung erfolgt hier mit festen Temp un relHum, um die Formelrichtigkeit testen zu können.

Als Grundlage dienen die Berechnungen wie in der excel Tabelle

Temperatur : Temp 35 C   (Celsius)

Rel.Feuchte: relHum 55 %   ( % )

                                       (17,1*Temp)

Sättigungsdruck: Sdru (Pa) = 610,8*EXP( --------------)  ->(EXP(1)= 2,7183)

                                       (234,2+Temp)

Sättigungsdruckin mbar --> Sdru/100 (hPa(=mbar)

Tatsächliche Dampfdruck : TaDa=(Sdru/100)*(relHum/100)

Taupunkt: 241,2* (LN(TaDa)-LN(6,112)) / (17,5043- (LN(TaDa)-LN(6,112)) )  ...natürlicher Logaritmus

-->  241,2* (LN(TaDa)-1,8103) / (17,5043- (LN(TaDa)-1,8103))

ACHTUNG Punkt statt Dezimalkomma verwenden!!!

Version 2: stammt von hier  www.wetterochs.de  (Author ist Dipl-Phys-Stefan Ochs)--------------

Beschreibung:

Die Luft ist ein Gemisch verschiedener Gase. Eines dieser Gase ist der Wasserdampf.

Die Menge an Wasserdampf, die in der Luft enthalten sein kann, ist allerdings begrenzt.

Je wärmer die Luft ist, desto mehr Wasserdampf kann in ihr enthalten sein.

Die relative Luftfeuchtigkeit gibt an, wie viel Prozent des maximalen Wasserdampfgehaltes die Luft

im Augenblick enthält.Da der maximale Wasserdampfgehalt mit steigender Temperatur ansteigt,

fällt die relative Luftfeuchtigkeit mit steigender Temperatur (und umgekehrt).

Die Taupunkttemperatur ist definiert als die Temperatur, bei der der aktuelle Wasserdampfgehalt in der Luft

der maximale (100% relative Luftfeuchtigkeit) ist. Die Taupunkttemperatur ist damit eine von der aktuellen

Temperatur unabhängige Größe.

Eine Möglichkeit die Taupunkttemperatur zu messen ist das Abkühlen von Metall bis sich die Oberfläche

mit Wasserdampf beschlägt. Dann ist die Temperatur des Metalls die Taupunkttemperatur.

Es gibt keine exakten Formel zur Umrechnung der Taupunkttemperatur in die relative Luftfeuchtigkeit.

Zur Erstellung meines Taupunktrechners habe ich eine einfache Näherungsformel benutzt.

Eine exakte Umrechnung ist nur mit experimentell ermittelten Tabellen möglich.

Aus Temperatur und relativer Luftfeuchte bzw. Temperatur und Taupunkt lässt sich auch der absolute Feuchtegehalt

der Luft in Gramm Wasserdampf pro Kubikmeter ausrechnen.

Formeln:

Die Grundlage der Berechnungen ist die Näherungsformel für den Sättigungsdampfdruck

( Gleichung 1 ), die sogenannte Magnusformel. Die relative Luftfeuchtigkeit ist definiert

als das Verhältnis vom augenblicklichen Dampfdruck zum Sättigungsdampfdruck (umgeformte Gleichung 2).

Bei der Taupunkttemperatur ist definitionsgemäß der Sättigungsdampfdruck gleich dem aktuellen Dampfdruck.

Aus diesen beiden Definitionen folgt unmittelbar Gleichung 3, die Formel zur Berechnung der relativen

Luftfeuchtigkeit aus der Taupunkttemperatur. Die 4. Gleichung beschreibt umgekehrt die Berechnung

der Taupunkttemperatur aus der relativen Luftfeuchtigkeit und der aktuellen Temperatur. Diese 4.

Gleichung ist im Grunde nichts anderes als die nach T aufgelöste 1. Gleichung , wobei für

den Sättigungsdampfdruck der aktuelle Dampfdruck (und nicht der aktuelle Sättigungsdampfdruck) eingesetzt wird,

so dass die Taupunkttemperatur und nicht die normale Temperatur als Ergebnis herauskommt.

Aus der allgemeinen Gasgleichung ergibt sich die 5. Gleichung .

Bezeichnungen:

relHum = relative Luftfeuchte

Temp = Temperatur in °C

TK = Temperatur in Kelvin (TK = Temp + 273.15)

TD = Taupunkttemperatur in °C

DD = Dampfdruck in hPa

SDD = Sättigungsdampfdruck in hPa

Parameter:

a = 7.5, b = 237.3 für Temp >= 0

a = 7.6, b = 240.7 für Temp < 0 über Wasser (Taupunkt)

a = 9.5, b = 265.5 für Temp < 0 über Eis (Frostpunkt)

R* = 8314.3 J/(kmol*K) (universelle Gaskonstante)

mw = 18.016 kg/kmol (Molekulargewicht des Wasserdampfes)

AF = absolute Feuchte in g Wasserdampf pro m3 Luft

Formeln:

     1-Sättigungsdampfdruck in hPa   SDD(Temp) = 6.1078 * 10^((a*Temp)/(b+Temp))

     2-Tatsächliche Dampfdruck       DD(relHum,Temp) = relHum/100 * SDD(Temp)

     3-relativen Luftfeuchtigkeit aus der Taupunkttemperatur:  relHum(Temp,TD) = 100 * SDD(TD) / SDD(Temp)

     4-Taupunkttemperatur   TD(relHum,Temp) = b*v/(a-v) mit v(relHum,Temp) = log10(DD(relHum,Temp)/6.1078)

     5-Aus der allgemeinen Gasgleichung ergibt sich:

           AF(relHum,TK) = 10^5 * mw/R* * DD(relHum,Temp)/TK; AF(TD,TK) = 10^5 * mw/R* * SDD(TD)/TK

Anmerkungdes Verfassers (Stefan Ochs): Leider kann ich zu den Formeln aus Zeitgründen keinen Support leisten!

Die Formeln sind vollständig und richtig. Falls Sie Probleme mit der Mathematik haben,

suchen Sie bitte anderweitig Hilfe. Wenn Sie unsicher sind, ob die Näherungen in ihrem

Spezialfall zulässig sind, dann kann ich das nicht für Sie entscheiden

*/

// ACHTUNG: DHT Sensor Pinbelegung beachten!!!!!!  Ucc-GND-DATA  oder Ucc-DATA-GND. Die Versorgung geschiet durch 

// HIGH und LOW Signallevel an den Arduino Ausgängen

#include <Streaming.h> // Serial.print kompakte Schreibweise

#include <Metro.h> //Include Metro library, für zeitgesteuerte Schleife,Intervallbildung

#include <math.h>

#include "DHT.h"

#include <OneWire.h>

#include <DallasTemperature.h> // Dallas DS18B20 Temperatursensor als Oberflaechentemperaturfuehler

#define DHTPIN 8     // DHT Signal Pin an Arduino Eingang

//#define DHTTYPE DHT11   // DHT 11 

#define DHTTYPE DHT22   // DHT 22  (AM2302)

#define LED 13 // LED an Pin 13 

#define GND 10 // GND für DHT als LOW Level

#define Vcc 9 // DHT Ucc+5V Pin als HIGH Level

// Data wire is plugged into port 2 on the Arduino

#define ONE_WIRE_BUS 2

// Setup a oneWire instance to communicate with any OneWire devices (not just Maxim/Dallas temperature ICs)

OneWire oneWire(ONE_WIRE_BUS);

// Pass our oneWire reference to Dallas Temperature. 

DallasTemperature sensors(&oneWire);

// arrays to hold device address

DeviceAddress insideThermometer;

int state = HIGH;

float Temp_DS18;

float f; // DHT temp in Fahrenheit

float hi; // DHT heat Index für Fahrenheit

float DHT_Heatindex; // in Celsius die empfundene Temperatur für die momentane Luftfeuchte

float Taupunkt;    // berechneter Taupunkt Temperatur in C

float TaDa;       // Tatsächlicher Dampfdruck 

float Temp_DHT ;      // DHT gemessene Temperatur ---> temp in C

float relHum ;    // gemessene relative Feuchtigkeit ---> rF in %

float THum;       // Tatsaechliche Feuchte in g Wasserdampf pro m3 Luft ,wird berechnet

float Sdru;       //Saettigungsdruck in Pa

float Sdru_mbar;  //Saettigungsdruck geteilt durch 100, in hPa

float absF; //absolute Feuchte in g Wasserdampf pro m3 Luft für V1 Berechnung

byte merker = 0;

//---------------Parameter Version 2 ----------------------------------------------

float TK ;     //   = Temperatur in Kelvin (TK = T + 273.15)

float TD ;     //   = Taupunkttemperatur in °C

float DD ;     //   = Dampfdruck in hPa

float SDD ;     //  = Sättigungsdampfdruck in hPa

// Parameter:

float v ;         // (relHum,Temp), Methode2

float a = 7.5 ;    //für T >= 0

float b = 237.3 ;  //für T >= 0

//  a = 7.6, b = 240.7 für T < 0 über Wasser (Taupunkt)

//  a = 9.5, b = 265.5 für T < 0 über Eis (Frostpunkt)

float R_konst = 8314.3 ; //  R* = 8314.3 J/(kmol*K) (universelle Gaskonstante)

float mw = 18.016 ; // mw = 18.016 kg/kmol (Molekulargewicht des Wasserdampfes)

float AF ; //   = absolute Feuchte in g Wasserdampf pro m3 Luft

float TF ;  //   = tatsächliche Feuchte in g Wasserdampf pro m3 Luft

float Anzeige_Taupunkt; // Mittelwert aus der 2 Berechnungsmethoden.

float Alarm_Temp; //  Temperaturwert-Abstand Taupunkt-Oberflächentemperatur

Metro AnzeigeMetro = Metro(3000); // Alle 3 sec neue Werte berechnen, 

DHT dht(DHTPIN, DHTTYPE);

//----------------------------------------------------------------------------------

void setup() {

  pinMode(GND,OUTPUT);

  pinMode(Vcc,OUTPUT);

  pinMode(LED,OUTPUT);

  digitalWrite(GND,LOW); 

  digitalWrite(Vcc,HIGH);

  digitalWrite(LED,state);

  Serial.begin(9600);

  Serial.println(" Taupunktberechnung ;");

  dht.begin();

  delay(100);

  //Serial.println(" Temperatur : 35 C ");

  //Serial.println(" relHum : 55 % ");

  // locate devices on the bus

  Serial.print("Locating devices...");

  sensors.begin();

  Serial.print("Found ");

  Serial.print(sensors.getDeviceCount(), DEC);

  Serial.println(" Dallas DS18B20.");

  // report parasite power requirements

  Serial.print("Parasite power is: "); 

  if (sensors.isParasitePowerMode()) Serial.println("ON");

  else Serial.println("OFF");

   if (!sensors.getAddress(insideThermometer, 0)) Serial.println("Unable to find address for Device 0"); 

   // show the addresses we found on the bus

  Serial.print("Dallas DS18B20 0 Address: ");

  printAddress(insideThermometer);

  Serial.println();

  // set the resolution to 9 bit (Each Dallas/Maxim device is capable of several different resolutions)

  sensors.setResolution(insideThermometer, 12);

  Serial.print("Dallas DS18B20 0 Resolution: ");

  Serial.print(sensors.getResolution(insideThermometer), DEC); 

  Serial.println();

}

void loop() {

  if (AnzeigeMetro.check() == 1) { // check if the metro has passed its interval .

    if (state==HIGH)  state=LOW;  // LED13 Blinken lassen, falls merker gesetzt ist

     else state=HIGH;

    if (merker==1) digitalWrite(LED,state);

     else digitalWrite(LED,LOW);

    THD22(); // Sensordaten anzeigen

    Serial.println(F(" Temperatur an der Materialoberflaeche wo sich Tauwasser bilden kann"));

    Serial.print(F(" Sensordaten von Dallas DS18B20: "));

    sensors.requestTemperatures(); // Send the command to get temperatures

    // It responds almost immediately. Let's print out the data

    printTemperature(insideThermometer);

    Serial.println();

    Serial.println(F(" THD Data reading - Sensordaten vom DHT22  ---------------------------"));

    Serial.print(" Luftfeuchtigkeit: "); // THD Humidity

    Serial.print(relHum);

    Serial.println(" %\t");

    Serial.print(" Luft-Temperatur: "); 

    Serial.print(Temp_DHT);

    Serial.print(" *C (");

    Serial.print(f);

    Serial.println("*F)\t");

    Serial.print(" Heat index(gefuehlte Temperatur): ");

    Serial.print(hi);

    Serial.print("*F ");

    Serial.print(DHT_Heatindex);

    Serial.println("*C ");

    Serial.println();

     Taupunktberechnung_V2();

    Serial.println();

    Serial.println(F(" Taupunktberechnung nach Methode 2; --------------------------------"));

    Serial.print(F(" Saettigungsdampfdruck in hPa : "));

    Serial.println(SDD);

    Serial.print(" Dampfdruck in hPa : ");

    Serial.println(DD);

    Serial.print(" Taupunkt : ");

    Serial.print(TD);

    Serial.println(" *C ");

    Serial.print(F(" absolute Feuchte in g Wasserdampf pro m3 Luft : "));

    Serial.println(AF);

    Serial.print(F(" IST Feuchte in g Wasserdampf pro m3 Luft : "));

    Serial.println(TF);

    Serial.println();

    Taupunktberechnung_V1();

    Serial.println(F(" Taupunktberechnung nach Methode 1; ------------------------------"));

    Serial.print(" Saettigungsdruck mbar : ");

    Serial.println(Sdru);

    Serial.print(" Dampfdruck in hPa : ");

    Serial.println(DD);

    Serial.print(" Tatsaechliche Dampdruck in hPa : ");

    Serial.println(TaDa);

    Serial.print(" Taupunkt : ");

    Serial.print(Taupunkt);

    Serial.println(" *C ");

    Serial.print(F(" absolute Feuchte in g Wasserdampf pro m3 Luft : "));

    Serial.println(absF);

    Serial.print(F(" Tatsaechliche Feuchte in g Wasserdampf pro m3 Luft : "));

    Serial.println(THum);

    Serial.println();

    Serial.println("--------------Datenanzeige----------------");

    Anzeige_Taupunkt = (Taupunkt + TD)/2;

    Alarm_Temp = Temp_DS18-Anzeige_Taupunkt;

    Serial <<" Tauwasser bildet sich bei "<< Temp_DHT<<" *C Luftfeuchtigkeit "<< endl;

    Serial <<" auf eine Oberflaechentemperatur mit "<<Anzeige_Taupunkt<<" Grad Celsius"<< endl;

    Serial.println();

    Serial <<" Achtung! Bis zu Tauwasserbildung fehlen "<<Alarm_Temp<<" Grad Celsius Temperaturabfall "<< endl;

    if (Alarm_Temp < 10) {

      Serial <<" Es wird kritisch, bitte LUEFTUNG einschalten"<< endl;

      merker = 1; // LED 13 blinkt

    }

      else {

        Serial<<" Tauwasserbildung ist noch nicht zu erwarten. "<< endl;

        merker = 0; // LED 13 ist aus

      }

     Serial.println();

  } 

    //hier könnten weitere Codezeilen stehen, zB. für Relaissteuerung oder Änliches.....

}

//----LOOP ENDE-----

//------------------------Taupunktberechnung_V1 nach Methode1---------------------------------

void Taupunktberechnung_V1() {

  Sdru = 610.8 * exp((17.1*Temp_DHT)/(234.2+Temp_DHT));

  Sdru_mbar=Sdru/100;

  TaDa=(Sdru_mbar*relHum)/100;

  Taupunkt= 241.2 * ((log(TaDa)-1.8103) / (17.5043- (log(TaDa)-1.8103)));

  absF = ((Sdru *0.002165022853) / (Temp_DHT+273.15))*1000; //absolute Feuchte in g Wasserdampf pro m3 Luft

  THum = (absF/100)*relHum ; // Tatsaechliche Feuchte in g Wasserdampf pro m3 Luft 

  }

//------------------------Taupunktberechnung_V2 nach Methode2---------------------------------  

void Taupunktberechnung_V2() { 

    SDD = 6.1078 * pow(10,((a*Temp_DHT)/(b+Temp_DHT))); // Saettigungsdampfdruck in hPa

    DD = (relHum/100) * SDD; // Dampfdruck in hPa

    v = log10((DD/6.1078)); // ACHTUNG log 10 verwenden!!!

    TD = (b*v)/(a-v); // Taupunkt

    AF = 216.686912909 * (SDD/(Temp_DHT + 273.15)); //absolute Feuchte in g Wasserdampf pro m3 Luft

    TF = (AF/100) * relHum ; // Tatsaechliche Feuchte in g Wasserdampf pro m3 Luft 

 }

 //------------------------THD22 Messwerte für Taupunktberechnung---------------------------------

 void THD22() {

   relHum = dht.readHumidity();

   Temp_DHT =  dht.readTemperature();

   f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).

   if (isnan(relHum) || isnan(Temp_DHT) || isnan(f)) {

      Serial.println("Failed to read from DHT sensor!");

      return;

      }

  // Compute heat index, Must send in temp in Fahrenheit!

    hi = dht.computeHeatIndex(f, relHum);

    DHT_Heatindex = (hi-32)/1.8; // Fahrenhein in Celsius umrechnen

   }

 //------------------------------------------------------------------------------

 // function to print a device address

void printAddress(DeviceAddress deviceAddress){

  for (uint8_t i = 0; i < 8; i++)

  {

    if (deviceAddress[i] < 16) Serial.print("0");

    Serial.print(deviceAddress[i], HEX);

  }

}

// ------------------function to print the temperature for a device----------------

void printTemperature(DeviceAddress deviceAddress){

  Temp_DS18 = sensors.getTempC(deviceAddress);

  Serial.print("Temp C: ");

  Serial.print(Temp_DS18);

  Serial.print(" Temp F: ");

  Serial.println(DallasTemperature::toFahrenheit(Temp_DS18)); // Converts tempC to Fahrenheit

}