LIN-Master-Bibliothek

//#define LIN13    // for classic checksum

#define LIN20  // for enhanced checksum

#define baudrate 19200

//#define baudrate 9600

//#define baudrate 4800

void txLINframe(byte nodeID, byte num, byte data[]){

  byte P0, P1, IDfield;

  int checksum = 0;

  P0 = ((nodeID>>0) + (nodeID>>1) + (nodeID>>2) + (nodeID>>4)) & 1;

  P1 = (~((nodeID>>1) + (nodeID>>3) + (nodeID>>4) + (nodeID>>5))) & 1;

  IDfield = nodeID & 0x3F | P0<<6 | P1<<7;

  // sync break (13 bit lengths zero)

  UCSR0B &= ~(1<<TXEN0);  // disable UART

  digitalWrite(1, LOW);  // output low for 13 bit times (minimum)

  delayMicroseconds(13*1e6/baudrate);

  digitalWrite(1, HIGH);

  delayMicroseconds(1e6/baudrate);  // sync delimiter (1 to 4 bits)

  UCSR0B |= 1<<TXEN0;  // enable UART

  // sync field (0x55)

  Serial.print(0x55, BYTE);

  // ident field (ID0:5, P0:1)

  Serial.print(IDfield, BYTE);

  #ifdef LIN20

    // LIN 2.0 includes ID field in checksum calculation

    // identifiers 60 (0x3c) to 63 (0x3f) shall always use classic checksum.

    if(nodeID < 60) {

      checksum = IDfield;

    }

  #endif

  for(byte i=0; i<num; i++) {

    Serial.print(data[i], BYTE);

    checksum += byte(data[i]);  // convert to unsigned number

    if(checksum > 255) {

      checksum -= 255;

    }

  }

  checksum = ~checksum;

  // send checksum

  Serial.print(byte(checksum), BYTE);

}