Freuquenzteiler in Xilinx

[Jonas (Gast)]

hallo Leute...

Hab jetzt die Aufgabe, einen Frequenzteiler in VHDL zu Programmieren.

Mein Eingangssignal kommt vom Altium Live Design Evaluation Board 
(Spartan 3) und nennt sich CLK_BRD.

Kann mir jemand helfen?
Bräuchte einen 50MHz Takt, den kann ich ja direkt vom Board übernehmen, 
da dieser ja nen Quarz mit 50MHz hat.
Dann brauch ich noch einen takt mit 500kHz und einen mit 50Hz.
Wäre für Lösungen sehr sehr dankbar, da ich selber leider noch keinen 
wirklichen Plan hab, wie ich das ganze angehen soll.

Danke!!!
Jonas

[Jonas (Gast)]

achja, ich brauch die takte dann als Ausgangsports, da wir ne 
gruppenarbeit haben, und andere damit weiterarbeiten....

[Klaus F. (kfalser)]

> da ich selber leider noch keinen wirklichen Plan hab,
> wie ich das ganze angehen soll.

Wie wäre es z.B mit googlen : Frequenzteiler und VHDL ?

[Jonas (Gast)]

hab ich schon, wurde dann aber in ein uraltes forum (2005) 
weitergeleitet, und da kam ich auch nicht weiter.....leider....

[Niklas G. (erlkoenig)]

Das ist eine Standardaufgabe. Du brauchst einen Zähler bzw. Timer; der 
zählt bei jedem 50MHz-Takt um eins rauf, und immer, wenn er bei 50 
angekommen ist, schaltest du den 500kHz-Ausgang auf high, und wenn er 
bei 100 ankommt schaltest du ihn wieder auf low, und resettest den 
Zähler auf 0. Für 50 Hz machst du das gleiche, nur mit 500 und 1000.

[Jonas (Gast)]

ok, das hört sich plausibel an...danke schonmal.....ich halt euch auf 
dem laufenden, wenn es probleme gibt! :)

[Jonas (Gast)]

LIBRARY ieee;
USE ieee.std_logic_1164.all;
ENTITY takt IS

  PORT
  (
    CLK      : IN   std_logic;
    takt50    : OUT  std_logic;
    takt500    : OUT  std_logic;
    takt50M    : OUT  std_logic
    );
END takt;


ARCHITECTURE takt_maker OF takt IS

signal clckzw: integer;
signal clckzw1: integer;
signal gen500: std_logic;
signal gen50: std_logic;


Begin

-------------------500kHz-------------------------- 

