Problem mit Bibliothek numeric standard

[transcend (Gast)]

Hallo zusammen;

Ich habe da folgendes Problem:
Mein VHDL Compiler erkennt die numeric_std nicht:

library IEEE;
use IEEE.std_logic_1164.all;
use IEEE.numeric_std.all;

-- Beschreibung der Black Box:

entity d_ff_reg is
  port
  (
    d_i : in std_logic_vector (3 downto 0);
    clk_i : in std_logic;
    en_i : in std_logic;
    sh_i : in std_logic;
    reset : in std_logic;
    q_o : out std_logic_vector (3 downto 0)
  );
end d_ff_reg;

architecture sim of d_ff_reg is

signal output_holder : std_logic_vector (3 downto 0);

begin
  p_logic0 : process (clk_i, reset)
  begin
    if(reset='1') then
      output_holder <= "0000";
    elsif(clk_i'event and clk_i='1') then
      if(en_i='0' and sh_i='0') then
        output_holder <= output_holder;
      elsif(en_i='0' and sh_i='1') then
        output_holder <= output_holder;
      elsif(en_i='1' and sh_i='0') then
        output_holder <= d_i;
      elsif(en_i='1' and sh_i='1') then
        output_holder <= SHIFT_LEFT(UNSIGNED(output_holder),1);
      end if;
    end if;
  end process p_logic0;
  q_o <= output_holder;
end sim;

Warum bekomme ich folgende Fehlermeldung obwohl die packages doch eh 
oben eingeblendet sind:

vhd(36): No feasible entries for subprogram "shift_left".
in Zeile:

output_holder <= SHIFT_LEFT(UNSIGNED(output_holder),1);

vhd(41): VHDL Compiler exiting

[Duke Scarring (Gast)]

Hier die Definition:

  -- Id: S.1
  function SHIFT_LEFT (ARG: UNSIGNED; COUNT: NATURAL) return UNSIGNED;

Dein Rückgabetyp pass nicht.

So geht's:

        output_holder <= std_logic_vector( SHIFT_LEFT(UNSIGNED(output_holder),1));

Duke

[PittyJ (Gast)]

Meiner übersetzt das auch nicht, aber aus einem anderen Grund:
Das Ergebnis von shift_left() ist ein unsigned und kein 
std_logic_vector.

Mit
        output_holder <= 
std_logic_vector(SHIFT_LEFT(UNSIGNED(output_holder),1));

geht das.

[transcend (Gast)]

Vielen vielen Dank für eure Hilfe und eure wertvolle Zeit.

[Michael F. (dasdgw)]

Also ich persönliches finde es übersichtlicher das Signal output_holder 
gleich als unsigned anzulegen. Dann muss man nur einen cast bei der 
Zuweisung zum Ausgangsport machen. In etwa so:

signal output_holder unsigned (3 downto 0);
...
output_holder <= SHIFT_LEFT(output_holder,1);
...
q_o <= std_logic_vector(output_holder);

Eventuell könnte man ja auch den Ausgangsport als unsigned wählen.
Dann könnte man sich den letzten cast auch noch sparen.