Mikrocontroller und Digitale Elektronik
›
Thread
ATTiny2313 Externes Interrupt an INT1
J
jretise
Gast
15.05.2011 16:14
#2184665
Hallo,
folgendes Programm für einen TIny2313 soll eigentlich einen Pegelwechsel
an INT1 erkennen und dann den aktuellen Wert der Zählerregister von
Timer1 an den PC senden. (Erst dass Low- dann das Highbyte)
PB0 und PB7 sind nur auf Low, bzw High für einen Taster zum Testen, der
an INT1 angeschlossen ist.
Anscheinend wird das Interrupt aber nie ausgelöst und ich kann meinen
Fehler nicht finden. Das Senden funktioniert prinzipiell, das habe ich
schon in der loop ausprobiert.
Danke fürs Lesen und ich hoffe der Thread ist hier richtig aufgehoben.
1 .include "/defs/tn2313def.inc"
2
3 ;---------defs
4
5 .def tmp = r16 ;tmpregister
6 .def sendl = r17 ;senderegisterlow
7 .def sendh = r18 ;senderegisterhigh
8
9 .equ F_CPU = 12000000 ; Systemtakt in Hz
10 .equ BAUD = 9600 ; Baudrate
11
12 ; UART Berechnungen
13 .equ UBRR_VAL = ((F_CPU+BAUD*8)/(BAUD*16)-1)
14 .equ BAUD_REAL = (F_CPU/(16*(UBRR_VAL+1)))
15 .equ BAUD_ERROR = ((BAUD_REAL*1000)/BAUD-1000)
16
17 .if ((BAUD_ERROR>10) || (BAUD_ERROR<-10))
18 .error "Baurate zu hoch"
19 .endif
20
21 ;--------interrupts
22
23 .CSEG
24 .org 0x00 ;Resetinterrupt
25 rjmp main
26 .org 0x02 ;Signal an INT1
27 rjmp input
28
29 ;------mainroutine
30 main:
31 ;Stackpointer:
32 ldi tmp, RAMEND
33 out SPL, tmp
34 ;-------------
35 ;Z-Pointer
36 ;ldi ZL, SRAM_START
37 ;ldi ZH, 0
38 ;---------------
39 ;Timer 1 mit cputakt / 64
40 ldi tmp, (1<<CS10)|(1<<CS11)
41 out TCCR1B, tmp
42 ;---------------
43 ;Interrupt für INT1
44 ldi tmp, (1<< ISC11) ;Interrupt bei jedem Wechsel
45 out MCUCR, tmp
46 ldi tmp, (1<< INT1) ;Interrupt aktivieren
47 out GIMSK, tmp
48 ;--------------------
49 ;Uart init
50 ldi tmp, high(UBRR_VAL)
51 out UBRRH, tmp
52 ldi tmp, low(UBRR_VAL)
53 out UBRRL, tmp
54 ;siehe datasheet seite 129 // 8 Bit no parity
55 ldi tmp, (1<<UCSZ0)|(1<<UCSZ1)
56 out UCSRC, tmp
57 sbi UCSRB,TXEN
58 ;Taster aktivieren (PB0 auf high, PB7 auf low
59 ldi tmp, (1<<PB0)|(1<<PB7)
60 out DDRB, tmp
61 sbi PORTB, PB0
62 cbi PORTB, PB7
63 ;Interrupts aktivieren
64 sei
65 ;-------Mainloop
66 rcall loop
67 loop:
68 rjmp loop
69
70 input:
71 ldi sendl, TCNT1L
72 ldi sendh, TCNT1H
73 rcall sendlow
74 rcall sendhigh
75 reti
76
77 sendlow:
78 sbis UCSRA,UDRE ;Auf Uart warten
79 rjmp sendlow
80 out UDR, sendl
81 ret
82
83 sendhigh:
84 sbis UCSRA,UDRE ;Auf Uart warten
85 rjmp sendhigh
86 out UDR, sendh
87 ret
88
89 ;-------EEPROM
S
spess53
Gast
15.05.2011 17:13
#2184743
Hi
>input:
> ldi sendl, TCNT1L
> ldi sendh, TCNT1H
Die Adressen der Register kannst du auch im Datenblatt nachlesen.
Versuche es mal mit 'in'.
MfG Spess
J
jretise
Gast
15.05.2011 17:33
#2184762
Jetzt funktionierts, vielen Dank!
An Assembler muss man sich auch wirklich erstmal gewöhnen ;)
↑ Nach oben
← Zurück zu Mikrocontroller und Digitale Elektronik
Antwort schreiben
Eine eigene Frage?
Dieser Thread ist über 15 Jahre alt.
Stell sie in einem eigenen Thread – dort lesen mehr Leute mit, und sie wird öfter und schneller beantwortet.
Neuen Thread starten
Eine Lösung, Ergänzung oder Rückmeldung zu diesem Thread? Dann antworte hier.