7Ksend01.asm

;Encoder für 7-Kanal Fernsteuersender zum Betrieb bzw. zum Test von Komponenten.

;Es stehen 6 Analogeingänge für Steuerknüppel zur Verfügung (K1...K6),

;sowie 2 Digitaleingänge für Taster oder einen Schalter für drei Stellungen (K7).

;Auf Trimmung und Impulsumkehr wurde bei dieser "Erstlingsversion" bewusst verzichtet.

;Portbelegung des AT90S4433:

;Eingänge:

;PC5: Steuerknüppel Kanal 1

;PC4: Steuerknüppel Kanal 2

;PC3: Steuerknüppel Kanal 3

;PC2: Steuerknüppel Kanal 4

;PC1: Steuerknüppel Kanal 5

;PC0: Steuerknüppel Kanal 6

;PB5: Schalter (gegen GND) impulsverkürzend Kanal 7

;PB4: Schalter (gegen GND) impulsverlängernd Kanal 7

;Ausgänge:

;PD0: Sendertastimpuls (H-aktiv)

;PD1: Kanalimpuls 1 (H-aktiv)

;PD2: Kanalimpuls 2 (H-aktiv)

;PD3: Kanalimpuls 3 (H-aktiv)

;PD4: Kanalimpuls 4 (H-aktiv)

;PD5: Kanalimpuls 5 (H-aktiv)

;PD6: Kanalimpuls 6 (H-aktiv)

;PD7: Kanalimpuls 7 (H-aktiv)

;PB0...PB3 sind vorerst unbenutzt...

.equ quarz=8000000  ;Quarzfrequenz 8MHz

.equ bi=150-64    ;Basisimpuls in 0,01ms

.equ schalt=30    ;Schaltimpulsdifferenz zu 1,5ms Impulsmitte

.def tsw=r1      ;Timer-Startwert für Zeitnormal

.def ib=r2      ;Impulsbreite Sendertastung

.def awh=r3      ;Analogwert H vom Steuerknüppel

.def pzl=r4      ;Pausenzähler L

.def pzh=r5      ;Pausenzähler H

.def pzsl=r6    ;Startwert Pausenzähler L

.def pzsh=r7    ;Startwert Pausenzähler H

.def srs=r8      ;Status-Register-Sicherungskopie

.def u1=r16      ;Universal 1

.def u2=r17      ;Universal 2

.def zz=r18      ;Zähler Zeitnormal

.def iq=r19      ;Input-Quelle (Analog-MUX)

.def awl=r20    ;Analogwert L vom Steuerknüppel

.def ia=r21      ;Impulsabstand (Kanalimpulsbreite)

.include"4433def.inc"

.cseg

.org 0        ;Reset und INT-Vektoren

 rjmp reset      ;Programm-Initialisierung

 reti        ;IRQ0

 reti        ;IRQ1

 reti        ;Timer1 Capture

 reti        ;Timer1 Compare

 reti        ;Timer1 ovf

 rjmp takt          ;Timer0-ovf

 reti        ;Serial Transfer complete

 reti        ;UART RX

 reti        ;UART UDRE

 reti        ;UART TX

 reti        ;ADC-Conversion complete

 reti        ;EEPROM-Writing complete

 reti        ;Analog-Comparator

reset:

 ldi u1,low(ramend)  ;Stackpointer

 out spl,u1      ;einrichten

 ldi u1,0      ;

 out portd,u1    ;Impulsausgänge auf L-Pegel

 out ddrd,u1    ;Eingänge Port D (Analog)

 out ddrb,u1    ;Eingänge Port B

 ldi u1,255      ;Ausgänge

 out ddrd,u1    ;Port D (Impulsausgänge)

 out portb,u1    ;Pull-Ups für Taster einschalten

 ldi u1,50      ;Impulsbreite für

 mov ib,u1      ;Sendertastung setzen

 ldi u1,248      ;Startwert

 mov pzsh,u1    ;Pause H setzen

 ldi u1,48      ;Startwert

 mov pzsl,u1    ;Pause L setzen

 ldi iq,5      ;ADC5 als Kanal 1

 out admux,iq    ;wählen

 ldi u1,0b11100110  ;ADC freilaufend mit Takt 1:64

 out adcsr,u1    ;initialisieren

 ldi u1,256-80+8  ;Startwert

 mov tsw,u1      ;für Timer0 definieren

 out tcnt0,tsw    ;und setzen (80 Takte bis Überlauf)

 ldi u1,1      ;Timer auf

 out tccr0,u1    ;Prozessortakt

 ldi u1,2      ;Timer-Interrupt

 out timsk,u1    ;einschalten

 sei        ;Interrupts aktivieren

 clr pzl      ;Startbedingung

 clr pzh      ;schaffen

