ADC umrechnen, mit Komma anzeigen (Assembler)

[Uwe O. (orti)]

Hallo...
ich habe ein Thermostat mit ATmega8 und 2x16 LCD gebaut. Die 
Temperaturregelung ist fertig und der Probelauf war erfolgreich. Jetzt 
habe ich nur noch das Problem den ADC-Wert in die Temperatur umrechnen 
und dann auf dem LCD anzeigen. Der Sensor incl OPV misst 0,1°C, aber ich 
möchte eine Anzeige in 0,5°C Schritten und für die Regelung verwende ich 
nur ganze Grad.
Die Formel für die Berechnung wäre
100 - (1060 - ADC) * 0,126 = Temperatur
aber wie macht man das im Assembler und das Ganze dann noch mit Komma 
??? Viele Fragen und keine Lösung in Sicht. Wäre nicht schlecht, wenn 
mir mal jemand das erklären könnte.

Gruss Uwe

[spess53 (Gast)]

Hi

>Viele Fragen und keine Lösung in Sicht. Wäre nicht schlecht, wenn
>mir mal jemand das erklären könnte.

Ich habe dir mal etwas für den Formelteil (1060 - ADC) * 0,126 
zusammengestellt. Das Ergebnis ist in r19...r16. Dabei liegt der 
Vorkommateil in r19:r18 (eigentlich ist r19 immer Null) und der 
Nachkommateil in r17:r16. Der Rest sollte nicht mehr so schwierig sein.

         ldi r18,Low($100)   ; ADC-Wert
         ldi r19,High($100)  ;
                       
         ldi r16, Low(1060)
         ldi r17,High(1060)
         
         sub r16,r18         ; 1060-ADC-Wert 
         sbc r17,r19

         movw r23:r22,r17:r16

         ldi r20,Low(Q15(0.126))
         ldi r21,High(Q15(0.126))

         ;r19:r18:r17:r16 = (r23:r22 * r21:r20) << 1

fmuls16x16_32:                ; Multiplikation mit 0,126
         clr r2               ; Null
         fmuls r23, r21       ; ((signed)ah*(signed)bh)<<1
         movw r19:r18, r1:r0
         fmul r22, r20        ; (al*bl)<<1
         adc r18, r2
         movw r17:r16, r1:r0
         fmulsu r23, r20      ; ((signed)ah*bl)<<1
         sbc r19, r2
         add r17, r0
         adc r18, r1
         adc r19, r2
         fmulsu r21, r22       ; ((signed)bh*al)<<1
         sbc r19, r2
         add r17, r0
         adc r18, r1
         adc r19, r2

MfG Spess

[Uwe O. (orti)]

Vielen Dank ... das werde ich gleich heute Abend testen.

Gruss Uwe

[spess53 (Gast)]

Hi

Ich habe das Ganze noch mal etwas überarbeitet

         ldi r18, Low($17F)
         ldi r19,High($17F)  ; ADC-Wert
                       
         ;###################################

;        in:  r19:r18    ADC-Wert
;        out: r22        Vorkomma-Wert 
;             r21        $00 -> xx,0
;                        $80 -> xx,5
;             r25        '+' positiver Wert
;                        '-' negativer Wert

         ldi r22, Low(1060)
         ldi r23,High(1060)
         
         sub r22,r18         ; 1060 - ADC-Wert 
         sbc r23,r19

         ldi r20,Low(Q15(0.126))
         ldi r21,High(Q15(0.126))

         ; r18..r16 = r23:r22 * r21:r20<<1

         clr r2             ; Null

         fmul r23, r21      ; (ah*bh)<<1
         mov r18, r0

         fmul r22, r20      ; (al*bl)<<1
         adc r18, r2        ; Übertrag von fmul
         movw r17:r16, r1:r0

         fmul r23, r20      ; (ah*bl)<<1
         add r17, r0
         adc r18, r1

         fmul r21, r22      ; (bh*al)<<1
         add r17, r0
         adc r18, r1

         ldi r25,'+'        ; Vorzeichen

         ;--------------------------------
         clr r20
         clr r21
         ldi r22,100        ; r22..r20= 100,0....

         sub r20,r16
         sbc r21,r17
         sbc r22,r18        ; 100 - (...)

         brpl aaa           ; wenn postiv nach aaa

         ;--------------------------------

         ldi r25,'-'        ; Vorzeichen

         com r20            ; 2er-Komplement
         com r21            ; von r22..r20
         com r22
         subi r20,Low(-1)
         sbci r21,byte2(-1)
         sbci r22,byte3(-1)

aaa:     ser r16            ; Werte zum
         ldi r17,$3F        ; Runden

         add r20,r16        ; auf xx,0/xx,5
         adc r21,r17        ; Runden
         adc r22,r2
         andi r21,$80       ;

MfG Spess

[Uwe O. (orti)]

Hallo...
das sieht ja schon ganz gut aus - mit runden und Vorzeichen. Aber meine 
Formal "geht von hinten durch die Brust ins Auge", ist viel zu 
kompliziert. Nach einiger Zeit bin ich drauf gekommen.
   ADC / 8 - 34    ist genau das selbe.
ADC / 8 ist die Auflösung (0,125°C je ADC-Wert), und bei ADC = 0 müssten 
es -34°C sein. Das kann man auch später noch korrigieren.

Dein Programm von Gestern hatte ich getestet, funzt.

Gruss Uwe