lampe.asm

.include "tn12def.inc"

.equ  initialgotospeed=$40

.equ  normalgotospeed  =$10

.equ  fastgotospeed  =$08

.equ  veryfastgotospeed  =$04

.equ  dotspeed  =$20

.equ  dashspeed  =$e0

.equ  pausespeed  =dotspeed

.equ  outputpin  =4

.equ  lobatpin  =3

.equ  buttonpin  =0

.equ  maxtastverh  =100

.equ  maxpower  =100

.equ  highpower  =84  ; dim to 70% light - i.e. 84% power

.equ  medpower  =63  ; dim to 40% light - i.e. 63% power

.equ  lowpower  =31  ; dim to 10% light - i.e. 31% power

.equ  lowbatpower  =15  ; when at lobat dim to minimal power

        ; consumption, but enough for reading

        ; instruments.

.equ  nopower    =0  ; lamp off

.def  gotospeed=r18

.def  lobat  =r19

.def  gdelay  =r20

.def  gdelay2  =r21

.def  gdelay3  =r23

.def  newtastverh=r24

.def  tastmax =r25

.def  tastverh=r26

.def  ison  =r27

.def  portbsh  =r28

.def  temp  =r29

.def  itemp  =r30

.ORG $000

  rjmp RESET

.ORG $001

  rjmp EXT_INT0

.ORG $002

  rjmp PIN_CHANGE

.ORG $003

  rjmp TIM0_OVP

.ORG $005

  rjmp ANA_CMP

shortdelaysub:

  clr     gdelay

sdm2:  DEC  gdelay

  BRNE    sdm2

sdm3:  DEC gdelay

  BRNE  sdm3

sdm4:  DEC gdelay

  BRNE  sdm4

  ret

;

; A simple macro for generating a short delay. 

; This is used for blinking SOS

;

.macro  shortdelay

.if 1 = 0

  clr  gdelay

sdm2:  DEC gdelay

  BRNE  sdm2

sdm3:  DEC gdelay

  BRNE  sdm3

sdm4:  DEC gdelay

  BRNE  sdm4

.else

  RCALL shortdelaysub

.endif

.endmacro

;

; Delay for as long as a "dot" symbol should be on.

;

.macro  dotdelay

  ldi     gdelay2,dotspeed

dd2:  shortdelay

  dec  gdelay2

  brne  dd2

.endmacro

;

; Delay for as long as a "dash" symbol should be on.

;

.macro  dashdelay

  ldi     gdelay2,dashspeed

dad2:  shortdelay

  dec  gdelay2

  brne  dad2

.endmacro

;

; Delay for as long as a pause between symbols should be.

;

.macro  pausedelay

  ldi     gdelay2,pausespeed

pd2:  shortdelay

  dec  gdelay2

  brne  pd2

.endmacro

;

; Send a dot with the inter-symbol pause trailing

;

.macro saydot

  ldi newtastverh,maxpower

  rcall soft_goto

  dotdelay

  ldi newtastverh,nopower

  rcall soft_goto

  pausedelay

.endmacro

;

; Send a dash with the inter-symbol pause trailing

;

.macro saydash

  ldi newtastverh,maxpower

  rcall soft_goto

  dashdelay

  ldi newtastverh,nopower

  rcall soft_goto

  pausedelay

.endmacro

;

; Delay for a inter-character pause - minus the already done inter-symbol pause

;

.macro newchardelay

  pausedelay

.endmacro

;

; Send an s, including trailing inter-char pause

;

.macro says

  saydot

  saydot

  saydot

  newchardelay

.endmacro

;

; Send an o, including trailing inter-char pause

;

.macro sayo

  saydash

  saydash

  saydash

  newchardelay

.endmacro

;

; Send an a, including trailing inter-char pause

;

.macro saya

  saydot

  saydash

  newchardelay

.endmacro

;

; Send an e, including trailing inter-char pause

;

.macro saye

  saydot

  newchardelay

.endmacro

TIM0_OVP:

  cpi ison,$00

  breq IS_OFF

  ldi ison,$00

  ldi itemp,$00

  SUB itemp,tastverh

  breq justret

  out TCNT0,itemp

  sbi PORTB,outputpin

