MQTT mit thingg.io auf ESP8266

#include <ESP8266WiFi.h>

#include <PubSubClient.h>

// Pins Config

const int LightPin = D0;

const int PhotoPin = A0;

const int DefaultPin = D4;

// Wifi Config

const char* ssid = "SSID";

const char* password = "PASSWORD";

// MQTT Config

const char* mqtt_server = "mqtt.tingg.io";

const int port = 1883; // 8883 for mqtts connections.

// Thing Config

const char* thing_id = "###";

const char* thing_key = "###";

// Topics Config

const char* pubTopic = "<pub_resource>";

const char* subTopic = "<sub_resource>";

// Default Config

const char* username = "thing";

WiFiClient espClient;

PubSubClient client(espClient);

// Vars

int val;

int prevVal = 0;

char buf[12];

long lastUpdateMillis = 0;

// Function to validate connection with the board

void blinking_loop(){

  while (ssid == "SSID") {

    digitalWrite(DefaultPin,HIGH);

    delay(500);

    digitalWrite(DefaultPin,LOW);

    delay(500);

    Serial.println("Default light should be blinking. Please set up your Wifi configuration.");

  }

}

void setup_wifi() {

  delay(10);

  Serial.print("Connecting to ");

  Serial.println(ssid);

  WiFi.mode(WIFI_STA);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  randomSeed(micros());

  Serial.println("");

  Serial.print("Congratulations!! WiFi connected on IP address: ");

  Serial.println(WiFi.localIP());

  Serial.println("");

  Serial.println("Now, follow up on the steps for the MQTT configuration. ");

}

void reconnect() {

  while (!client.connected()) {

    Serial.print("Attempting to connect MQTT...");

    if (client.connect(thing_id, username, thing_key)) {

      Serial.println("connected");

      client.subscribe(subTopic);

    } else {

      Serial.print(" Still not connected...");      // Serial.print(client.state());

      Serial.println(" trying again in 5 seconds"); // Wait 5 seconds before retrying

      delay(5000);

    }

  }

}

String message(byte* payload, unsigned int length) {

  payload[length] = '\0';

  String s = String((char*)payload);

  return s;

}

void callback(char* topic, byte* payload, unsigned int length) {

  Serial.println(topic);

  String msg = message(payload, length);

  if ((msg == "ON") || (msg == "on") || (msg == "1")) {

    Serial.println("Light turned On");

    digitalWrite(LightPin,HIGH);

  }

  else if ((msg == "OFF") || (msg == "off") || (msg == "0")) {

    Serial.println("Light turned Off");

    digitalWrite(LightPin,LOW);

  }

  else {

    Serial.println("Unknown command. Please try: ON, on, 1, OFF, off or 0.");

  }

}

void setup() {

  pinMode(LightPin,OUTPUT);

  pinMode(PhotoPin,INPUT);

  pinMode(DefaultPin,OUTPUT);

  Serial.begin(115200);

  blinking_loop();

  setup_wifi();

  client.setServer(mqtt_server, port);

  client.setCallback(callback);

}

void loop() {

  if (!client.connected()) {

    reconnect();

  }

  client.loop();

  val = analogRead(PhotoPin);

  if (prevVal != val || millis() - lastUpdateMillis > 3000) {

    lastUpdateMillis = millis();

    prevVal = val;

    client.publish(pubTopic,itoa(val, buf, 10));

    Serial.print("Updating value to ");

    Serial.println(val);

    delay(250);

  }

  delay(50);

}