Attiny 2313 als SPI Slave - Übertragungsprobleme

[Dominique S. (mronak)]

Hallo zusammen,

nachdem ich das Forum schon einige Zeit anonym stalke ist nun die Zeit 
gekommen hier eine Frage zu stellen :-/.

Ich versuche einen ATTiny2313 als SPI Slave zu betreiben, gefüttert von 
einem Arduino Uno als SPI Master. Die Daten kommen jedoch nicht oder 
nicht korrekt an. Wenn ich in der Interrupt Routine des Slaves debugge 
(LED an/aus) dann wird diese aufgerufen. Jedoch kommen die Daten die ich 
per SPI übertrage nicht an.

Zu den Problemen im Detail noch mehr weiter unten.

Der Test besteht daraus, auf dem Uno das Drücken eines Pushbuttons an 
Pin 3 auszulesen, eine LED am eigenen Pin 2 umzuschalten (drücken -> an, 
erneut drücken -> aus) und via SPI Kommandos an den ATtiny zu schicken 
(an = 0b10011001, aus = 0x00) der dann seinerseits ebenfalls eine LED 
togglen soll.

Das Beispiel ist relativ dumm, aber ich dachte ich fange mit etwas 
simplem an bevor ich "echte" Befehle und Daten via SPI übertrage.

Ich habe viel Zeit mit der Suche verbracht aber ATTinys als SPI Slave 
scheinen relativ rar zu sein.

Hier mal der Code für den Master:

#include <SPI.h>

#define PIN_SS_ATTINY2313 10
#define PIN_LED 2
#define PIN_BTN 3

#define CMD_LEDON 0b10011001
#define CMD_LEDOFF 0x00

byte bitOrder = MSBFIRST;
int btnState; int lastBtnState; int ledState;

void setup() {
  pinMode(PIN_LED, OUTPUT);
  pinMode(PIN_BTN, INPUT);
  pinMode(PIN_SS_ATTINY2313, OUTPUT);
  
  digitalWrite(PIN_SS_ATTINY2313, HIGH);
  
  SPI.begin();
  SPI.setDataMode(SPI_MODE0);
  SPI.setBitOrder(bitOrder);
  SPI.setClockDivider(SPI_CLOCK_DIV128); // 128kKz
  
  ledOff();
}

void loop() {
  lastBtnState = btnState;
  btnState = digitalRead(PIN_BTN);
  
  if (lastBtnState == 0 && btnState == 1) {
    if (ledState == LOW) {
      ledOn();
    } else {
      ledOff();
    }
  }
}

void ledOn() {
  digitalWrite(PIN_LED, HIGH);
  ledState = HIGH;

  digitalWrite(PIN_SS_ATTINY2313, LOW);
  SPI.transfer(CMD_LEDON);
  digitalWrite(PIN_SS_ATTINY2313, HIGH);
}

void ledOff() {
  digitalWrite(PIN_LED, LOW);
  ledState = LOW;

  digitalWrite(PIN_SS_ATTINY2313, LOW);
  SPI.transfer(CMD_LEDOFF);
  digitalWrite(PIN_SS_ATTINY2313, HIGH);
}

Wenn ich den Uno mit dem SPI Master code an einen 74HCT595 anschließe 
(der macht ja auch nur SPI Mode 0) und 8 LEDs an die einzelnen Ausgänge 
des Shiftregisters anschließe dann schalten alle LEDs korrekt, ich gehe 
daher naiver Weise mal davon aus das der Master funktioniert.

Und der Code für den Slave am ATtiny 2313:

#include <avr/io.h>
#include <avr/interrupt.h>
#include <util/delay.h>
 
#define CTRL_PORT  DDRB
#define DATA_PORT  PORTB
#define SS_PIN    PB4
#define CLK_PIN    PB7
#define  DI_PIN    PB5
#define DO_PIN    PB6

// SPI mode 0 or 1 - modes 2 and 3 are NOT supported
#define SPI_MODE 0

#define PIN_LED PD5
#define CMD_LEDON 0b10011001
#define CMD_LEDOFF 0x00