justret:

  reti

IS_OFF:

  ldi ison,$ff

  ldi itemp,$00

  sub itemp,tastmax

  add itemp,tastverh

  breq justret

  cbi PORTB,outputpin

  out TCNT0,itemp

  reti

EXT_INT0:

  reti

PIN_CHANGE:

  reti

;

; The analog comparator triggered. This means we have a lobat condition

; 

ANA_CMP:

  SBIC ACSR,5

  rjmp on_lobat

have_enough:

  cbi PORTB,lobatpin

  reti

on_lobat:

  ser lobat

  sbi PORTB,lobatpin

  reti

set_lobat:

  ser lobat

  sbi PORTB,lobatpin

  ret

reset_lobat:

  clr lobat

  cbi PORTB,lobatpin

  ret

soft_goto:

  cp tastverh,newtastverh

  breq sg_doret

  brlo goto_less

  dec tastverh

  rjmp redo_goto

sg_doret:

  ret

goto_less:

  inc tastverh

redo_goto:

  mov  gdelay2,gotospeed

rg2:  clr     gdelay

rg1:  dec  gdelay

  brne  rg1

  dec  gdelay2

  brne  rg2

  rjmp soft_goto

;

; Wait for key. A looong keypress (about 6 seconds) enters SOS-Mode

;

.macro sostimingdelay

  ldi gdelay3,$15

down:

  dec gdelay3

  brne down

.endmacro

waitforkey:

  CLR gdelay2

  CLR gdelay

wfk_loop:

  sostimingdelay

  dec gdelay

  BRNE skipdec2

  dec gdelay2

  BREQ have_sos    ; YEAH - we really jump into something

        ; that doesn't return. SOS-Mode can only

        ; be left by a RESET.

skipdec2:

  SBRC lobat,0    ; lobat clear?

  ret      ; if lobat is set, break out

  SBIS PINB,buttonpin  ; if Button is not pressed, skip to waitforkey2

  rjmp wfk_loop    ; if Button is pressed, keep looping

waitforkey2:

  SBRC lobat,0    ; lobat clear?

  ret      ; if lobat is set, break out

  SBIC PINB,buttonpin  ; if Button is pressed, ret

  rjmp waitforkey2  ; if Button is not pressed, keep looping

  ret  

waitforkey_nolobatbreak:

  CLR gdelay2

  CLR gdelay

wfk_loop_nlbb:

  sostimingdelay

  dec gdelay

  BRNE skipdec3

  dec gdelay2

  BREQ have_sos    ; YEAH - we really jump into something

        ; that doesn't return. SOS-Mode can only

        ; be left by a RESET.

skipdec3:

  SBIS PINB,buttonpin  ; if Button is not pressed, skip to waitforkey2

  rjmp wfk_loop_nlbb  ; if Button is pressed, keep looping

waitforkey_nlbb2:

  SBIC PINB,buttonpin  ; if Button is pressed, ret

  rjmp waitforkey_nlbb2  ; if Button is not pressed, keep looping

  ret  

;

; Blink SOS

;

; In this mode we don't give a f*** about the battery life

;

have_sos:

  ldi gotospeed,veryfastgotospeed

  says      ; Blink ... --- ...

  sayo

  says

  ldi temp,65    ; Wait about 10 seconds

sos_delay:

  pausedelay

  dec temp

  brne sos_delay

  rjmp have_sos

; *************************************************************************

; Main program starts here

; *************************************************************************

RESET:

;

; Initialize Variables

;

  CLR ison

  ldi tastverh,nopower

  LDI tastmax,maxtastverh

;

; Setup the Output pins

;

  LDI temp,(1<<outputpin)|(1<<lobatpin)

  OUT DDRB,temp

  ; activate pullup resistor on the

  ; pin the button is connected to

  LDI temp,(1<<buttonpin)  

  OUT PORTB,temp

;

; Set up the timer/counter.

; ATTiny12 has an internal 1.2MHz clock.

; That makes for 18750Hz at CK/64.

; Using an 8 Bit counter, we can thus reach Frequencies between

; 73Hz and 18kHz for driving the lamp.

