LCDControllerDEM120064A.asm

; Display Test for LCD DEM120064
; (C) Mario Latzig 2017
; on ATtiny2313(A), 4 MHz ext. Crystal
; PB0: CS      (Chip Select, active Low)
; PB1: RES     (Reset, active Low)
; PB2: DC      (Data=High / Command=Low)
; PB3: SCK     (Serial Clock, Data is triggered on Low-High-Edge)
; PB4: SDA     (Serial Data) 
; PD2: LED     (Test LED, active High)          
; *****************************************************************************
; *** Definitions                                                           ***
; *****************************************************************************
.def temp = r0                ; Temporary Register (Memory load)
.def zero = r1                ; (always Zero)
.def stat = r2                ; Temporary Status Register
.def a = r16                ; Temporary Register (a)  
.def b = r17                ; Temporary Register (b)
.def c = r18                ; Temporary Register (c)
.def d = r19                ; Temporary Register (d)
.def e = r20                ; Temporary Register (e)
.def f = r21                ; Temporary Register (f)
.def g = r22                ; Temporary Register (g)
.def pdat = r23                ; Temporary Port Register
.def ol = r24                ; Counter Register (LO)
.def oh = r25                ; Counter Register (HI)
; --- General -----------------------------------------------------------------
.equ FC = 4000000              ; Clock = 4 MHz (ext. Crystal)
; --- Pins --------------------------------------------------------------------
.equ PINB_CS = (1<<0)            ; PB0: CS      (Chip Select, active Low)
.equ PINB_RES = (1<<1)            ; PB1: RES     (Reset, active Low)
.equ PINB_DC = (1<<2)            ; PB2: DC      (Data=High / Command=Low)
.equ PINB_SCK = (1<<3)            ; PB3: SCK     (Serial Clock, Data is triggered on Low-High-Edge)
.equ PINB_SDA = (1<<4)            ; PB4: SDA     (Serial Data) 
.equ PIND_LED = (1<<2)            ; PD2: LED     (Test LED, active High)  
; === LCD =====================================================================
; $00: Set Lower Column Address
.equ LCD_SET_COL_LO = 0x00
; $10: Set Higher Column Address
.equ LCD_SET_COL_HI = 0x10
; $20: Set Internal Regulator Resistor Ratio (X0-X2: Internal regulator gain increases as X2X1X0 increased from 000b to 111b. At POR = 100b)
.equ LCD_SET_INT_REG_RES_RATIO = 0x20
; $28: Set Power Control Register (X0: Output op-amp buffer, X1: internal regulator,X2: internal voltage booster)
.equ LCD_SET_POWER_CTRL = 0x28
; $81: Set Contrast 
.equ LCD_SET_CONTRAST = 0x81
; $A0: Set Segment Re-map (X0=0: Col Addr $00=SEG0 (POR), X0=1: Col Addr $83=SEG0)
.equ LCD_CMD_SEGMENT_REMAP = 0xA0      
; $A2: Set LCD Bias (X0=0: 1/9 Bias, X0=1: 1/7 Bias)
.equ LCD_CMD_BIAS = 0xA2          
; $A6: Set Normal/Reverse Display (X0=0: normal display (POR), X0=1: reverse display)
.equ LCD_SET_NORMAL_DISPLAY = 0xA6          
; $A9: Set Bias Ratio / Set TC Value / Modify Osc. Freq.
.equ LCD_SET_BIAS_TC_OSC = 0xA9
; $AE: Set Entire Display On/Off (X0=0: normal display (POR), X0=1: entire display on)
.equ LCD_SET_DISPLAY = 0xAE
; $B0: Set Set Page Address
.equ LCD_SET_PAGE = 0xB0
; $C0: Set COM Output Scan Direction (X3=0: COM0 to COM[N-1] (POR), X3=1:  COM[N-1] to COM0)
.equ LCD_SET_COM_OUTPUT_SCAN_DIR = 0xC0
.equ LCD_COLS = 20              ; Number of Chars per Row
.equ LCD_ROWS = 8              ; Number of Rows
; *****************************************************************************
; *****************************************************************************
; *****************************************************************************
; *****************************************************************************
.org 0x0000
    rjmp init
.org INT_VECTORS_SIZE
; *****************************************************************************
; *****************************************************************************
.include "font.inc"
; ### INIT ####################################################################
    cli                  ; Disable interrupts
    clr zero              ; Reset Zero Register
    ldi a,LOW(RAMEND)          ; Init Stack Pointer
    out SPL,a
    rcall led_init            ; Inits Test LED
    rcall lcd_init            ; Inits LCD
    sei                  ; Enable interrupts