process (CLK)
  
  begin
  if(CLK'event and CLK = '1')
  then
    clckzw <= clckzw + 1;
  elsif(clckzw = 50)
  then
    clckzw <= 0;
    gen500 <= not gen500;
  end if;
  takt500 <= gen500;
 end process;

is jetzt für 500kHz, da ich von nem 50MHz takt ausgeh.....klappt auch 
ganz gut....danke für die tips

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Das sieht recht eigenartig aus...
Ich formatier das mal schöner:

process (CLK) begin
  if(CLK'event and CLK = '1') then  -- wenn ein Takt kommt dann zählen 
    clckzw <= clckzw + 1;
  elsif(clckzw = 50)  then   -- sonst auswerten???? --> seltsame Schreibweise...
    clckzw <= 0;
    gen500 <= not gen500;
  end if;
  takt500 <= gen500; -- das ist hier ganz schlecht: gen500 müsste eigentlich in der Sens-List stehen
end process;

Diese Schreibweise ist gelinde gesagt, unüblich.


Schöner, weil gängiger, ist das so:

signal clckzw: integer range 0 to 49;
:
process (CLK) begin
  if rising_edge(CLK) then  -- wenn ein Takt kommt dann zählen 
    if (clckzw < 49) then   -- 0..49 = 50 Takte
       clckzw <= clckzw + 1;
    else
       clckzw <= 0;
       gen500 <= not gen500;
    end if;
  end if;
end process; 

takt500 <= gen500;  -- concurrent Zuweisung

Gib bei integer einen Range an, sonst werden immmer gleich 32 Bits 
dafür angelegt.

[unpartei'scher (Gast)]

>achja, ich brauch die takte dann als Ausgangsports, da wir ne
>gruppenarbeit haben, und andere damit weiterarbeiten....

was wollen andere denn dranhängen?
üblicherweise würde man einen Puls ('1' mit Dauer 20 ns @50MHz)
erzeugen, egal ob man 1ms oder 1sec irgendwo braucht.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

> üblicherweise würde man einen Puls ('1' mit Dauer 20 ns @50MHz)
Das ist das, was man gemeinhin als Clock-Enable bezeichnet...   :-/

[Daniel -. (root)]

Die Tags waren falsch gesetzt .. siehe nächsten korrigierten Beitrag

[Daniel -. (root)]

Ich brauche öfters Pulse als Takte(nennt man das wirktlich Takte?).
Dafür habe ich in meinen Designs folgendes für schnell und gut befunden.

signal cnt: integer range 0 to 100e6 := 0;
signal sec_pulse: std_logic;
--
cnt <= cnt + 1 when rising_edge(clk100MHz);
sec_pulse <= '1' when cnt = 0 else '0';

in etwas umständlicheren Form mit expliziter Trennung

signal cnt, cnt_next: integer range 0 to 100e6 := 0;
signal sec_pulse: std_logic;
--
process
begin
    wait until rising_edge(clk100MHz);
    cnt <= cnt_next + 1;
end process;

cnt_next <= cnt + 1;

sec_pulse <= '1' when cnt = 0 else '0';

Dafür ist die explizite Form leicht erweiterbar, wenn
etwas mehr Funktionalität gefragt ist. Man muss nur eine
Zeile anpassen. zB

cnt_next <= preload_value when modus = load else
    cnt + 1 when modus = upcount else
    cnt - 1 when modus = downcount else
    cnt;

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

signal cnt: integer range 0 to 100e6 := 0;
:
cnt <= cnt + 1 when rising_edge(clk100MHz);
sec_pulse <= '1' when cnt = 0 else '0';

Das das geht wundert mich ein wenig.
Hier wird bei erreichen von 100000000 ein impliziter Reset auf 0 
angenommen, der aber weder von der Simulation noch von der Hardware 
unterstützt wird (mal davon abgesehen, dass der Zähler um 1 zu weit 
zählen würde: von 0 bis 100000000 sind es 100000001 Takte).

Die Simulation bringt eine Bereichsverletzung:

# ** Fatal: (vsim-3421) Value 100000001 for cnt is out of range 0 to 100000000.

Die Synthese macht einen 27Bit-Zähler, und der geht bis 134217727, erst 
dann läuft er über (siehe Screenshot)  :-o

Ich beschreibe das dann eher so:

process begin
    wait until rising_edge(clk100MHz);
    sec_pulse <= '0';
    if (cnt<100000000-1) then -- 0 bis 99999999
       cnt <= cnt + 1;
    else
       cnt <= 0;
       sec_pulse <= '1'     
    end if;
end process;

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

So geht es:

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;

entity CounterImplizit is
    Port ( clk : in  STD_LOGIC;
           sec : out  STD_LOGIC);
end CounterImplizit;

architecture Behavioral of CounterImplizit is
signal cnt: integer range 0 to 100e6 := 0;
begin

  cnt <=  0       when cnt=100e6 else
          cnt + 1 when rising_edge(clk);

  sec <= '1' when cnt = 0 else '0';

end Behavioral;

Allerdings ist die Beschreibung etwas unüblich und mir gefällt der 
asynchrone Reset nicht so richtig...   :-/

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

... denn die Auswertung des Vergleichs  cnt=100e6  braucht doch einiges 
an Logik (Screenshot), und wehe, da kommt mal ein kleiner Glitch 
zusammen.
Dann wird der Zähler einfach vor Erreichen des Endwerts zurückgesetzt.


Fazit: Finger weg von solchen asynchronen Beschreibungen.


Kommt jetzt einer auf die Idee, den Vergleich auch noch zu takten:

  cnt <=  0       when cnt=100e3-1 and rising_edge(clk)else
          cnt + 1 when rising_edge(clk);

Dann klopft ihm der Synthesizer auf die Finger und bemängelt eine
bad asynchronous descritpion.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Zum schönen Abschluss die synchrone Beschreibung:

  process begin
     wait until rising_edge(clk);
     if cnt=100e6-1 then cnt <= 0;
     else                cnt <= cnt + 1;
     end if;
  end process;

  sec <= '1' when cnt = 0 else '0';

Und der klitzekleine Unterschied im Screenshot:
der Zähler wird synchron zurückgesetzt
(die Reset-Leitung geht auf ein R statt auf ein CLR)

[Daniel (root) (Gast)]

Ich habe leider nicht nachgeschaut was aus meiner Kurzform nach
der Synthese wird. Dafür mache ich noch zu wenig mit den FPGA's
:)

Auf den Fehler in der Simulation bin ich aber auch irgendwann mal
gekommen. Das war glaube ich sogar bei der längeren Form wie
ich sie oben geschrieben habe.

Eigentlich müsste die Übergangslogik für cnt_next sauber heissen

cnt_next <= 0 when cnt = 100e6 else
    cnt + 1;
sec_pulse <= '1' when cnt=100e6 else '0';

Dann sollte auch cnt_next nie 100e6+1 werden.

Ich schaue mir deine RTL jpgs genauer etwas später an.
Bin jetzt etwas beschäftigt dafür.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Diese getrennte Schreibweise (cnt und cnt_next, das ist fast schon der 
Zwei-Prozess-SM Stil) ist überflüssig und führt nur zu unüberschaubaren 
Zähl- und Rücksetzbedingungen.
Mach den gesamten Zähler in einem (1) getakteten Prozess, dann sind 
alle Zählbedingungen sofort einsichtig und Querverbindungen 
ausgeschlossen.

Um dein eigenes Beispiel zu nehmen:

signal cnt: integer range 0 to 100e6-1 := 0;
signal sec_pulse: std_logic;
--
process
begin
    wait until rising_edge(clk100MHz);
    if     modus = load      then cnt <= preload_value;
    elsif  modus = upcount   then cnt <= cnt + 1;
    elsif  modus = downcount then cnt <= cnt - 1;
    elsif  cnt = 100e6-1     then cnt <= 0; 
    else                          cnt <= cnt + 1;
end process;

sec_pulse <= '1' when cnt = 0 else '0';

[Jonas (Gast)]

hallo lothar, danke für deinen Tip,
hat alles so geklappt, wie ich das brauchte....

das mit dem (CLK'event and CLK = '1') kam bei uns so in der 
Digitaltechnik vorlesung dran, deswegen hab ich das so verwendet.

wir bauen gerade eine Smart Cockpitsteuerung zusammen, deswegen muss ich 
die Frequenz als Port nehmen und an andere weiterleiten, die die 
Frequenz brauchen....

Jonas