; For ease of calculation I chose 187Hz (tastmax=100).

;

  LDI temp,$03  ;  CK/64

  OUT TCCR0,temp

;

; Enable timer interrupt.

;

  LDI temp,$02

  OUT TIMSK,temp

  SEI

;

; Now enable the analog comparator stuff. 

;

  LDI temp,$48  ; $40=enable bandgap $08=Interrupt enable 

      ; $00=int on toggle.

  OUT ACSR,temp

; The manual says not to do this, as it can cause interrupts while bits

; are being shuffled.

; As we are only setting a flag in the interrupt, which gets cleared after

; startup anyway - we don't care.

softstart:

;

; Do a soft start of the lamp. Then reset the lobat entry.

; This is done at startup in order to reset any pending lobat 

; interrupts.

; We check the button condition.

; If the lamp comes up with the button active, either the button is 

; stuck, or the user is requesting "emergency full power".

; As a safe default, we keep the lamp at 100% if that happens.

;

  ldi gotospeed,initialgotospeed

  ldi newtastverh,lowpower

  rcall soft_goto;

  ldi gotospeed,normalgotospeed

  ldi newtastverh,maxpower

  rcall soft_goto;

  rcall reset_lobat

  SBIS PINB,buttonpin  ; if Button is not pressed, skip emergency mode

  rjmp emergency_full

;

; If we started up in alobat situation and are not in emergency mode,

; jump directly to lobat.

;

  SBIC ACSR,5    ; Is the AC output clear? Then all is well.

  rjmp have_lobat    ; otherwise indicate lobat.

  rjmp ss2

;

; usually we come back here. The lamp starts up soft as well,

; but we assume lobat has been cleared before.

; Notice, that detecting lobat is an edge-triggered action.

; So if we are on lobat here, and lobat flag has been cleared,

; we are toast.

;

;

; While in normal operating mode, we wait for button press. 

; the button press fuction will also return, if a lobat condition

; is detected. This macro will jump to "have_lobat", if lobat

; condition is active.

;

.macro testandjumplobat

  tst  lobat

  brne  have_lobat

.endmacro

.macro waitforkey_and_lobat

  rcall waitforkey

  testandjumplobat

.endmacro

softstart2:

  ldi newtastverh,maxpower

  rcall soft_goto;

ss2:

  waitforkey_and_lobat

; dim to high power setting

  ldi newtastverh,highpower

  rcall soft_goto;

  waitforkey_and_lobat

; dim to medium power setting

  ldi newtastverh,medpower

  rcall soft_goto

  waitforkey_and_lobat

lopower:

; dim to low power setting

  ldi newtastverh,lowpower

  rcall soft_goto

  waitforkey_and_lobat

; dim to medium power setting

  ldi newtastverh,medpower

  rcall soft_goto;

  waitforkey_and_lobat

; dim to high power setting

  ldi newtastverh,highpower

  rcall soft_goto;

  waitforkey_and_lobat

; jump to start - brings us back to 100%

  rjmp softstart2

;

; We have a lobat condition. 

; First notify the user by morsing A A A (like Attention Accu Alert)

; then dim the light to 20% Power, which probably gives about 4% Light.

;

have_lobat:

  rcall set_lobat  ; reset the lobat condition.

  ldi newtastverh,lowbatpower

  rcall soft_goto    ; bring us to minimum light.

  ldi gotospeed,fastgotospeed

  saya

  ldi gotospeed,normalgotospeed

  ldi newtastverh,lowbatpower

  rcall soft_goto    ; bring us to minimum light.

  rcall waitforkey_nolobatbreak

        ; if the user presses a button, he wants

        ; more light.

  rcall reset_lobat  ; reset the lobat condition.

  SBIC ACSR,5    ; Is the AC output clear? In that case we 

        ; might have enough power for a higher

        ; setting.

  rjmp have_lobat    ; otherwise indicate lobat.

  rjmp lopower    ; give him lopower first.

emergency_full:

  ldi newtastverh,nopower

  rcall soft_goto    ; bring us to minimum light.

  ldi newtastverh,maxpower

  rcall soft_goto    ; bring us to minimum light.

forever:

  rjmp forever