UART Mac wie?

#include <avr/io.h> 

#define USART_BAUDRATE 9600 

#define BAUD_PRESCALE (((F_CPU / (USART_BAUDRATE * 16UL))) - 1) 

int main (void) 

{ 

   char ReceivedByte; 

   UCSRB |= (1 << RXEN) | (1 << TXEN);   // Turn on the transmission and reception circuitry 

   UCSRC |= (1 << URSEL) | (1 << UCSZ0) | (1 << UCSZ1); // Use 8-bit character sizes 

   UBRRL = BAUD_PRESCALE; // Load lower 8-bits of the baud rate value into the low byte of the UBRR register 

   UBRRH = (BAUD_PRESCALE >> 8); // Load upper 8-bits of the baud rate value into the high byte of the UBRR register 

   for (;;) // Loop forever 

   { 

      while ((UCSRA & (1 << RXC)) == 0) {}; // Do nothing until data have been recieved and is ready to be read from UDR 

      ReceivedByte = UDR; // Fetch the recieved byte value into the variable "ByteReceived" 

      while ((UCSRA & (1 << UDRE)) == 0) {}; // Do nothing until UDR is ready for more data to be written to it 

      UDR = ReceivedByte; // Echo back the received byte back to the computer 

   }    

}

.include "m8def.inc"

.def temp = R16

.equ F_CPU = 12000000                            ; Systemtakt in Hz

.equ BAUD  = 9600                               ; Baudrate

; Berechnungen

.equ UBRR_VAL   = ((F_CPU+BAUD*8)/(BAUD*16)-1)  ; clever runden

.equ BAUD_REAL  = (F_CPU/(16*(UBRR_VAL+1)))     ; Reale Baudrate

.equ BAUD_ERROR = ((BAUD_REAL*1000)/BAUD-1000)  ; Fehler in Promille

.if ((BAUD_ERROR>10) || (BAUD_ERROR<-10))       ; max. +/-10 Promille Fehler

  .error "Systematischer Fehler der Baudrate grösser 1 Prozent und damit zu hoch!"

.endif

.org 0x00

        rjmp main

.org URXCaddr

        rjmp int_rxc

; Hauptprogramm

main:

    ; Stackpointer initialisieren

    ldi     temp, LOW(RAMEND)

    out     SPL, temp

    ldi     temp, HIGH(RAMEND)

    out     SPH, temp

    ; Port B = Ausgang

    ldi     temp, 0xFF

    out     DDRB, temp

    ; Baudrate einstellen

    ldi     temp, HIGH(UBRR_VAL)

    out     UBRRH, temp

    ldi     temp, LOW(UBRR_VAL)

    out     UBRRL, temp

    ; Frame-Format: 8 Bit

    ldi     temp, (1<<URSEL)|(3<<UCSZ0)

    out     UCSRC, temp

    sbi     UCSRB, RXCIE                ; Interrupt bei Empfang

    sbi     UCSRB, RXEN                 ; RX (Empfang) aktivieren

    sei                                 ; Interrupts global aktivieren

loop:

    rjmp loop                           ; Endlosschleife

; Interruptroutine: wird ausgeführt sobald ein Byte über das UART empfangen wurde

int_rxc:

    push    temp                        ; temp auf dem Stack sichern

    in      temp, sreg                  ; SREG sichern

    push    temp

    in      temp, UDR                   ; UART Daten lesen

    cpi     temp, '1'                   ; empfangenes Byte mit '1' vergleichen

    brne    int_rxc_1                   ; wenn nicht gleich, dann zu int_rxc_1

    cbi     PORTB, 0                    ; LED einschalten, low aktiv

    rjmp    int_rxc_2                   ; Zu int_rxc_2 springen

int_rxc_1:

    cpi     temp, '0'                   ; empfangenes Byte mit '0' vergleichen

    brne    int_rxc_2                   ; wenn nicht gleich, dann zu int_rxc_2

    sbi     PORTB, 0                    ; LED ausschalten, low aktiv

int_rxc_2:

    pop     temp

    out     sreg, temp                  ; SREG wiederherstellen

    pop     temp                        ; temp wiederherstellen

    reti