; ### TEST ####################################################################
    ldi a,'!'
    ldi oh,0
test_loop_row:
    ldi ol,0
test_loop_col:
    rcall lcd_char
    inc a
    cpi a,0x7F
    brne test_loop_cnt
    ldi a,'!'|0x80
test_loop_cnt:
    inc ol
    cpi ol,LCD_COLS
    brlo test_loop_col
    inc oh
    cpi oh,LCD_ROWS
    brlo test_loop_row
test_hold:
    rjmp test_hold
; *****************************************************************************
; *****************************************************************************
; ### Inits LCD
lcd_init:
    push a
    push b
    push pdat
    in pdat,PORTB
    sbr pdat,PINB_RES|PINB_CS
    cbr pdat,PINB_SCK|PINB_SDA|PINB_DC
    out PORTB,pdat
    in a,DDRB
    sbr a,PINB_SCK|PINB_SDA|PINB_DC|PINB_CS|PINB_RES
    out DDRB,a
    ser a                ; Enable Test LED
    rcall led_set
    cbr pdat,PINB_RES          ; Trigger HW Reset of LCD
    out PORTB,pdat
    rcall util_delay_10us
    sbr pdat,PINB_RES
    out PORTB,pdat
    ldi a,LCD_CMD_BIAS|0        ; Init Sequence
    rcall lcd_cmd
    ldi a,LCD_CMD_SEGMENT_REMAP|0
    rcall lcd_cmd
    ldi a,LCD_SET_COM_OUTPUT_SCAN_DIR|8
    rcall lcd_cmd
    ldi a,LCD_SET_INT_REG_RES_RATIO|5
    rcall lcd_cmd
    ldi a,LCD_SET_NORMAL_DISPLAY
    rcall lcd_cmd
    ldi a,LCD_SET_POWER_CTRL|7
    rcall lcd_cmd
    ldi a,LCD_SET_DISPLAY|1
    rcall lcd_cmd
    ldi a,LCD_SET_CONTRAST
    ldi b,0x20
    rcall lcd_cmd2
    clr a                ; Disable Test LED
    rcall led_set
    pop pdat
    pop b
    pop a
    ret
; ### Draw Char
; >a: The ASCII Char (0-127), Bit7: Invert Flag
; >ol: The Column (0-19)
; >oh: The Row (0-7)
lcd_char:
    push temp
    push a
    push b
    push pdat
    push ol
    push oh
    push zl
    push zh
lcd_char_chk:    
    mov temp,a
    cpi ol,LCD_COLS            ; ### Check Range
    brsh lcd_char_exit
    cpi oh,LCD_ROWS
    brsh lcd_char_exit
lcd_char_col:                ; ### Set LCD Column 
    lsl ol
    mov b,ol              ; (Multiply Char Column by 6)
    lsl ol
    add b,ol
    subi b,-6
    mov a,b
    andi a,0x0F
    ori a,LCD_SET_COL_LO
    rcall lcd_cmd
    mov a,b
    swap a
    andi a,0x0F
    ori a,LCD_SET_COL_HI
    rcall lcd_cmd
lcd_char_row:                ; ### Set LCD Page Address 
    mov a,oh              ; (Using Char Row)
    ori a,LCD_SET_PAGE
    rcall lcd_cmd
lcd_char_font:                ; ### Calculate Font Address 
    ldi zl,LOW(2*FONT5X7)        ; Offset = (ASCII Char - 0x20) * 5
    ldi zh,HIGH(2*FONT5X7)
    mov a,temp
    andi a,0x7F
    cpi a,' '
    brsh lcd_char_font_cnt
    ldi a,' '
lcd_char_font_cnt:  
    subi a,' '      
    clr b
    add zl,a
    adc zh,b
    lsl a
    rol b
    lsl a
    rol b
    add zl,a
    adc zh,b
lcd_char_draw:                ; ### Draw Char 
    in pdat,PORTB            ; Enable Chip Select
    cbr pdat,PINB_CS
    out PORTB,pdat
    ldi ol,5              ; Set 5 Bytes as Data
lcd_char_draw_loop:
    lpm a,z+
    sbrc temp,7
    com a
    ser b
    rcall lcd_byte
    dec ol
    brne lcd_char_draw_loop
    clr a                ; Add 1 Byte as Space
    sbrc temp,7
    com a
    rcall lcd_byte
    in pdat,PORTB            ; Disable Chip Select
    sbr pdat,PINB_CS
    out PORTB,pdat