// Some macros that make the code more readable
#define output_low(port,pin) port &= ~(1<<pin)
#define output_high(port,pin) port |= (1<<pin)
#define set_input(portdir,pin) portdir &= ~(1<<pin) 
#define set_output(portdir,pin) portdir |= (1<<pin)

boolean ledState;
byte cmd;
boolean cmdAvailable;

int main(void) {
  init();
  
  while (1) {
    if (cmdAvailable == true) {
      
      // SPI command handling
      if (cmd == CMD_LEDOFF) {
        output_low(PORTD, PIN_LED);
        ledState = false;
      } else if (cmd == CMD_LEDON) {
        output_high(PORTD, PIN_LED);
        ledState = true;
      }

      cmdAvailable = false;
    }
  }
  
  return 0;
}

void init() {
  // initialize the direction of PORTD #5 to be an output
  set_output(DDRD, PIN_LED);  
  
  output_high(PORTD, PIN_LED);
  ledState     = true;
  cmdAvailable = false;

  // DO pin is configured for output
  CTRL_PORT |= _BV(DO_PIN);
  // other pins as input
  CTRL_PORT &= ~_BV(DI_PIN) | ~_BV(CLK_PIN) | ~_BV(SS_PIN);
  // set pull ups
  DATA_PORT |= _BV(DI_PIN) | _BV(CLK_PIN);
  // enable USI overflow interrupt, set three wire mode and set
  //  clock to external, positive edge
  USICR = 0;
  USICR = (1<<USIOIE) | (1<<USIWM0) | (1<<USICS1) | (SPI_MODE<<USICS0);
  
  USISR = (1<<USIOIF); // clear overflow flag
}

/**
 * USI overflow intterupt - triggered when transfer complete
 */
ISR(USI_OVERFLOW_vect) {
  cmd           = USIDR;
  USISR         = (1<<USIOIF); // clear overflow flag
  cmdAvailable  = true;
}

Wie ihr seht ignoriert der Slave aktuell noch den SS Pin (also eher USI 
statt SPI) aber das sollte meines Verständnisses nach dem USI_OVERFLOW 
Interrupt keinen Abbruch tun?

Der Test "if (cmdAvailable == true)" in main() trifft nie zu, es ist als 
ob die Interrupt Routine nie ausgeführt würde.

Wenn ich allerdings in der Interrupt Routine die LED direkt toggle, ohne 
die SPI-Daten zu beachten dann toggled diese tatsächlich mit jedem 
Drücken des Pushbuttons, also wird sie "irgendwie doch" aufgerufen.

Was ich meine ist innerhalb der ISP Routine folgendes einzubauen:

  if (ledState == false) {
    output_high(PORTD, PIN_LED);
    ledState = true;
  } else {
    output_low(PORTD, PIN_LED);
    ledState = false;
  }

Das toggled mit jedem Drücken des Buttons am Uno die LED am Attiny, 
allerdings werden natürlich die SPI Daten ignoriert.

Was ich überhaupt nicht verstehe ist warum der Aufruf von cmdAvailable = 
true; innerhalb der Interrupt Routine nicht dazu führt dass in main() in 
die If-Schleife gesprungen wird. Ich kann doch in der Interrupt Routine 
eine globale Boolsche Variable setzen und die dann im Loop der main() 
auslesen, oder habe ich da einen größeren Denkfehler?

Ich bin nicht sicher ob ich das USI Register für SPI Mode 0 korrekt 
setze, fast glaube ich es liegt daran (neben dem Mysterium der nicht 
gesetzten Boolschen Variable) aber beim Abgleich mit dem Datenblatt 
finde ich keinen Fehler.

Am Anfang hatte ich in der init() am Ende noch einen Aufruf von sei(); 
aber nach meinem Verständnis werden die Interrupts durch Setzen von 
(1<<USIOIE) sowieso aktiviert?

Ich bin mit meinem Latein ziemlich am Ende, danke schon mal für Eure 
Hilfe :)

[C. W. (chefkoch)]

Probier mal cmdAvailable als volatile zu deklarieren

[Dominique S. (mronak)]

Ach f.....ielen Dank. Ja klar, das war's.

volatile auf cmdAvailable und cmd und schon gehts. Grmpf. Kopf -> Wand.

Tausend Dank!

[C. W. (chefkoch)]

Bitte