warte:    ;Hauptschleife...

 tst pzl      ;Pausenzähler L auf 0?

 brne warte      ;nein...

 tst pzh      ;Pausenzähler H auf 0?

 brne warte      ;nein...

 ldi iq,5      ;Kanal 1 einschalten

 out admux,iq    ;Analogkanal wählen

 ldi ia,bi      ;Basisimpulsbreite setzen

 ldi u1,3      ;Sendertastimpuls und

 out portd,u1    ;Kanalimpuls 1 einschalten

 clr zz        ;Zeitzähler löschen

 mov pzl,pzsl    ;Pausenzähler

 mov pzh,pzsh    ;neu setzen

 rjmp warte

takt00:

 out sreg,srs    ;Statusregister wiederherstellen

 reti        ;fertig

takt:    ;ISR Zeitnormal (10 Mikrosekunden)

 in srs,sreg    ;Statusregister sichern

 out tcnt0,tsw    ;Timer-Startwert setzen

 inc pzl      ;Pausenzähler

 brne takt1      ;Übertrag? nein...

 inc pzh      ;ja

takt1:

 inc zz        ;Zeit-Zähler erhöhen

 breq takt00    ;0 nicht auswerten...

 cp zz,ib      ;Impulsbreite Sendertastung?

 brne takt3      ;nein...

 cbi portd,0    ;ja, Sendeimpuls abschalten

 tst ia        ;Kanalimpulsdauer berechnen und zuweisen?

 breq takt00    ;nein, Sync-Pause...

 cpi iq,255      ;ja, digitale Signalquelle? (Kanal 7)

 breq takt2      ;ja...

 in awl,adcl    ;Analogwert

 in awh,adch    ;lesen

 ror awh      ;10-Bit-Wert

 ror awl      ;durch 8 teilen

 ror awh      ;

 ror awl      ;(ergibt 7-Bit-Wert

 ror awh      ;in awl)

 ror awl      ;(0...127)

 cpi awl,14      ;Wert kleiner als Mitte-50?

 brpl takt1a    ;nein...

 ldi awl,14      ;ja, korregieren

takt1a:

 cpi awl,114    ;Wert größer als Mitte+50?

 brmi takt1b    ;nein...

 ldi awl,114    ;ja, korregieren

takt1b:

 add ia,awl      ;Wert zum Basisimpuls addieren

 out sreg,srs    ;Statusregister wiederherstellen

 reti        ;fertig

takt2:    ;Schalteingang für Kanal7

 ldi awl,64      ;Mittelwert als Voreinstellung

 sbis pinb,5    ;Taste1?

 ldi awl,64-schalt  ;ja, kürzerer Impuls

 sbis pinb,4    ;Taste2?

 ldi awl,64+schalt  ;ja, längerer Impuls

 add ia,awl      ;Wert zum Basisimpuls addieren

 out sreg,srs    ;Statusregister wiederherstellen

 reti        ;fertig

takt3:

 cp zz,ia      ;Kanalimpulsbreite erreicht?

 brne takt00    ;nein...

 clr zz        ;ja, Zeitzähler löschen

 ldi u2,1      ;Sendertastimpuls ein,

 out portd,u2    ;Kanalimpulse erstmal alle aus

 ldi ia,0      ;Leerwert für Impulsabstand (Pause)

 dec iq        ;nächster Analogkanal

 cpi iq,5      ;Kanal 1?

 brne takt3a    ;nein...

 sbi portd,1    ;ja, Impuls 1 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

 out admux,iq    ;Analogkanal wählen

takt3a:

 cpi iq,4      ;Kanal 2?

 brne takt3b    ;nein...

 sbi portd,2    ;ja, Impuls 2 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

 out admux,iq    ;Analogkanal wählen

takt3b:

 cpi iq,3      ;Kanal 3?

 brne takt3c    ;nein...

 sbi portd,3    ;ja, Impuls 3 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

 out admux,iq    ;Analogkanal wählen

takt3c:

 cpi iq,2      ;Kanal 4?

 brne takt3d    ;nein...

 sbi portd,4    ;ja, Impuls 4 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

 out admux,iq    ;Analogkanal wählen

takt3d:

 cpi iq,1      ;Kanal 5?

 brne takt3e    ;nein...

 sbi portd,5    ;ja, Impuls 5 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

 out admux,iq    ;Analogkanal wählen

takt3e:

 cpi iq,0      ;Kanal 6?

 brne takt3f    ;nein...

 sbi portd,6    ;ja, Impuls 6 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

 out admux,iq    ;Analogkanal wählen

takt3f:

 cpi iq,255      ;Kanal 7?

 brne takt0      ;nein...

 sbi portd,7    ;ja, Impuls 7 einschalten

 ldi ia,bi      ;Impulsabstand (= Kanalimpulsbreite) erstmal auf Minimum setzen

takt0:

 out sreg,srs    ;Statusregister wiederherstellen

 reti        ;fertig