Entprellung / Blockieren von Mehrfachinput

[Morg (Gast)]

Hallo,

ich habe einen Rundenzähler / -timer für meine Carrerabahn geschrieben.

Der CTC-Timer läuft jede Millisekunde und zählt die beiden Rundentimer
hoch (mm:ss.hh).

Die beiden Interrupts sind an die Lichtschranken gekoppelt und sollen im
Grunde die aktuelle Rundenzeit im RAM sichern und danach zurücksetzen.

Dabei findet eine Abfrage statt, ob die aktuelle Rundenzeit schon 2
Sekunden oder mehr beträgt - das geht aber nicht. Ich habe teilweise
Rundenzeiten von nur wenigen Hundertsteln oder 00:00.00.

Irgendwie stehe ich auf dem Schlauch, was das nicht läuft.

Die Interruptroutinen sehen wie folgt aus, den gesamten Code habe ich
angehängt. Vielleicht kann mir einer von euch einen Tipp geben, auf
welchem Schlauch ich stehe?

Gruß
Morg

timer1_compare:  ; Timer 1 Output Compare Handler
 
  push  temp1      ; temp 1 sichern
  in  temp1,sreg    ; SREG sichern
 
  inc  SubCount    ; Wenn dies nicht der 10. Interrupt
  cpi  SubCount, 10    ; ist, dann passiert gar nichts
  brne  end_isr
 
  ; Überlauf
  clr  SubCount    ; SubCount rücksetzen

    ; Bahn 1
  inc   B1_Split    ; plus 1 1/100-Sekunde
  cpi   B1_Split, 100    ; sind 100 1/100-Sekunden vergangen?
  brne  B1_Ausgabe    ; wenn nicht kann die Ausgabe schon gemacht werden
 
  clr   B1_Split    ; 1/10-Sekunden wieder auf 0 und dafür
  inc   B1_Second    ; plus 1 Sekunde
  cpi   B1_Second, 60    ; sind 60 Sekunden vergangen ?
  brne  B1_Ausgabe    ; wenn nicht, -> Ausgabe

  clr   B1_Second    ; Sekunden wieder auf 0 und dafür
  inc   B1_Minute    ; plus 1 Minute
  cpi   B1_Minute, 60    ; sind 60 Minuten vergangen ?
  brne  B1_Ausgabe    ; wenn nicht, -> Ausgabe
 
  clr   B1_Minute    ; Minuten zurücksetzen
 
B1_Ausgabe:
  ori  Status, B_TimerFlag  ; Flag setzen, LCD updaten

  ; Bahn 2
  inc   B2_Split    ; plus 1 1/100-Sekunde
  cpi   B2_Split, 100    ; sind 100 1/100-Sekunden vergangen?
  brne  B2_Ausgabe    ; wenn nicht kann die Ausgabe schon gemacht werden
 
  clr   B2_Split    ; 1/10-Sekunden wieder auf 0 und dafür
  inc   B2_Second    ; plus 1 Sekunde
  cpi   B2_Second, 60    ; sind 60 Sekunden vergangen ?
  brne  B2_Ausgabe    ; wenn nicht, -> Ausgabe

  clr   B2_Second    ; Sekunden wieder auf 0 und dafür
  inc   B2_Minute    ; plus 1 Minute
  cpi   B2_Minute, 60    ; sind 60 Minuten vergangen ?
  brne  B2_Ausgabe    ; wenn nicht, -> Ausgabe
 
  clr   B2_Minute    ; Minuten zurücksetzen
 
B2_Ausgabe:
  ori  Status, B_TimerFlag  ; Flag setzen, LCD updaten
 
end_isr:
 
  out   sreg,temp1    ; sreg wieder herstellen
  pop   temp1
  reti        ; das wars. Interrupt ist fertig


;*
;* Interrupt 0 - Bahn 1
;*

int0_handler:

  push  temp1      ; temp 1 sichern
  in    temp1,sreg    ; SREG sichern

  ; improvisiertes Entprellen bzw. Sperren für 2 Sekunden
  cpi  B1_Minute, 0    ; nicht mehr in Minute 0?
  brge  int0_ok      ; dann weiter

  cpi  B1_Second, 2    ; Sekunde größer od. gleich 2?
  brge  int0_ok      ; dann weiter

  rjmp  int0_return    ; sonst raus
  
int0_ok:  
  ; aktuelle Zeit im SRAM speichern
  sts  B1_Lap_Split, B1_Split
  sts  B1_Lap_Second, B1_Second
  sts  B1_Lap_Minute, B1_Minute
  
  clr  B1_Split
  clr  B1_Second
  clr  B1_Minute

  ; TimerFlag, B1_Lap und B1_LapSet setzen
  ori  Status, B_TimerFlag | B_B1_Lap | B_B1_LapSet

  inc  B1_LapCount

int0_return:
  out   sreg,temp1    ; sreg wieder herstellen
  pop   temp1
  reti


;*
;* Interrupt 1 - Bahn 2
;*

int1_handler:

  push  temp1      ; temp 1 sichern
  in    temp1,sreg    ; SREG sichern

  ; improvisiertes Entprellen bzw. Sperren für 2 Sekunden
  cpi  B2_Minute, 0    ; nicht mehr in Minute 0?
  brge  int1_ok      ; dann weiter

  cpi  B2_Second, 2    ; Sekunde größer od. gleich 2?
  brge  int1_ok      ; dann weiter

  rjmp  int1_return    ; sonst raus
  
int1_ok:  
  ; aktuelle Zeit im SRAM speichern
  sts  B2_Lap_Split, B2_Split
  sts  B2_Lap_Second, B2_Second
  sts  B2_Lap_Minute, B2_Minute
  
  clr  B2_Split
  clr  B2_Second
  clr  B2_Minute

  ; TimerFlag, B2_Lap und B2_LapSet setzen
  ori  Status, B_TimerFlag | B_B2_Lap | B_B2_LapSet

  inc  B2_LapCount

int1_return:
  out   sreg,temp1    ; sreg wieder herstellen
  pop   temp1
  reti

[Karl H. (kbuchegg)]

  ; improvisiertes Entprellen bzw. Sperren für 2 Sekunden
  cpi  B2_Minute, 0    ; nicht mehr in Minute 0?
  brge  int1_ok      ; dann weiter

  cpi  B2_Second, 2    ; Sekunde größer od. gleich 2?
  brge  int1_ok      ; dann weiter

  rjmp  int1_return    ; sonst raus

brge ist "branch if greater or equal".
Effektiv sind deine Abfragen dadurch wirkungslos, weil am Anfang in 
Minute 0, die 0 in B2_Minute natürlich equal zu 0 ist.

  ; improvisiertes Entprellen bzw. Sperren für 2 Sekunden
  cpi  B2_Minute, 1    ; nicht mehr in Minute 0?
  brge  int1_ok      ; dann weiter

  cpi  B2_Second, 3    ; Sekunde größer od. gleich 2?
  brge  int1_ok      ; dann weiter

  rjmp  int1_return    ; sonst raus

[Morg (Gast)]

Mann... wie kann man denn sooo blind sein...

Vielen Dank, das war wohl fällig :-)

Ich geh's gleich mal ausprobieren...