lcd_char_exit:
    pop zh
    pop zl
    pop oh
    pop ol
    pop pdat
    pop b
    pop a
    pop temp
    ret
; ### Send 2-Byte Command
; >a: The Command
; >b: The Data
lcd_cmd2:
    push temp
    push a
    push b
    push pdat
    in pdat,PORTB            ; Enable Chip Select
    cbr pdat,PINB_CS
    out PORTB,pdat
    mov temp,b              ; Send Command
    rcall lcd_byte
    mov a,temp              ; Send Data
    rcall lcd_byte
    in pdat,PORTB            ; Disable Chip Select
    sbr pdat,PINB_CS
    out PORTB,pdat
    pop pdat
    pop b
    pop a
    pop temp
    ret
; ### Send Single Command Byte
; >a: The Command
lcd_cmd:
    push b
    push pdat
    in pdat,PORTB            ; Enable Chip Select
    cbr pdat,PINB_CS
    out PORTB,pdat
    clr b                ; Send Byte
    rcall lcd_byte
    in pdat,PORTB            ; Disable Chip Select
    sbr pdat,PINB_CS
    out PORTB,pdat
    pop pdat
    pop b
    ret
; ### Shift Byte
; >a: The Byte
; >b: The DC Flag
lcd_byte:
    push a
    push b
    push pdat
    in pdat,PORTB            ; Set DC Pin
    cbr pdat,PINB_DC
    cpse b,zero
    sbr pdat,PINB_DC
    out PORTB,pdat    
lcd_byte_shift:                ; Bit-Banging Input Byte (MSB first)
lcd_byte_shift_loop:
    cbr pdat,PINB_SDA
    lsl a
    brcc lcd_byte_shift_cnt
    sbr pdat,PINB_SDA
lcd_byte_shift_cnt:
    out PORTB,pdat    
    sbr pdat,PINB_SCK
    out PORTB,pdat    
    cbr pdat,PINB_SCK
    out PORTB,pdat    
    dec b
    brne lcd_byte_shift_loop
    pop pdat
    pop b
    pop a
    ret
; *****************************************************************************
; *****************************************************************************
; ### Inits LED
led_init:
    push a
    in a,DDRD              ; Set LED Pins to Output
    sbr a,PIND_LED
    out DDRD,a
    ser a                ; Flash LED
    rcall led_set            
    ldi a,250
    rcall util_delay_Xms
    clr a
    rcall led_set            
    ldi a,250
    rcall util_delay_Xms
    pop a
    ret
; ### Switch LED
; >a: The enabled flag
led_set:
    push pdat
    in pdat,PORTD
    cbr pdat,PIND_LED
    cpse a,zero
    sbr pdat,PIND_LED
    out PORTD,pdat
    pop pdat
    ret
; *****************************************************************************
; *** Core Utility                                                          ***
; *****************************************************************************
; ### Delay 10us
.equ CLK10US = ((FC/100000)-12)/3      ; Constant for 10us including RCALL
util_delay_10us:
    push a                ; 1 x push = 2 clocks
    ldi a,CLK10US            ; 1 x load = 1 clock
util_delay_10us_loop:            
    dec a                ; N * 3 clocks
    brne util_delay_10us_loop
    pop a                ; 1 x pop + ret = 6 clocks
    ret
; ### Delay 1ms
.equ CLK1MS = ((FC/1000)-17)/4        ; Constant for 1ms including RCALL
util_delay_1ms: 
    push ol                ; 2 x push = 4 clocks
    ldi oh,HIGH(CLK1MS)          ; 2 x load = 2 clocks
    ldi ol,LOW(CLK1MS)
util_delay_1ms_loop:
    sbiw ol,1              ; N * 4 clocks
    brne util_delay_1ms_loop 
    pop oh                ; 2 x pop + ret = 8 clocks 
    pop ol
    ret
; ### Delay X*0-255 ms
; (tolerance by additional 2+X*(0+1+2)+2+4
; >a: value of ms
util_delay_Xms:
    push a
util_delay_Xms_loop:            ; Delays X times for one millisecond
    rcall util_delay_1ms        ; Cycles for RCALL are already included in calculation here
    dec a
    brne util_delay_Xms_loop
    pop a
    ret
Kontakt/Impressum – Datenschutzerklärung – Nutzungsbedingungen – Werbung auf Mikrocontroller.net